Merge remote-tracking branch 'origin/5.4'
[scilab.git] / scilab / configure.ac
1 #
2 # Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
3 # Copyright (C) INRIA - 2006-2008 - Sylvestre Ledru
4 # Copyright (C) DIGITEO - 2009-2011 - Sylvestre Ledru
5 # Copyright (C) DIGITEO - 2009 - Pierre MARECHAL <pierre.marechal@scilab.org>
6 #
7 # This file must be used under the terms of the CeCILL.
8 # This source file is licensed as described in the file COPYING, which
9 # you should have received as part of this distribution.  The terms
10 # are also available at
11 # http://www.cecill.info/licences/Licence_CeCILL_V2-en.txt
12 #
13
14 dnl Process this file with autoconf to produce a configure script.
15
16
17 AC_REVISION($Revision$)dnl
18 AC_INIT([Scilab],[5],[http://bugzilla.scilab.org/])
19 AC_PREREQ(2.62)
20 AC_CONFIG_MACRO_DIR([m4/])
21
22 SCI_BUILDDIR="`pwd`"
23 SCI_SRCDIR="$srcdir"
24 SCI_SRCDIR_FULL="`cd $SCI_SRCDIR && pwd`"
25
26 SCILAB_VERSION_MAJOR=5
27 SCILAB_VERSION_MINOR=5
28 SCILAB_VERSION_MAINTENANCE=0
29 AC_SUBST(SCILAB_VERSION_MAJOR)
30 AC_SUBST(SCILAB_VERSION_MINOR)
31 AC_SUBST(SCILAB_VERSION_MAINTENANCE)
32
33
34 SCILAB_LIBRARY_VERSION=$SCILAB_VERSION_MAJOR:$SCILAB_VERSION_MINOR:$SCILAB_VERSION_MAINTENANCE
35 AC_SUBST(SCILAB_LIBRARY_VERSION)
36
37 SCILAB_BINARY_VERSION=$SCILAB_VERSION_MAJOR.$SCILAB_VERSION_MINOR.$SCILAB_VERSION_MAINTENANCE
38 AC_SUBST(SCILAB_BINARY_VERSION)
39
40 #shared library versioning
41 #GENERIC_LIBRARY_VERSION=1:2:0
42 #                       | | |
43 #                +------+ | +---+
44 #                |        |     |
45 #             current:revision:age
46 #                |        |     |
47 #                |        |     +- increment if interfaces have been added
48 #                |        |        set to zero if interfaces have been removed
49 #                                  or changed
50 #                |        +- increment if source code has changed
51 #                |           set to zero if current is incremented
52 #                +- increment if interfaces have been added, removed or changed
53
54 # Check if we have a space in the path to the source tree
55 SPACE_IN_PATH=`echo "$SCI_SRCDIR_FULL"|grep " " > /dev/null; echo $?`
56 if test "$SPACE_IN_PATH" = "0"; then
57    AC_MSG_WARN([=====================================])
58    AC_MSG_WARN([Configure thinks that there is a space in the path to the source. This may cause problem with libtool and some other things...])
59    AC_MSG_WARN([=====================================])
60    sleep 180
61 fi
62
63 AC_CONFIG_AUX_DIR(config)
64 AC_CONFIG_HEADERS([modules/core/includes/machine.h])
65
66 # strip executable
67 AM_PROG_INSTALL_STRIP
68 AC_PROG_LN_S
69
70 AC_CUSTOM_LARGE_FILE
71
72 # In order to be able to change the scilab directory
73 # See http://wiki.debian.org/RpathIssue
74 AC_RELOCATABLE
75 AC_RELOCATABLE_LIBRARY
76 AC_LIB_RPATH
77
78 # If configure detect that timestamp changed,
79 # it tries to rebuild configure & makefile which can be a painmaker
80 # if the version is different
81 AM_MAINTAINER_MODE
82
83 AM_INIT_AUTOMAKE([-Wall foreign]) # Not using -Werror because we override {C,F}FLAGS in order to disable optimisation
84
85 AC_CANONICAL_HOST
86
87 #################################
88 ## all the --with-* argument help
89 #################################
90
91
92 AC_ARG_ENABLE(debug,
93    AC_HELP_STRING([--enable-debug],[Do not optimize and print warning messages (C/C++/Fortran/Java code)]))
94
95 AC_ARG_ENABLE(debug-C,
96    AC_HELP_STRING([--enable-debug-C],[Do not optimize and print warning messages (C code)]))
97
98 AC_ARG_ENABLE(debug-CXX,
99    AC_HELP_STRING([--enable-debug-CXX],[Do not optimize and print warning messages (C++ code)]))
100
101 AC_ARG_ENABLE(debug-java,
102    AC_HELP_STRING([--enable-debug-java],[Print warning messages and line numbers (Java code)]))
103
104 AC_ARG_ENABLE(debug-fortran,
105    AC_HELP_STRING([--enable-debug-fortran],[Do not optimize and print warning messages (Fortran code)]))
106
107 AC_ARG_ENABLE(debug-linker,
108    AC_HELP_STRING([--enable-debug-linker],[Print warning messages from the linker (ld)]))
109
110 AC_ARG_ENABLE(code-coverage,
111    AC_HELP_STRING([--enable-code-coverage],[Enable code coverage]))
112
113 AC_ARG_ENABLE(stop-on-warning,
114    AC_HELP_STRING([--enable-stop-on-warning],[Stop the compilation on the first warning found in the C/C++ code]))
115
116 AC_ARG_WITH(gcc,
117     AC_HELP_STRING([--with-gcc],[Use gcc C compiler ]))
118
119 AC_ARG_WITH(gfortran,
120     AC_HELP_STRING([--with-gfortran],[Use gfortran, GNU Fortran 95 compiler]))
121
122 AC_ARG_WITH(intelcompilers,
123     AC_HELP_STRING([--with-intelcompilers],[Use Intel C (icc) and Fortran (ifort) proprietary compilers (GNU/Linux only) ]))
124
125 AC_ARG_WITH(tk,
126     AC_HELP_STRING([--without-tk],[Disable the interface to Tcl/Tk ]))
127
128 AC_ARG_WITH(javasci,
129     AC_HELP_STRING([--without-javasci],[Disable the Java/Scilab interface (javasci)]))
130
131 AC_ARG_ENABLE(compilation-tests,
132     AC_HELP_STRING([--enable-compilation-tests],[Enable unitary tests and checks at compilation time]))
133
134 AC_ARG_WITH(gui,
135     AC_HELP_STRING([--without-gui],[Disable the Scilab Graphical User Interface (GUI). Intended for embedded/clustering/grid Scilab ]))
136
137 AC_ARG_ENABLE(build-swig,
138     AC_HELP_STRING([--enable-build-swig],[Regenerate Java => C wrappers produces by Swig (A Java Development Kit (JDK) is mandatory for this option)]))
139
140 AC_ARG_ENABLE(build-giws,
141     AC_HELP_STRING([--enable-build-giws],[Regenerate C/C++ => Java wrappers produces by Giws (A Java Development Kit (JDK) is mandatory for this option)]))
142
143
144 ################################################
145 ########## compilator & misc programs detection
146 ################################################
147
148 AC_PROG_CPP
149 AC_PROG_GREP
150
151 ######
152 #### Mac OS X set of fink path with provided
153 ######
154
155 AC_ARG_WITH(fink_prefix,
156 AC_HELP_STRING([--with-fink-prefix],[Provide a fink prefix. Default: /sw/ ]))
157 # Need MacosX Version to specify some path.                                  
158 case "$host_os" in
159      *Darwin* | *darwin*)
160               AC_GET_MACOSX_VERSION
161      ;;
162 esac
163
164 case "$host" in
165     *darwin*)
166         if test -n "$with_fink_prefix"; then
167             # If with-fink-prefix is provided, use the provided path to make sure that we will
168             # use it to detect dependencies (for example, gfortran is not provided in xcode.
169             # Therefor, we use the one in fink)
170             FINK_PREFIX="$with_fink_prefix/"
171
172             # Exec the init script of fink to make sure that the env is set
173             if test -f $with_fink_prefix/bin/init.sh; then
174                 echo "source $with_fink_prefix/bin/init.sh executed to set the env"
175                 source $with_fink_prefix/bin/init.sh
176             else
177                 AC_MSG_WARN([Could not find the fink init.sh script: $with_fink_prefix/bin/init.sh])
178             fi
179         else
180             FINK_PREFIX="/sw/"
181         fi
182
183         #Append to the default flags on Apple machines
184         CPPFLAGS="$CPPFLAGS -I$FINK_PREFIX/include/"
185         LDFLAGS="$LDFLAGS -L$FINK_PREFIX/lib/"
186         ;;
187 esac
188
189 AC_ARG_WITH(min_macosx_version,
190 AC_HELP_STRING([--with-min-macosx-version],[Force compilers to generate binaries compatible with MacOSX minimal version.]))
191 case "$host" in
192     *darwin*)
193     if test -n "$with_min_macosx_version"; then
194        MIN_MACOSX_VERSION=$with_min_macosx_version
195        #Append to the default flags on Apple machines
196        ARCH_CFLAGS="-mmacosx-version-min=$MIN_MACOSX_VERSION"
197        ARCH_CXXFLAGS="-mmacosx-version-min=$MIN_MACOSX_VERSION"
198        ARCH_FFLAGS="-mmacosx-version-min=$MIN_MACOSX_VERSION"
199        ARCH_LDFLAGS="-mmacosx-version-min=$MIN_MACOSX_VERSION"
200        # We need this to be passed to all linker commands
201        LDFLAGS="$LDFLAGS -mmacosx-version-min=$MIN_MACOSX_VERSION"
202     fi
203 ;;
204 esac
205
206
207 #####################################################
208 ## Look for pkg-config
209 #####################################################
210 PKG_PROG_PKG_CONFIG
211
212 #####################################################
213 ## check if options are correct (or not)
214 #####################################################
215
216 if test "$with_intelcompilers" = yes -a "$with_gcc" = yes; then
217     AC_MSG_ERROR([Conflicting options : you specified two compiler series])
218 fi
219
220 ######## fortran ########
221
222 if test "$with_gfortran" = yes; then
223    AC_PROG_F77(gfortran)
224    if test -z "$F77"; then
225      AC_MSG_ERROR([You asked me to use gfortran but i haven't been able to find it])
226     fi
227 fi
228
229 if test "$with_intelcompilers" = yes; then
230    AC_PROG_F77(ifc ifort)
231    if test -z "$F77"; then
232      AC_MSG_ERROR([You asked me to use ifc (intel fortran compiler) but i haven't been able to find it])
233     fi
234 fi
235
236 if test -z "$F77"; then
237 ## No Fortran compiler specified... Prefer gfortran and intel compilers
238    AC_PROG_F77([gfortran ifc ifort])
239    if test -z "$F77"; then
240         # Best effort to find a compiler (might be g77)
241         AC_PROG_F77
242    fi
243 fi
244
245
246 # case statements were introduced in fortran 90 so we can use that
247 # as a test to see if our compiler is fortran 90 compatible.
248 f90compatible=false
249 if test -z "$F77"; then
250   AC_MSG_ERROR([No fortran compiler found. Cannot compile scilab without a fortran compiler])
251 fi
252
253 AC_MSG_CHECKING([if $F77 is a fortran 90 compatible compiler])
254  f90compatible=false
255 AC_LANG_PUSH([Fortran 77])
256 AC_COMPILE_IFELSE([
257       PROGRAM hello
258         do 50 i = 1, 5
259            select case ( i )
260               case (1)
261                  print*, "case is 1, i is ", i
262               case ( 2 : 3 )
263                  print*, "case is 2 to 3, i is ", i
264               case default
265                  print*, "default case, i is ", i
266               end select
267  50           continue
268       END
269     ],
270     [AC_MSG_RESULT([yes])
271      AC_DEFINE([G95_FORTRAN],[],[uses G95 fortran])
272      f90compatible=true
273     ],
274     [AC_MSG_RESULT([no])]
275 )
276 AC_LANG_POP([Fortran 77])
277
278 ############ C ###############
279
280
281 if test "$with_gcc" = yes; then
282    AC_PROG_CC(gcc)
283    if test -z "$CC"; then
284      AC_MSG_ERROR([You asked me to use gcc but i haven't been able to find it])
285     fi
286 fi
287
288 if test "$with_intelcompilers" = yes; then
289    AC_PROG_CC(icc ecc)
290    if test -z "$CC"; then
291      AC_MSG_ERROR([You asked me to use icc (intel C compiler) but I haven't been able to find it])
292     fi
293 fi
294
295 if test -z "$CC"; then
296 # No C compiler specified... We rely on Autoconf to find the best
297    AC_PROG_CC
298 fi
299
300 if test -z "$CC"; then
301   AC_MSG_ERROR([No C Compiler found. Cannot compile Scilab without a C compiler])
302 fi
303
304 AC_CHECK_SIZEOF([int])
305 AC_CHECK_SIZEOF([long])
306
307 ### C++ ###
308 AC_PROG_CXX
309 # we can't just do something like
310 # AC_CHECK_PROG(cxx_present, $CXX, "yes", "no")
311 # because if the user has specified the full path of the desired C++ compiler then AC_CHECK_PROG
312 # will fail.  If AC_PROG_CXX fails to find a c++ compiler it will set CXX=g++ so just run AC_CHECK_PROG
313 # in this special case
314 case $CXX in
315     g++)
316         AC_CHECK_PROG([cxx_present], [$CXX], [yes], [no])
317         if test "x$cxx_present" != "xyes"; then
318             AC_MSG_ERROR([No C++ compiler found. Cannot compile scilab without a C++ compiler])
319         fi
320         ;;
321 esac
322
323 # for "subdir-objects"
324
325 AM_PROG_CC_C_O
326 AC_PROG_F77_C_O
327
328
329 # If this option is provided, enable the debug on C & C++
330 if test "$enable_stop_on_warning" = yes; then
331    enable_debug_C=yes
332    enable_debug_CXX=yes
333 fi
334
335 if test "$enable_debug" = yes; then
336    enable_debug_fortran=yes
337    enable_debug_C=yes
338    enable_debug_CXX=yes
339    enable_debug_java=yes
340 else
341    enable_debug=no
342 fi
343
344 if test "$enable_debug_fortran" = yes; then
345    FFLAGS="`echo "$FFLAGS"| sed -e 's|-O[0-9+]|-O0|'`"
346 else
347    enable_debug_fortran=no
348 fi
349
350 if test "$enable_debug_C" = yes; then
351    CFLAGS="`echo "$CFLAGS"| sed -e 's|-O[0-9+]|-O0|'`"
352 else
353    enable_debug_C=no
354 fi
355
356 if test "$enable_debug_CXX" = yes; then
357    CXXFLAGS="`echo "$CXXFLAGS"| sed -e 's|-O[0-9+]|-O0|'`"
358 else
359    enable_debug_CXX=no
360 fi
361
362 if test "$enable_debug_java" = yes; then
363    LOGGING_LEVEL="INFO"
364 else
365    LOGGING_LEVEL="SEVERE"
366 fi
367 AC_SUBST(LOGGING_LEVEL)
368
369 if test "x${prefix}" = "xNONE"; then
370   prefix="${ac_default_prefix}"
371 fi
372
373 ###############################
374 ## get the version
375 ###############################
376
377 SCIVERSION=`cat $SCI_SRCDIR/Version.incl | sed -e "s/SCIVERSION=//" `
378
379 #############################################
380 ## Compilers and options according to machine
381 #############################################
382
383 ######################
384 ######## Set compilation options for intel C/Fortran compilers
385 ######################
386
387 if test "$with_intelcompilers" = yes; then
388    SCI_INTEL_COMPILER()
389 fi
390
391 ########### FORTRAN ######################
392
393
394 ######################
395 ######## With gfortran ...
396 ######################
397 if test -n "$F77"; then
398    case "$F77" in
399      gfortran*)
400         ## With GNU Compiler enable the code coverage
401         if test "$enable_code_coverage" = yes; then
402             CODE_COVERAGE_FFLAGS="-fprofile-arcs -ftest-coverage"
403         fi
404      ;;
405      g77*)
406         AC_MSG_ERROR([g77 is no longer supported. Please consider switching to gfortran])
407      ;;
408    esac
409
410    if test "$enable_debug_fortran" = yes; then
411     AC_LANG_PUSH([Fortran 77])
412     for flag in -g -Wall -Wsurprising; do
413         case " ${FFLAGS} " in
414             *\ ${flag}\ *)
415                 # flag is already present
416                 ;;
417
418             *)
419                 AC_MSG_CHECKING([if the Fortran compiler accepts ${flag}])
420                 ac_save_FFLAGS="$FFLAGS"
421                 FFLAGS="$FFLAGS ${flag}"
422                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],
423                     [AC_MSG_RESULT([yes])
424                      DEBUG_FFLAGS="${flag}"
425                     ],
426                     [AC_MSG_RESULT([no])]
427                 )
428                 ;;
429         esac
430     done
431     AC_LANG_POP([Fortran 77])
432    else
433       DEBUG_FFLAGS="-DNDEBUG"
434    fi
435       case "$host" in
436          x86_64-*-linux*)
437             ARCH_FFLAGS="-m64 -fPIC"
438                     ;;
439         # Dec Alpha OSF 4
440         alpha*-dec-osf4.*)
441           ARCH_FFLAGS="-fpe3"
442         ;;
443         alpha*-dec-osf*)
444             ARCH_FFLAGS="-fpe3 -switch nosqrt_recip"
445         ;;
446         rs6000-*-*)
447             ARCH_FFLAGS="-qcharlen=4096"
448             ;;
449         mips-*-ultrix*)
450             ARCH_FFLAGS="-O0 -fpe1"
451         ;;
452           *-*-hpux9.*)
453             ARCH_FFLAGS="+Obb1200 +E4 -Dhpux"
454         ;;
455           *-*-hpux10.*)
456             if test "$enable_debug_fortran" = yes; then
457                 ARCH_FFLAGS="+E4 +Z +DAportable -Dhpux"
458             else
459                 ARCH_FFLAGS="+O2 +E4 +Z +DAportable -Dhpux"
460             fi
461 #            ARCH_LDFLAGS="-Wl,+vnocompatwarnings,-E /usr/lib/libdld.sl"
462
463             ;;
464           *-*-hpux11.*)
465            if test "$enable_debug_fortran" = yes; then
466               ARCH_FFLAGS=" +Z +DAportable -Dhpux"
467              else
468               ARCH_FFLAGS="+O2 +Z +DAportable -Dhpux"
469            fi
470            ARCH_LDFLAGS="-ldld -lnsl -lU77 -lm"
471
472      ;;
473       esac
474
475 fi
476
477 #########################
478 # setting parameters according to system types
479 #########################
480
481 case "$host" in
482     *-*-hpux9.*|*-*-hpux10.*|*-*-hpux11.*)
483         HPUX=1
484     ;;
485     sparc-*)
486         SPARC=1
487     ;;
488     mips-sgi-irix*)
489       MIPS_SGI_IRIX=1
490     ;;
491      *-*-solaris*)
492      SOLARIS=1
493      ;;
494     *darwin*)
495       MACOSX=1
496     ;;
497 esac
498
499 AM_CONDITIONAL(IS_MACOSX, test -n "$MACOSX")
500 AM_CONDITIONAL(IS_HPUX, test -n "$HPUX")
501 AM_CONDITIONAL(IS_SPARC, test -n "$SPARC")
502 AM_CONDITIONAL(IS_SOLARIS, test -n "$SOLARIS")
503 AM_CONDITIONAL(IS_MIPS_SGI_IRIX, test -n "$MIPS_SGI_IRIX")
504
505
506
507 ############
508 ## C++
509 ############
510
511
512 if test -z "$CXX"; then
513   AC_MSG_ERROR([No C++ compiler found. Cannot compile scilab without a C++ compiler])
514 fi
515
516 case "$CXX" in
517     g++-* | g++ | ccache*g++ | ccache*g++-* )
518         ## With GNU C++ Compiler
519
520         # enable the code coverage
521         if test "$enable_code_coverage" = yes; then
522             CODE_COVERAGE_CXXFLAGS="-fprofile-arcs -ftest-coverage"
523         fi
524
525         if test "$enable_debug_CXX" = yes; then
526             DEBUG_CXXFLAGS="-pipe -Wshadow -Wpointer-arith -Wcast-align -Wreturn-type -Wswitch -Wtrigraphs -Wcomment -W -Wchar-subscripts -Wformat -Wparentheses -Wsign-compare -Wwrite-strings -Wunused -Wno-strict-aliasing -Wextra -Wall -g3 -Wunsafe-loop-optimizations"
527             case "$host" in
528                 *-linux-gnu )
529                     # Only doing that under Linux
530                     DEBUG_CXXFLAGS="$DEBUG_CXXFLAGS -fdiagnostics-show-option -Werror=format-security"
531                 ;;
532             esac
533         else
534             DEBUG_CXXFLAGS="-DNDEBUG"
535         fi
536         COMPILER_CXXFLAGS="-fno-stack-protector " # bug 3131
537         COMPILER_LDFLAGS="-lstdc++"
538     ;;
539
540     clang-* | clang)
541         # clang linker expect an explict declaration
542         #¬†until the http://libcxx.llvm.org/ release, we select the GNU one.
543         COMPILER_LDFLAGS="-lstdc++"
544     ;;
545 esac
546
547 #### 64 bits detection
548 IS_64_BITS_CPU=false
549 case "$host" in
550          x86_64-*-linux-gnu | x86_64-linux-gnu | ia64-*-linux-gnu | alpha-*-linux-gnu | alpha-*-netbsd* | x86_64-*-netbsd* | sparc64-*-netbsd*)
551                 IS_64_BITS_CPU=true
552     ;;
553 esac
554
555 ##########"
556
557 case "$CC" in
558      gcc-* | gcc | ccache*gcc | ccache*gcc-* )
559    ## With GNU Compiler
560
561    # enable the code coverage
562    if test "$enable_code_coverage" = yes; then
563     CODE_COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
564    fi
565
566    if test "$enable_debug_C" = yes; then
567       DEBUG_CFLAGS="-pipe -Wformat -Wshadow -Wfloat-equal -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations  -Wstrict-prototypes  -Wmissing-noreturn -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wwrite-strings -Winline -Wredundant-decls -Wall -Wchar-subscripts -Wextra  -Wuninitialized -Wno-format-y2k -Wmissing-format-attribute -Wno-missing-field-initializers -Wno-strict-aliasing  -Wold-style-definition -g3 -Wunsafe-loop-optimizations"
568       # used to be -O
569       # -D_FORTIFY_SOURCE=2
570       case "$host" in
571       *-linux-gnu )
572       # Only doing that under Linux
573         if test "$enable_debug_linker" = yes; then
574             LDFLAGS="$LDFLAGS -Wl,--warn-common,-x"
575         fi
576           DEBUG_CFLAGS="$DEBUG_CFLAGS -fdiagnostics-show-option -Werror=format-security"
577           ;;
578           esac
579    else
580       DEBUG_CFLAGS="-DNDEBUG"
581    fi
582
583    COMPILER_CFLAGS="-fno-stack-protector " # bug 3131
584    # Explictly disable the as needed. It was disable by default but Ubuntu
585    # activated it by default since release 11.04. See bug #8961.
586    # Once all cyclic dependencies have been dropped, this line could be removed.
587    # Check if linker supports --as-needed and --no-as-needed options
588    if $LD --help 2>/dev/null | grep no-as-needed > /dev/null; then
589       COMPILER_LDFLAGS="$COMPILER_LDFLAGS -Wl,--no-as-needed"
590    fi
591
592
593    case "$host" in
594      x86_64-*-linux-gnu | x86_64-linux-gnu)
595         ARCH_CFLAGS="-m64"
596     ;;
597      alpha-*-linux-gnu)
598         ARCH_CFLAGS="-mieee-with-inexact"
599         ARCH_LDFLAGS="-mieee-with-inexact"
600     ;;
601      powerpc-*-linux-gnu)
602         ARCH_CFLAGS="-D_GNU_SOURCE"
603     ;;
604      *-*-solaris*)
605         ARCH_CFLAGS="-DSVR4 -DSYSV -Dsolaris"
606     ;;
607    *-*-freebsd*)
608      ARCH_CFLAGS="-Dfreebsd"
609      ARCH_LDFLAGS="-lm"
610      ;;
611
612   alpha-*-netbsd*)
613     ARCH_CFLAGS="-Dnetbsd -mieee"
614     ARCH_FFLAGS="-Dnetbsd -mieee"
615     ;;
616
617   *-*-netbsd*)
618     ARCH_CFLAGS="-Dnetbsd"
619     ;;
620
621   *-*-darwin*)
622     ARCH_CFLAGS="$ARCH_CFLAGS -no_compact_linkedit"
623     ARCH_CXXFLAGS="$ARCH_CXXFLAGS -no_compact_linkedit"
624     ARCH_LDFLAGS="$ARCH_LDFLAGS -no_compact_linkedit"
625     # We need this to be passed to all linker commands
626     LDFLAGS="$LDFLAGS -no_compact_linkedit"
627
628     case "$F77" in
629          gfortran-*|gfortran)
630              # Extract from gfortran -v the version it has been built for
631                MAC_DETECTED_ARCH="`$F77 -v 2>&1|grep "Target:"|sed -e "s/Target: \([[a-z0-9A-Z_]]*\).*/\1/g"`"
632          ;;
633          *)
634         AC_MSG_WARN([gfortran not used. Could not detect the architecture. Switch to the default case: x86_64])
635         MAC_DETECTED_ARCH="x86_64"
636          ;;
637     esac
638     CC="$CC -arch $MAC_DETECTED_ARCH"
639     CXX="$CXX -arch $MAC_DETECTED_ARCH"
640     ;;
641 esac
642 ;; # end of the gcc case on the $CC
643    *)
644
645         ## CC compiler (not GCC)
646         if test "$enable_debug_C" != yes; then
647              ARCH_CFLAGS="-DNDEBUG"
648         fi
649
650 case "$host" in
651 # Dec Alpha OSF 4
652   alpha*-dec-osf4.*)
653       ARCH_CFLAGS="-std -ieee_with_inexact"
654       ARCH_LDFLAGS="-ieee_with_inexact"
655       ;;
656   alpha*-dec-osf*)
657       ARCH_CFLAGS="-ieee_with_inexact"
658       ARCH_LDFLAGS="-ieee_with_inexact"
659       ;;
660   rs6000-*-*) # IBM AIX RS 6000 (NO LONGER SUPPORTED)
661     ARCH_CFLAGS="-Daix -DSYSV"
662   ;;
663   mips-sgi-irix*) # SGI
664     ARCH_CFLAGS="-DSYSV -DSVR4"
665   ;;
666   *-*-hpux9.*)
667     ARCH_CFLAGS="-DSYSV -Dhpux"
668   ;;
669   *-*-hpux10.*) # HP 10
670     if test "$enable_debug_C" = yes; then
671       ARCH_CFLAGS="-DSYSV -Dhpux"
672     else
673       ARCH_CFLAGS="-DSYSV -Dhpux +Z +DAportable"
674     fi
675   ;;
676
677   *-*-hpux11.*) # HP 11
678     ARCH_CFLAGS="-DSYSV -Dhpux -Dhppa +Z +DAportable"
679   ;;
680   *-*-solaris*) # SUN SOLARIS
681     ARCH_CFLAGS="-DSVR4 -DSYSV -Dsolaris -I/usr/local/include/"
682     ARCH_LDFLAGS="-L/usr/local/lib/"
683   ;;
684 esac
685 ;; # end of not a gcc compiler
686 esac
687
688
689 # enable the code coverage
690 if test "$enable_code_coverage" = yes; then
691    AC_PATH_PROG(LCOV, lcov)
692    if test -z "$LCOV" ; then
693         AC_MSG_ERROR([Cannot find lcov. Please install it (package lcov under Debian) or remove the option --enable-code-coverage])
694    fi
695    AC_PATH_PROG(GENHTML, genhtml)
696    if test -z "$GENHTML" ; then
697         AC_MSG_ERROR([Cannot find genhtml. Please install it (package lcov under Debian) or remove the option --enable-code-coverage])
698    fi
699    CODE_COVERAGE_LDFLAGS="-coverage"
700 fi
701 AM_CONDITIONAL(CODE_COVERAGE, test "$enable_code_coverage" = yes)
702
703 # flag for possible compilations in configure
704 SCILIBS_CFLAGS=''
705 SCILIBS_CXXFLAGS=''
706 SCILIBS_FFLAGS=''
707
708 if test $IS_64_BITS_CPU = true -o "$MACOSX" = "1"; then
709    if test $f90compatible = false; then
710       AC_MSG_ERROR([64 bits support needs a fortran 90 compiler (try --with-gfortran).])
711    fi
712    AC_DEFINE([USE_DYNAMIC_STACK], [], [If we are building a 64 bits version])
713 fi
714
715 AM_CONDITIONAL(IS_64_BITS_CPU, test $IS_64_BITS_CPU = true)
716 AM_CONDITIONAL(USE_DYNAMIC_STACK, test $IS_64_BITS_CPU = true -o "$MACOSX" = "1")
717
718 ################
719 ## SSE
720 ## By default, for x86 CPU, enable the SSE.
721 ## Note that it is already the case with 64 bits CPU
722 ## (these extensions are enabled by default by gcc)
723 ################
724
725 case "$host" in
726      i*86-linux-gnu|i*86-*-linux-gnu)
727         SSE_CFLAGS="-msse"
728         SSE_FFLAGS="-msse"
729         SSE_CXXFLAGS="-msse"
730      ;;
731 esac
732
733 #######################
734 ## test for underscores (name mangling issues between C and fortran)
735 #######################
736 AC_CHECK_UNDERSCORE_FORTRAN()
737
738
739 #################
740 ## HDF5
741 #################
742
743 AC_HDF5()
744 # The Java detection is done after in this file.
745
746 #################
747 ## XCOS
748 #################
749
750 AC_ARG_WITH(xcos,
751     AC_HELP_STRING([--without-xcos],[Disable Xcos]))
752
753 AC_ARG_WITH(modelica,
754     AC_HELP_STRING([--without-modelica],[Disable the OCaml module (modelica)]))
755
756
757 if test "$with_gui" = no; then
758    AC_MSG_WARN([GUI is disabled. Disabling then xcos])
759    with_xcos=no
760 fi
761
762 XCOS_ENABLE=no
763
764 if test "$with_xcos" != no -a "$with_gui" != no; then
765    AC_DEFINE([WITH_XCOS], [], [With XCOS])
766
767    save_LIBS="$LIBS"
768
769    AC_CHECK_LIB([rt], [clock_gettime],
770               [RT_LIB="-lrt";
771               AC_DEFINE([HAVE_CLOCK_GETTIME], [1],[Whether clock_gettime is available]) ],
772         [AC_MSG_WARN([librt: library missing (Cannot find symbol clock_gettime). Check if librt is installed (it is usually provided by the libc) and if the version is correct])]
773    )
774    LIBS="$save_LIBS"
775    AC_SUBST(RT_LIB)
776
777
778 #################
779 ## ocaml which only called when using Xcos
780 #################
781
782    if test "$with_modelica" != no; then
783       AC_CHECK_PROG_OCAML()
784    fi
785    XCOS_ENABLE=yes
786
787 fi
788
789 AC_SUBST(XCOS_ENABLE)
790
791 AM_CONDITIONAL(OCAML, test "$with_modelica" != no -a "$OCAMLC" != no -a "$OCAMLOPT" != no)
792 AM_CONDITIONAL(XCOS, test "$XCOS_ENABLE" != no)
793
794 ###########################
795 ## test for JAVA compiler
796 ###########################
797
798 if test "$with_javasci" != no -o "$with_gui" != no -o "$enable_build_help" != no; then
799
800    # See if --with-jdk command line argument is given
801      # Try to detect the installed JVM, this could be controlled
802      # by the above --with options
803      AC_JAVA_WITH_JDK
804      AC_JAVA_DETECT_JVM
805      case "$ac_java_jvm_version" in
806         1.6 | 1.7)
807         ;;
808         *)
809             AC_MSG_ERROR([Wrong version of Java. Expected at least 1.6. Found $ac_java_jvm_version])
810         ;;
811      esac
812
813    if test "$ac_java_jvm_name" = "jdk"; then
814         JAVA_HOME=$ac_java_jvm_dir
815         JAVA_VERSION=$ac_java_jvm_version
816 #     AC_JAVA_TOOLS
817         AC_JAVA_JNI_INCLUDE
818         JAVA_JNI_INCLUDE=$ac_java_jvm_jni_include_flags
819
820         case "$host_os" in
821              *Darwin* | *darwin*)
822                # Mac OS X does not link against the lib but uses -framework
823                JAVA_JNI_LIBS="-framework JavaVM"
824              ;;
825              *)
826                AC_JAVA_JNI_LIBS
827                JAVA_JNI_LIBS=$ac_java_jvm_jni_lib_flags
828                JAVA_JNI_LIBS_PRELOAD=$ac_java_jvm_ld_preload
829              ;;
830         esac
831
832         AC_JAVA_CLASSPATH
833         JAVA_CLASSPATH=$ac_java_classpath
834         AC_JAVA_TOOLS
835         AC_JAVA_ANT
836
837         case "$host_os" in
838              *Darwin* | *darwin*)
839                   JAVA_HOME=""
840              ;;
841         esac
842
843
844         if test "$with_gui" != no; then
845
846                 if test $XCOS_ENABLE = yes; then
847                    # jgraphx
848                    AC_JAVA_CHECK_PACKAGE([jgraphx],[com.mxgraph.model.mxCell],[Diagram design])
849                    JGRAPHX=$PACKAGE_JAR_FILE
850                    AC_SUBST(JGRAPHX)
851
852                    AC_JAVA_CHECK_VERSION_PACKAGE([jgraphx],[import com.mxgraph.view.mxGraph;],$JGRAPHX,[1.8.0.0],[mxGraph.VERSION],[],[])
853
854                 fi
855
856
857                 # scirenderer
858                 AC_JAVA_CHECK_PACKAGE([scirenderer],[org.scilab.forge.scirenderer.PackageInfo],[Scilab Renderer])
859                 SCIRENDERER=$PACKAGE_JAR_FILE
860                 AC_SUBST(SCIRENDERER)
861
862                 AC_JAVA_CHECK_VERSION_PACKAGE([scirenderer],[import org.scilab.forge.scirenderer.PackageInfo;],$SCIRENDERER,[1.0.2],[PackageInfo.VERSION])
863
864                # Docking system
865                 AC_JAVA_CHECK_PACKAGE([flexdock],[org.flexdock.docking.DockingManager],[Scilab Gui])
866                 FLEXDOCK=$PACKAGE_JAR_FILE
867                 AC_SUBST(FLEXDOCK)
868
869                 AC_JAVA_CHECK_VERSION_PACKAGE([flexdock],[import org.flexdock.util.Utilities;],$FLEXDOCK,[1.2.0],[Utilities.VERSION])
870
871                 # Swing look&feel implementations
872                 AC_JAVA_CHECK_PACKAGE([looks],[com.jgoodies.looks.common.MenuItemRenderer],[Scilab Gui - Look and feel],"yes")
873                 LOOKS=$PACKAGE_JAR_FILE
874
875                 # Named differently under ArchLinux or Fedora
876                 if test -z "$LOOKS"; then
877                     AC_JAVA_CHECK_PACKAGE([jgoodies-looks],[com.jgoodies.looks.common.MenuItemRenderer],[Scilab Gui - Look and feel])
878                     LOOKS=$PACKAGE_JAR_FILE
879                 fi
880                 AC_SUBST(LOOKS)
881
882                 #  Skin Look and Feel
883                 AC_JAVA_CHECK_PACKAGE([skinlf],[com.l2fprod.util.AccessUtils],[Scilab Gui - Skin Look and Feel])
884                 SKINLF=$PACKAGE_JAR_FILE
885                 AC_SUBST(SKINLF)
886
887                 # JOGL 2
888                 AC_JAVA_CHECK_PACKAGE([jogl2],[javax.media.opengl.glu.GLUnurbs],[Scilab 3D rendering - Version 2.0])
889                 JOGL2=$PACKAGE_JAR_FILE
890                 AC_SUBST(JOGL2)
891
892                 if test "$MACOSX" = 1; then
893                    echo "Check of the presence of libjogl.jnilib and libjogl_awt.jnilib disabled under Mac OS X"
894                 else
895                    LDFLAGS_save=$LDFLAGS
896                    # Provide known paths where distribs/OS can store JNI libs
897                    LDFLAGS="$LDFLAGS -L/usr/lib/jni -L/usr/lib64/jni"                   # Debian
898                    LDFLAGS="$LDFLAGS -L/usr/lib/java -L/usr/lib64/java"                 # jpackage.org
899                    LDFLAGS="$LDFLAGS -L/usr/lib/jogl -L/usr/lib64/jogl"                 # RedHat
900                    LDFLAGS="$LDFLAGS -L$SCI_SRCDIR/thirdparty -L$SCI_SRCDIR/bin"        # Scilab thirdparties
901                    AC_CHECK_LIB([jogl_desktop], [glTexParameterf], [JOGL2_LIBS="-ljogl"],[AC_MSG_WARN([Could not link against -ljogl_desktop. Will try against -ljogl2 -lGL])])
902                    if test -z "$JOGL2_LIBS"; then # The previous test failed add more options to the LDFLAGS
903                        # the space after "jogl" in the following line is on
904                        # purpose to disable the cache
905                           AC_CHECK_LIB([jogl_desktop ], [glTexParameterf],
906                        [JOGL2_LIBS="-ljogl_desktop -lGL"],
907                        [AC_MSG_ERROR(["libjogl: Library
908 missing (Cannot find symbol glTexParameterf). Check if libjogl - C/Java (JNI)
909 interface for JOGL2 - or libGL (OpenGL library) are installed and if the version is correct. Note that you might have to update etc/librarypath.xml to provide the actual path the the JNI libraries."])],
910                        [-lGL])
911                    fi
912
913                    LDFLAGS=$LDFLAGS_save
914                 fi
915
916                 # JoGL Native <=> Java connector
917                 AC_JAVA_CHECK_PACKAGE([gluegen2-rt],[jogamp.common.os.MachineDescriptionRuntime],[Scilab 3D rendering])
918                 GLUEGEN2_RT=$PACKAGE_JAR_FILE
919                 AC_SUBST(GLUEGEN2_RT)
920
921                 if test "$MACOSX" = 1; then
922                    echo "Check of the presence of libgluegen-rt.jnilib disabled under Mac OS X"
923                 else
924                    LDFLAGS_save=$LDFLAGS
925                    # Provide known paths where distribs/OS can store JNI libs
926                    LDFLAGS="$LDFLAGS -L/usr/lib/jni -L/usr/lib64/jni"                   # Debian
927                    LDFLAGS="$LDFLAGS -L/usr/lib/java -L/usr/lib64/java"                 # jpackage.org
928                    LDFLAGS="$LDFLAGS -L/usr/lib/gluegen -L/usr/lib64/gluegen"           # RedHat
929                    LDFLAGS="$LDFLAGS -L$SCI_SRCDIR/thirdparty -L$SCI_SRCDIR/bin"        # Scilab thirdparties
930                    symbol="Java_jogamp_common_jvm_JVMUtil_initialize"
931                    AC_CHECK_LIB([gluegen2-rt], [$symbol], [GLUEGEN_RT_LIBS="-lgluegen-rt"],
932                    [AC_MSG_ERROR([libgluegen2-rt: Library missing (Cannot find symbol $symbol). Check if libgluegen-rt - C/Java (JNI) interface for GLUEGEN2 - is installed and if the version is correct. Note that you might have to update etc/librarypath.xml to provide the actual path the the JNI libraries.])],
933                    [-ldl])
934                    LDFLAGS=$LDFLAGS_save
935                 fi
936
937                 # Jhall
938                 AC_JAVA_CHECK_PACKAGE([jhall],[javax.help.JHelp],[Scilab Help Browser],"yes")
939                 JHALL=$PACKAGE_JAR_FILE
940
941                 # Named differently under Mandriva or Fedora
942                 if test -z "$JHALL"; then
943                     AC_JAVA_CHECK_PACKAGE([javahelp2],[javax.help.JHelp],[Scilab Help Browser])
944                     JHALL=$PACKAGE_JAR_FILE
945                 fi
946                 AC_SUBST(JHALL)
947
948                 # Console API
949                 AC_JAVA_CHECK_PACKAGE([jrosetta-API],[com.artenum.rosetta.interfaces.core.ConsoleConfiguration],[JRosetta : Console API Artenum / Scilab],"yes")
950                 JROSETTA_API=$PACKAGE_JAR_FILE
951                 if test -z "$JROSETTA_API"; then
952                         AC_JAVA_CHECK_PACKAGE([jrosetta-api],[com.artenum.rosetta.interfaces.core.ConsoleConfiguration],[JRosetta : Console API Artenum / Scilab])
953                         JROSETTA_API=$PACKAGE_JAR_FILE
954                 fi
955                 AC_SUBST(JROSETTA_API)
956
957                 # Console Core
958                 AC_JAVA_CHECK_PACKAGE([jrosetta-engine],[com.artenum.rosetta.core.action.AbstractConsoleAction],[JRosetta : Console Core Artenum / Scilab])
959                 JROSETTA_ENGINE=$PACKAGE_JAR_FILE
960                 AC_SUBST(JROSETTA_ENGINE)
961                 AC_JAVA_CHECK_VERSION_PACKAGE([jrosetta-engine],[import com.artenum.rosetta.util.ConfigurationBuilder;],$JROSETTA_ENGINE,[1.0.4],[ConfigurationBuilder.getVersion()])
962
963
964                 # MathML rendering solution
965                 # Used in both graphic & help
966                 AC_JAVA_CHECK_PACKAGE([jeuclid-core],[net.sourceforge.jeuclid.LayoutContext],[MathML rendering solution (at least version 3.1.X)])
967                 JEUCLID_CORE=$PACKAGE_JAR_FILE
968                 AC_SUBST(JEUCLID_CORE)
969
970
971                 ################ Mandatory for graphic_export features #####
972                 # XML to PDF/other Translator
973                 AC_JAVA_CHECK_PACKAGE([fop],[org.apache.fop.pdf.PDFInfo],[XML to PDF Translator (fop)])
974                 FOP=$PACKAGE_JAR_FILE
975                 AC_SUBST(FOP)
976
977                 # xml.apache.org SVG Library (under mandriva for example)
978                 AC_JAVA_CHECK_PACKAGE([batik-all],[org.apache.batik.parser.Parser],[Apache SVG Library],"yes")
979                 BATIK=$PACKAGE_JAR_FILE
980
981                 if test -z "$BATIK"; then
982                    # Other other distribs
983                    AC_JAVA_CHECK_PACKAGE([batik],[org.apache.batik.parser.Parser],[Apache SVG Library])
984                    BATIK=$PACKAGE_JAR_FILE
985                 fi
986                 AC_SUBST(BATIK)
987                 AC_JAVA_CHECK_VERSION_PACKAGE([batik],[import org.apache.batik.Version;],$BATIK,[1.7],[Version.getVersion()])
988
989                 # Commons I/O library
990                 AC_JAVA_CHECK_PACKAGE([commons-io],[org.apache.commons.io.output.CountingOutputStream],[Commons I/O library])
991                 COMMONS_IO=$PACKAGE_JAR_FILE
992                 AC_SUBST(COMMONS_IO)
993
994                 # XML graphics common
995                 AC_JAVA_CHECK_PACKAGE([xmlgraphics-commons],[org.apache.xmlgraphics.util.Service],[Commons graphics library])
996                 XMLGRAPHICS_COMMONS=$PACKAGE_JAR_FILE
997                 AC_SUBST(XMLGRAPHICS_COMMONS)
998
999                 # Avalon Framework (PDF)
1000                 AC_JAVA_CHECK_PACKAGE([avalon-framework],[org.apache.avalon.framework.configuration.ConfigurationException],[Common framework for Java server application])
1001                 AVALON_FRAMEWORK=$PACKAGE_JAR_FILE
1002                 AC_SUBST(AVALON_FRAMEWORK)
1003
1004                 # XML API EXT (conversion of a SVG => PNG)
1005                 AC_JAVA_CHECK_PACKAGE([xml-apis-ext],[org.w3c.dom.svg.SVGDocument],[XML Commons external code],"yes")
1006                 XML_APIS_EXT=$PACKAGE_JAR_FILE
1007
1008                 if test -z "$XML_APIS_EXT"; then
1009                     # Other other distribs (Ex: Fedora/Redhat)
1010                     AC_JAVA_CHECK_PACKAGE([xml-commons-apis-ext],[org.w3c.dom.svg.SVGDocument],[XML Commons external code])
1011                     XML_APIS_EXT=$PACKAGE_JAR_FILE
1012                 fi
1013                 AC_SUBST(XML_APIS_EXT)
1014
1015                 ################ END Mandatory for graphic_export features #####
1016
1017
1018                 # Logging (flexdock dep)
1019                 AC_JAVA_CHECK_PACKAGE([commons-logging],[org.apache.commons.logging.LogFactory],[Apache logging])
1020                 COMMONS_LOGGING=$PACKAGE_JAR_FILE
1021                 AC_SUBST(COMMONS_LOGGING)
1022
1023                 # JLaTeXMath
1024                 AC_JAVA_CHECK_PACKAGE([jlatexmath],[org.scilab.forge.jlatexmath.TeXFormula],[LaTex Rendering])
1025                 JLATEXMATH=$PACKAGE_JAR_FILE
1026                 AC_SUBST(JLATEXMATH)
1027
1028                 AC_JAVA_CHECK_VERSION_PACKAGE([jlatexmath],[import org.scilab.forge.jlatexmath.TeXFormula;],$JLATEXMATH,[1.0.0],[TeXFormula.VERSION])
1029
1030                 AC_DEFINE([WITH_GUI],[],[With the JAVA stuff (GUI, Console, JOGL...)])
1031
1032         fi
1033
1034         # Checkstyle (code checking)
1035         AC_JAVA_CHECK_PACKAGE([checkstyle],[com.puppycrawl.tools.checkstyle.CheckStyleTask],[Checkstyle - code checking],"yes")
1036         CHECKSTYLE=$PACKAGE_JAR_FILE
1037         AC_SUBST(CHECKSTYLE)
1038
1039         # Commons beanutils (dependency of checkstyle)
1040         AC_JAVA_CHECK_PACKAGE([commons-beanutils],[org.apache.commons.beanutils.Converter],[Bean utility],"yes")
1041         COMMONS_BEANUTILS=$PACKAGE_JAR_FILE
1042         AC_SUBST(COMMONS_BEANUTILS)
1043
1044         # antlr (dependency of checkstyle)
1045         AC_JAVA_CHECK_PACKAGE([antlr],[antlr.TokenStreamException],[language tool for constructing recognizers],"yes")
1046         ANTLR=$PACKAGE_JAR_FILE
1047         AC_SUBST(ANTLR)
1048
1049         # Junit 4 (java unitary test)
1050         AC_JAVA_CHECK_PACKAGE([junit4],[org.junit.Assert],[Junit4 - Unit tests],"yes")
1051         JUNIT4=$PACKAGE_JAR_FILE
1052         AC_SUBST(JUNIT4)
1053
1054         # Cobertura (java code coverage)
1055         AC_JAVA_CHECK_PACKAGE([cobertura],[net.sourceforge.cobertura.merge.Main],[cobertura - Java code coverage],"yes")
1056         COBERTURA=$PACKAGE_JAR_FILE
1057         AC_SUBST(COBERTURA)
1058
1059         # ASM (a dependency of Cobertura)
1060         AC_JAVA_CHECK_PACKAGE([asm3],[org.objectweb.asm.Type],[Java bytecode manipulation (dep of cobertura)],"yes")
1061         ASM3=$PACKAGE_JAR_FILE
1062         AC_SUBST(ASM3)
1063         if test -z "$ASM3"; then
1064                 AC_JAVA_CHECK_PACKAGE([asm],[org.objectweb.asm.Type],[Java bytecode manipulation (dep of cobertura)],"yes")
1065                 ASM3=$PACKAGE_JAR_FILE
1066         fi
1067
1068     else
1069         AC_MSG_WARN([Sun javac not found: I will not build the java interface])
1070         if test "$ac_java_jvm_name" != ""; then
1071             AC_MSG_WARN([We do not support $ac_java_jvm_name yet])
1072         fi
1073     fi
1074     AC_SUBST(JAVA_JNI_INCLUDE)
1075     AC_SUBST(JAVA_JNI_LIBS)
1076     AC_SUBST(JAVA_HOME)
1077
1078
1079     if test "$enable_debug_java" = yes; then
1080         JAVAC_DEBUG="on"
1081     else
1082         JAVAC_DEBUG="off"
1083     fi
1084     AC_SUBST(JAVAC_DEBUG)
1085
1086     if test "$enable_build_swig" != no -a "$enable_build_swig" != ""; then
1087         SWIG_PROG()
1088         SWIG_ENABLE_JAVA()
1089         AC_SUBST(SWIG_BIN)
1090         AC_SUBST(SWIG_JAVA)
1091
1092     fi
1093
1094     # Giws is the equivalent of Swig developed by the Scilab team
1095     # in order to provide a wrapper to Java from C/C++
1096     if test "$enable_build_giws" != no -a "$enable_build_giws" != ""; then
1097         AC_GIWS([1.3.0])
1098     fi
1099 fi
1100
1101 JAVA_ENABLE=yes
1102
1103 if test -z "$JAVAC"; then
1104    JAVA_ENABLE=no
1105 fi
1106
1107 AC_SUBST(JAVA_ENABLE)
1108
1109 # Xcos is not checked here because gui=no disables it
1110 AM_CONDITIONAL(NEED_JAVA, test "$with_javasci" != no -o "$with_gui" != no -o "$enable_build_help" != no)
1111 AM_CONDITIONAL(GUI, test "$with_gui" != no)
1112 AM_CONDITIONAL(JAVASCI, test "$with_javasci" != no)
1113 AM_CONDITIONAL(SWIG, test "$enable_build_swig" != no -a "$enable_build_swig" != "")
1114 AM_CONDITIONAL(GIWS, test "$enable_build_giws" != no  -a "$enable_build_giws" != "")
1115
1116 ##############################################################
1117 ## GUI module
1118 ##############################################################
1119
1120 GUI_ENABLE=no
1121
1122 if test "$JAVA_ENABLE" != no; then
1123    GUI_ENABLE=yes
1124 fi
1125
1126 if test "$with_gui" != no; then
1127    GUI_ENABLE=yes
1128 fi
1129
1130 AC_SUBST(GUI_ENABLE)
1131
1132 ##############################################################
1133 ## test for functions in standard C library and C math library
1134 ##############################################################
1135
1136 # Provided by unistd.h
1137 AC_CHECK_FUNCS([sleep] [usleep] [dup2] [getcwd] [getpagesize] [getpass])
1138 AC_CHECK_FUNCS([rmdir])
1139
1140 AC_CHECK_FUNC([getwd],AC_DEFINE([HAVE_GETWD],[1],[Define to 1 if you have the `getwd' function.]),[AC_DEFINE([getwd(x)],[getcwd(x,1024)],[Don't use getwd but getcwd])])
1141
1142 # Provided by <regex.h>
1143 AC_CHECK_FUNCS([regcomp])
1144
1145 # Provided by stdlib.h
1146 AC_CHECK_FUNCS([atexit] [putenv] [setenv])
1147
1148 # Provided by String.h
1149 AC_CHECK_FUNCS([bzero] [memmove] [memset] [strcasecmp] [strerror] [strchr] [strdup] [strpbrk] [strrchr] [strstr] [strtol])
1150
1151 # Provided by select.h
1152 AC_CHECK_FUNCS([select])
1153
1154 # Provided by pwd.h
1155 AC_CHECK_FUNCS([endpwent])
1156
1157 # Provided by netdb.h
1158 AC_CHECK_FUNCS([gethostbyaddr] [gethostbyname] [gethostname])
1159
1160 # Provided by time.h
1161 AC_CHECK_FUNCS([gettimeofday])
1162
1163 # Provided by ctype.h
1164 AC_CHECK_FUNCS([isascii])
1165
1166 # Provided by wctype.h
1167 AC_CHECK_FUNCS([iswprint])
1168
1169 # Provided by types.h
1170 AC_CHECK_FUNCS([mkdir])
1171
1172 # Provided by mman.h
1173 AC_CHECK_FUNCS([munmap])
1174
1175 # Provided by signal.h
1176 AC_CHECK_FUNCS([strsignal])
1177
1178
1179 # Check of the libm (lib math). Macro provided by libtool.
1180 save_LDFLAGS="$LDFLAGS"
1181 LT_LIB_M()
1182
1183 # Provided by math.h
1184
1185 LDFLAGS="$LDFLAGS $LIBM"
1186 AC_CHECK_FUNCS([pow] [sqrt] [finite] [floor] [exp10])
1187
1188 ### If isinf exists or not (used to not be the case under Solaris)
1189 ### See bug #4164
1190 AC_CHECK_FUNC([isinf],,[
1191         AC_DEFINE([isinf(x)],[(!finite(x) && x==x)],[Provide a macro to do isinf])
1192 ])
1193 LIBS="$LIBS $LIBM"
1194 LDFLAGS="$save_LDFLAGS"
1195
1196 # Provided by regex.h
1197 AC_CHECK_FUNCS([re_comp])
1198
1199 # Provided by socket.h
1200 AC_CHECK_FUNCS([socket])
1201
1202 # Provided by utsname.h
1203 AC_CHECK_FUNCS([uname])
1204
1205 # Provided by wtloop.c
1206 AC_CHECK_FUNCS([setlocale])
1207
1208 # Function memcmp used in modules/fileio/src/c/xls.c
1209 AC_FUNC_MEMCMP
1210
1211 # function stat used in modules/core/src/c/link_std.c
1212 AC_FUNC_STAT
1213
1214 # function strtod used in modules/core/src/c/getval.c
1215 AC_FUNC_STRTOD
1216
1217 ########################
1218 ## test for header files
1219 ########################
1220
1221 AC_CHECK_HEADERS([limits.h values.h])
1222
1223 AC_CHECK_HEADERS([fcntl.h float.h libintl.h locale.h malloc.h netdb.h netinet/in.h nlist.h sgtty.h stddef.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h sys/timeb.h sys/utsname.h syslog.h term.h termcap.h termio.h termios.h wchar.h wctype.h time.h])
1224
1225 # check header dirent
1226 AC_HEADER_DIRENT
1227
1228 # static struct timeval defined or not | used in modules/core/src/c/timer.c
1229 AC_HEADER_TIME
1230
1231 # check if the specific header is available or not | used in modules/core/src/c/link_SYSV.c
1232 AC_HEADER_SYS_WAIT
1233
1234
1235 #######################
1236 ## Test for structures ##
1237 #######################
1238 AC_CHECK_MEMBERS([struct stat.st_blksize])
1239 AC_CHECK_MEMBERS([struct stat.st_rdev])
1240
1241
1242 #######################
1243 ## MISC Test
1244 #######################
1245
1246 # gettext.  See http://www.gnu.org/software/hello/manual/gettext/AM_005fGNU_005fGETTEXT.html
1247 AM_GNU_GETTEXT([external])
1248 AM_GNU_GETTEXT_VERSION([0.16])
1249
1250 # function closedir used in modules/metanet/src/c/files.c
1251 AC_FUNC_CLOSEDIR_VOID
1252
1253 # Signals used in modules/core/src/c/realmain.c
1254 AC_TYPE_SIGNAL
1255
1256 # struct tm used in modules/core/src/c/history.c
1257 AC_STRUCT_TM
1258
1259 # st_blocks in the struct in modules/io/sci_gateway/c/intfilestat.c
1260 AC_STRUCT_ST_BLOCKS
1261
1262
1263 ##################
1264 ## termcap library
1265 ##################
1266
1267 # some systems may have a system curses implementation as well as ncurses
1268 # installed.  We need to be consistent in making sure we get the correct
1269 # library to go with the correct header and also provide a way for the user
1270 # to have some control over which is picked when both are available.
1271 #
1272 # For now, just check for -lcurses and then -lncurses.  The user control
1273 # may need to be revisited
1274
1275 TERMCAP_LIB=no
1276
1277 # Various observations:
1278 #
1279 #  ncurses
1280 #    - installs ncurses.h and possibly curses.h as a link to ncurses.h
1281 #    - installs -lncurses.
1282 #    - need to include term.h for tgetent() but tgetent() is in -lncurses.a
1283 #
1284 # curses as found in NetBSD-4 and NetBSD-5
1285 #    - installs curses.h
1286 #    - need to include termcap.h and link with -ltermcap for tgetent()
1287 #
1288
1289 AC_CHECK_LIB([curses],[main])
1290 if test $ac_cv_lib_curses_main = no ; then
1291     AC_CHECK_LIB([ncurses],[main])
1292 fi
1293
1294 # make sure we have what we need for tgetent
1295 AC_SEARCH_LIBS([tgetent],[termcap])
1296
1297 AC_CHECK_HEADERS([ncurses.h curses.h])
1298
1299 if test "x$ac_cv_lib_curses_main" = "xyes" -o "x$ac_cv_lib_ncurses_main" = "xyes" ; then
1300   AC_DEFINE([HAVE_TERMCAP],[],[Have Term Cap])
1301 else
1302  AC_MSG_ERROR([No termcap library detected. Please install ncurses dev library (or termcap library)])
1303 fi
1304
1305 ##################
1306 ## other libraries
1307 ##################
1308
1309 AC_CHECK_LIB(dl, dlopen)
1310
1311 AC_SEARCH_LIBS([pthread_join],[pthread])
1312
1313 #################
1314 ## FFTW
1315 #################
1316
1317 AC_ARG_WITH(fftw,
1318     AC_HELP_STRING([--without-fftw],[Disable the interface to the FFTW 3 library]))
1319
1320 FFTW_ENABLE=no
1321 if test "$with_fftw" != no; then
1322    AC_FFTW()
1323    FFTW_ENABLE=yes
1324 fi
1325
1326 AC_SUBST(FFTW_ENABLE)
1327 AM_CONDITIONAL(FFTW, test "$with_fftw" != no)
1328
1329
1330 #################
1331 ## MPI
1332 #################
1333
1334 # Not in Scilab 5.0
1335 #AC_ARG_WITH(mpi,
1336 #    [  --with-mpi               compile with MPI library])
1337 #
1338 #if test "$with_mpi" = yes; then
1339 #   AC_OPENMPI()
1340 #   # We will have to detect other implementation of OpenMPI
1341 #fi
1342 #AM_CONDITIONAL(MPI, test "$with_mpi" = yes)
1343
1344 #################
1345 ## OpenMP
1346 #################
1347
1348 AC_ARG_WITH(openmp,
1349     AC_HELP_STRING([--without-openmp],[Disable the usage of OpenMP (parallelization of some algoritms)]))
1350
1351 OPENMP_ENABLE=no
1352 if test "$with_openmp" != no; then
1353 #   AC_OPENMP
1354     OPENMP_CFLAGS="-fopenmp"
1355     OPENMP_CXXFLAGS="-fopenmp"
1356     OPENMP_LIBS="-lgomp"
1357
1358     AC_CHECK_HEADERS([omp.h], [],
1359      [AC_MSG_ERROR([Could not find omp.h])])
1360
1361     OPENMP_ENABLE=yes
1362 fi
1363 AC_SUBST(OPENMP_ENABLE)
1364 AC_SUBST(OPENMP_CFLAGS)
1365 AC_SUBST(OPENMP_CXXFLAGS)
1366 AC_SUBST(OPENMP_LIBS)
1367
1368 AM_CONDITIONAL(OPENMP, test "$with_openmp" != no)
1369
1370
1371 #######################
1372 ## Test for libxml
1373 #######################
1374
1375 AC_LIBXML2()
1376
1377 #######################
1378 ## Test for gettext
1379 #######################
1380
1381 ALL_LINGUAS="en_US fr_FR zh_CN zh_TW ru_RU ca_ES de_DE es_ES pt_BR ja_JP it_IT uk_UA pl_PL cs_CZ"
1382 ALL_LINGUAS_DOC="en_US fr_FR pt_BR ja_JP ru_RU"
1383
1384 AC_ARG_ENABLE(build-localization,
1385         AC_HELP_STRING([--disable-build-localization],[Disable the localization build])
1386         )
1387 BUILD_LOCALIZATION_ENABLE=no
1388
1389 if test "$enable_build_localization" != no; then
1390
1391    AC_SUBST(ALL_LINGUAS)
1392    AC_SUBST(ALL_LINGUAS_DOC)
1393    AC_CHECK_FUNCS([bind_textdomain_codeset])
1394
1395    AC_PATH_PROG(MSGCAT, msgcat, no)
1396 #   AC_PATH_PROG(MSGFMT, msgfmt, no)
1397 #   AC_PATH_PROG(XGETTEXT, xgettext, no)
1398
1399    if test x$MSGFMT = xno; then
1400       AC_ERROR([The msgfmt command is required to build Scilab.  If it is installed on your system, ensure that it is in your path.  If it is not, install GNU gettext to continue or use the option --disable-build-localization ])
1401       fi
1402     if test x$MSGCAT = xno; then
1403       AC_ERROR([The msgcat command is required to build Scilab.  If it is installed on your system, ensure that it is in your path.  If it is not, install GNU gettext to continue or use the option --disable-build-localization ])
1404     fi
1405     BUILD_LOCALIZATION_ENABLE=yes
1406 fi
1407 AM_CONDITIONAL(GENERATE_LOCALIZATION_FILES, test "$BUILD_LOCALIZATION_ENABLE" = yes)
1408
1409 #######################
1410 ## Test for blas/Atlas and lapack
1411 #######################
1412 AC_MSG_CHECKING([if BLAS, ATLAS or MKL is available])
1413 echo ""
1414 ACX_BLAS(
1415         [AC_MSG_RESULT([$BLAS_TYPE found])]
1416         ,
1417         AC_MSG_ERROR([Impossible to find a BLAS compatible library (see BLAS or ATLAS).])
1418         )
1419
1420 AC_MSG_CHECKING([if LAPACK is available])
1421 echo ""
1422 ACX_LAPACK(
1423         [AC_MSG_RESULT([$LAPACK_TYPE found])],
1424         AC_MSG_ERROR([Impossible to find the LAPACK library.])
1425         )
1426
1427
1428 AC_ARG_WITH(arpack-ng,
1429     AC_HELP_STRING([--without-arpack-ng],[Disable the interface to ARPACK-NG]))
1430
1431 ARPACK_NG=no
1432 if test "$with_arpack_ng" != no; then
1433    ARPACK_NG=yes
1434    AC_MSG_CHECKING([if ARPACK-NG is available])
1435 echo ""
1436 ACX_ARPACK(
1437         [AC_MSG_RESULT([ARPACK-NG library found])],
1438         AC_MSG_ERROR([Impossible to find the ARPACK library. Please note that arpack was bundled with version prior to 5.4.0 and Scilab requires arpack-ng ( http://forge.scilab.org/index.php/p/arpack-ng/ ).])
1439         )
1440
1441 CHECK_ARPACK_OK(
1442 [AC_MSG_RESULT([Working ARPACK-NG library found (probably ARPACK-NG or a patched version of ARPACK)])],
1443 [AC_MSG_ERROR([ARPACK library found, but seems not to work properly. Please make sure you are using arpack-ng])
1444 ])
1445 else
1446    AC_MSG_CHECKING([Skip ARPACK-NG detection])
1447 fi
1448
1449 AM_CONDITIONAL(ARPACK_NG, test "$ARPACK_NG" != "no")
1450
1451
1452 #################
1453 ## UMFPACK
1454 #################
1455
1456 AC_ARG_WITH(umfpack,
1457     AC_HELP_STRING([--without-umfpack],[Disable the interface to the UMFPACK library]))
1458
1459 UMFPACK_ENABLE=no
1460 if test "$with_umfpack" != no; then
1461    AC_UMFPACK([$BLAS_LIBS])
1462    UMFPACK_ENABLE=yes
1463 fi
1464
1465 AC_SUBST(UMFPACK_ENABLE)
1466 AM_CONDITIONAL(UMFPACK, test "$with_umfpack" != no)
1467
1468 #######################
1469 ## Test for PCRE
1470 #######################
1471
1472 AC_PCRE()
1473
1474 #################
1475 ## Tcl/Tk library
1476 #################
1477
1478 WITH_TKSCI=no
1479 if test "$with_tk" != no; then
1480    if test "$MACOSX" = "1"; then
1481       AC_MSG_ERROR([Due to technical constraints, Tcl/Tk must be disabled under Mac OS X (--without-tk)])
1482    fi
1483
1484     # check user arguments
1485     USER_TCL_LIB_PATH=""
1486     USER_TCL_INC_PATH=""
1487     AC_ARG_WITH(tcl-library,
1488         AC_HELP_STRING([--with-tcl-library=DIR],[Set the path to the TCL library]),
1489         [  USER_TCL_LIB_PATH=$withval
1490     ])
1491     AC_ARG_WITH(tcl-include,
1492         AC_HELP_STRING([--with-tcl-include=DIR],[Set the path to the TCL headers]),
1493         [  USER_TCL_INC_PATH=$withval
1494     ])
1495
1496     USER_TK_LIB_PATH=$USER_TCL_LIB_PATH
1497     USER_TK_INC_PATH=$USER_TCL_INC_PATH
1498
1499     AC_ARG_WITH(tk-library,
1500         AC_HELP_STRING([--with-tk-library=DIR],[Set the path to the TK library]),
1501         [  USER_TK_LIB_PATH=$withval
1502     ])
1503
1504     AC_ARG_WITH(tk-include,
1505         AC_HELP_STRING([--with-tk-include=DIR],[Set the path to the TK headers]),
1506         [  USER_TK_INC_PATH=$withval
1507     ])
1508
1509 ###########################
1510 ########## X11 checks
1511 ###########################
1512         ## This check is mandatory since tk needs Xlib headers and libs
1513         AC_PATH_XTRA
1514         ##
1515
1516     saved_cflags="$CFLAGS"
1517     saved_ldflags="$LDFLAGS"
1518     saved_cppflags="$CXXFLAGS"
1519
1520     AC_CHECK_LIB([dl], [main], [TCLTK_LIBS=" -ldl"])
1521     AC_CHECK_TCLTK
1522
1523     # set variables
1524     if test "$WITH_TKSCI" = yes; then
1525         AC_DEFINE([WITH_TK], [], [With TK])
1526     else
1527         AC_MSG_ERROR([TCL/TK not found. Use --without-tk or specify the librairies and include paths manually])
1528     fi
1529
1530     AC_SUBST(TCLTK_LIBS)
1531     AC_SUBST(TCL_INC_PATH)
1532     AC_SUBST(TK_INC_PATH)
1533
1534 fi
1535 AC_SUBST(WITH_TKSCI)
1536 AM_CONDITIONAL(TCLTK, test "$WITH_TKSCI" = yes)
1537
1538 #################
1539 ## MATIO LIBRARY (MAT File I/O Library)
1540 #################
1541
1542
1543 AC_ARG_WITH(matio,
1544     AC_HELP_STRING([--without-matio],[Disable the interface to Matio (MAT File I/O library)]))
1545
1546 AC_ARG_WITH(matio_include,
1547         AC_HELP_STRING([--with-matio-include=DIR],[Set the path to the MATIO headers]),
1548         [with_matio_include="-I$withval"], [])
1549
1550 AC_ARG_WITH(matio_library,
1551         AC_HELP_STRING([--with-matio-library=DIR],[Set the path to the MATIO libraries]),
1552         [with_matio_library="-L$withval"], [])
1553
1554 MATIO_ENABLE=no
1555
1556 if test "$with_matio" != no; then
1557    if test -n "$with_matio_include" -o -n "$with_matio_library" ; then
1558       MATIO_CFLAGS="$with_matio_include"
1559       MATIO_LIBS="$with_matio_library -lm -lz -lmatio"
1560    else
1561       PKG_CHECK_MODULES(MATIO, [matio >= 1.3.3])
1562    fi
1563
1564    save_CFLAGS="$CFLAGS"
1565    save_LIBS="$LIBS"
1566
1567    CFLAGS="$CFLAGS $MATIO_CFLAGS"
1568    LIBS="$LIBS $MATIO_LIBS"
1569
1570    AC_CHECK_HEADERS([matio.h matioConfig.h], [],
1571      [AC_MSG_ERROR([Invalid MATIO_CFLAGS returned by pkg-config. Try to define MATIO_CFLAGS.])])
1572    AC_CHECK_LIB([matio], [Mat_Open], [],
1573      [AC_MSG_ERROR([Invalid MATIO_LIBS returned by pkg-config. Try to define MATIO_LIBS.])])
1574
1575    LIBS="$save_LIBS"
1576    CFLAGS="$save_CFLAGS"
1577
1578    AC_DEFINE([WITH_MATIO], [], [With the MATIO library])
1579    MATIO_ENABLE=yes
1580 fi
1581
1582
1583 AC_SUBST(MATIO_ENABLE)
1584 AM_CONDITIONAL(MATIO, test "$with_matio" != no)
1585
1586 #############################
1587 ## Documentation management #
1588 #############################
1589
1590 HELP_ENABLE=yes
1591
1592 AC_ARG_ENABLE(build-help,
1593         AC_HELP_STRING([--disable-build-help],[Disable the help build])
1594         )
1595
1596 if test "$enable_build_help" != no; then
1597     AC_DOCBOOK()
1598 else
1599     HELP_ENABLE=no
1600 fi
1601
1602 if test "$JAVA_ENABLE" = no; then
1603     HELP_ENABLE=no
1604 fi
1605
1606 AC_SUBST(HELP_ENABLE)
1607
1608 AM_CONDITIONAL(BUILD_HELP, test $HELP_ENABLE = yes)
1609
1610 ## Install XML help files ###
1611
1612 AC_ARG_WITH(install-help-xml,
1613         AC_HELP_STRING([--with-install-help-xml],[make install will install XML files])
1614         )
1615 HELP_INSTALL_ENABLE=no
1616 if test "$with_install_help_xml" != no -a "$with_install_help_xml" != ""; then
1617    HELP_INSTALL_ENABLE=yes
1618 fi
1619 AM_CONDITIONAL(INSTALL_HELP_XML, test "$HELP_INSTALL_ENABLE" != "")
1620
1621 ## Doxygen help generation
1622 AC_ARG_ENABLE(build-doxygen,
1623     AC_HELP_STRING([--enable-build-doxygen],[Generate doxygen C/C++ documentation]))
1624
1625 DOXYGEN_ENABLE=yes
1626 if test "$enable_build_doxygen" != no -a "$enable_build_doxygen" != ""; then
1627     AC_DOXYGEN()
1628 else
1629     DOXYGEN_ENABLE=no
1630 fi
1631 AM_CONDITIONAL(DOXYGEN, test $DOXYGEN_ENABLE = yes)
1632
1633 ##############################################################
1634 ## Javasci module
1635 ##############################################################
1636
1637 JAVASCI_ENABLE=yes
1638
1639 if test "$JAVA_ENABLE" = no -o "$JAVASCI" = no; then
1640    JAVASCI_ENABLE=no
1641 fi
1642
1643 AC_SUBST(JAVASCI_ENABLE)
1644
1645
1646 ##############################################################
1647 ## Enable test a compilation time
1648 ##############################################################
1649
1650 COMPILATION_TESTS=no
1651 if test "$enable_compilation_tests" != no -a "$enable_compilation_tests" != ""; then
1652    COMPILATION_TESTS=yes
1653 fi
1654
1655 if test COMPILATION_TESTS=yes -a "$JUNIT4" == ""; then
1656    AC_MSG_WARN([--enable-compilation-tests deactivated: Could not find Junit4"])
1657    COMPILATION_TESTS=no
1658 fi
1659
1660 AM_CONDITIONAL(COMPILATION_TESTS, test "$COMPILATION_TESTS" != "no")
1661
1662 ##############################################################
1663 ## demo_tools module
1664 ##############################################################
1665
1666 DEMOTOOLS_ENABLE=yes
1667
1668 if test "$GUI_ENABLE" = no; then
1669    DEMOTOOLS_ENABLE=no
1670 fi
1671
1672 AC_SUBST(DEMOTOOLS_ENABLE)
1673
1674 ##############################################################
1675 ## graphics/renderer/graphic_export module
1676 ##############################################################
1677
1678 GRAPHICS_ENABLE=yes
1679
1680 if test "$GUI_ENABLE" = no; then
1681    GRAPHICS_ENABLE=no
1682 fi
1683
1684 AC_SUBST(GRAPHICS_ENABLE)
1685
1686 #########################
1687 ## libtool
1688 #########################
1689
1690 AM_DISABLE_STATIC
1691 LT_PREREQ([2.2.7])
1692 AC_PROG_LIBTOOL([shared dlopen])
1693 AM_PROG_LIBTOOL
1694
1695
1696 # Avoid to link all the dep from others libraries (*.la included by LIBADD)
1697 link_all_deplibs=no
1698
1699 # Check to see if building shared libraries
1700 libtool_build_shared_libs=no
1701 if test "$enable_shared" = "yes"; then
1702   libtool_build_shared_libs=yes
1703 fi
1704
1705 # Check to see if building static libraries
1706 libtool_build_static_libs=no
1707 if test "$enable_static" = "yes"; then
1708   libtool_build_static_libs=yes
1709 fi
1710
1711 # AM_CONDITIONAL(ENABLE_STATIC, test "$libtool_build_static_libs" = yes)
1712 # Fake to disable the static build
1713 AM_CONDITIONAL(ENABLE_STATIC, test "$libtool_build_static_libs" = xxxx)
1714
1715 AC_C_CONST()
1716 AC_C_INLINE()
1717
1718 AC_BACKTRACE()
1719
1720 ##########
1721 ##### Code quality
1722 ##########
1723 AC_PATH_PROG(SPLINT, splint, no)
1724
1725 ##########
1726 ##### Detect ccache and use it by default if available
1727 ##########
1728
1729 AC_ARG_ENABLE(ccache,
1730         AC_HELP_STRING([--disable-ccache],[Disable the use of ccache])
1731         )
1732 AC_PATH_PROG(CCACHE, ccache)
1733 if test x"$CCACHE" != x -a "$enable_ccache" != no; then
1734   CC="$CCACHE $CC"
1735   CXX="$CCACHE $CXX"
1736 fi
1737
1738 #######################
1739 ###### Creation of the header file (machine.h)
1740 #######################
1741
1742 AC_DEFINE_UNQUOTED([PATH_SEPARATOR], ["$PATH_SEPARATOR"],
1743 [The default path separator character.])
1744
1745 AH_TOP([#ifndef MACHINE_H
1746 #define MACHINE_H
1747 /* This file defines global element configuration of the build host */
1748 ])
1749
1750 AH_BOTTOM([
1751
1752 #ifdef DIR_SEPARATOR
1753        #undef DIR_SEPARATOR
1754 #endif
1755 #define DIR_SEPARATOR "/"
1756
1757 #endif /* MACHINE_H  */
1758 ])
1759
1760 # Define the standard extension of a dynamic library
1761 AC_DEFINE_UNQUOTED([SHARED_LIB_EXT],["$shrext_cmds"],[Extension of a shared library])
1762
1763 #################
1764 ## stop on warning
1765 #################
1766
1767 # Stop to compile scilab when a warning is found ...
1768 # This stuff is at the end of the configure.ac because it causes some
1769 # problem with AC_COMPILE (the -Werror is added to the test)
1770 #
1771 dnl @TODO : -O0 is only to bypass Stack shit... Must be removed.
1772 if test "$enable_stop_on_warning" = yes; then
1773     WARNING_CFLAGS="-Werror=implicit-function-declaration -O0"
1774     WARNING_CXXFLAGS="-Werror=implicit-function-declaration -O0"
1775 fi
1776
1777 # SCI_*FLAGS contains all defaults values detected on configure
1778 SCI_CFLAGS=$(echo   $LARGEFILE_CFLAGS   $CODECOVERAGE_CFLAGS   $DEBUG_CFLAGS   $ARCH_CFLAGS   $COMPILER_CFLAGS   $SCILIBS_CFLAGS   $SSE_CFLAGS   $BACKTRACE_CFLAGS   $WARNING_CFLAGS)
1779 SCI_CXXFLAGS=$(echo $LARGEFILE_CXXFLAGS $CODECOVERAGE_CXXFLAGS $DEBUG_CXXFLAGS $ARCH_CXXFLAGS $COMPILER_CXXFLAGS $SCILIBS_CXXFLAGS $SSE_CXXFLAGS $BACKTRACE_CXXFLAGS $WARNING_CXXFLAGS)
1780 SCI_FFLAGS=$(echo   $LARGEFILE_FFLAGS   $CODECOVERAGE_FFLAGS   $DEBUG_FFLAGS   $ARCH_FFLAGS   $COMPILER_FFLAGS   $SCILIBS_FFLAGS   $SSE_FFLAGS   $BACKTRACE_FFLAGS   $WARNING_FFLAGS)
1781 SCI_LDFLAGS=$(echo  $LARGEFILE_LDFLAGS  $CODECOVERAGE_LDFLAGS  $DEBUG_LDFLAGS  $ARCH_LDFLAGS  $COMPILER_LDFLAGS  $SCILIBS_LDFLAGS  $SSE_LDFLAGS  $BACKTRACE_LDFLAGS  $WARNING_LDFLAGS)
1782 AC_SUBST(SCI_CFLAGS)
1783 AC_SUBST(SCI_CXXFLAGS)
1784 AC_SUBST(SCI_FFLAGS)
1785 AC_SUBST(SCI_LDFLAGS)
1786
1787 AC_CONFIG_FILES([
1788 libs/MALLOC/Makefile
1789 libs/dynamiclibrary/Makefile
1790 libs/doublylinkedlist/Makefile
1791 libs/hashtable/Makefile
1792 libs/libst/Makefile
1793 contrib/Makefile
1794 desktop/images/icons/Makefile
1795 desktop/Makefile
1796 modules/helptools/Makefile
1797 modules/data_structures/Makefile
1798 modules/differential_equations/Makefile
1799 modules/optimization/Makefile
1800 modules/elementary_functions/Makefile
1801 modules/special_functions/Makefile
1802 modules/io/Makefile
1803 modules/completion/Makefile
1804 modules/history_manager/Makefile
1805 modules/jvm/Makefile
1806 modules/commons/Makefile
1807 modules/sound/Makefile
1808 modules/statistics/Makefile
1809 modules/mexlib/Makefile
1810 modules/sparse/Makefile
1811 modules/linear_algebra/Makefile
1812 modules/polynomials/Makefile
1813 modules/symbolic/Makefile
1814 modules/signal_processing/Makefile
1815 modules/arnoldi/Makefile
1816 modules/interpolation/Makefile
1817 modules/intersci/Makefile
1818 modules/localization/Makefile
1819 modules/cacsd/Makefile
1820 modules/boolean/Makefile
1821 modules/integer/Makefile
1822 modules/double/Makefile
1823 modules/fileio/Makefile
1824 modules/spreadsheet/Makefile
1825 modules/string/Makefile
1826 modules/time/Makefile
1827 modules/graphics/Makefile
1828 modules/graphic_export/Makefile
1829 modules/graphic_objects/Makefile
1830 modules/renderer/Makefile
1831 modules/action_binding/Makefile
1832 modules/gui/Makefile
1833 modules/randlib/Makefile
1834 modules/tclsci/Makefile
1835 modules/windows_tools/Makefile
1836 modules/core/Makefile
1837 modules/prebuildjava/Makefile
1838 modules/api_scilab/Makefile
1839 modules/call_scilab/Makefile
1840 modules/types/Makefile
1841 modules/hdf5/Makefile
1842 modules/fftw/Makefile
1843 modules/umfpack/Makefile
1844 modules/scicos/Makefile
1845 modules/scicos_blocks/Makefile
1846 modules/functions/Makefile
1847 modules/dynamic_link/Makefile
1848 modules/overloading/Makefile
1849 modules/javasci/Makefile
1850 modules/m2sci/Makefile
1851 modules/compatibility_functions/Makefile
1852 modules/development_tools/Makefile
1853 modules/output_stream/Makefile
1854 modules/console/Makefile
1855 modules/demo_tools/Makefile
1856 modules/genetic_algorithms/Makefile
1857 modules/simulated_annealing/Makefile
1858 modules/parameters/Makefile
1859 modules/matio/Makefile
1860 modules/atoms/Makefile
1861 modules/xcos/Makefile
1862 modules/scinotes/Makefile
1863 modules/ui_data/Makefile
1864 modules/graph/Makefile
1865 modules/parallel/Makefile
1866 modules/modules_manager/Makefile
1867 modules/history_browser/Makefile
1868 modules/preferences/Makefile
1869 modules/xml/Makefile
1870 modules/external_objects/Makefile
1871 modules/Makefile
1872 libs/Makefile
1873 Makefile
1874 scilab.pc
1875 etc/modules.xml
1876 etc/classpath.xml
1877 etc/Info.plist
1878 etc/logging.properties
1879 scilab.properties
1880 scilab-lib.properties
1881 scilab-lib-doc.properties
1882 modules/helptools/etc/SciDocConf.xml
1883 modules/core/includes/version.h
1884 ])
1885
1886 # Detection of the module for the future version of Scilab 6
1887 # ie we detect module which ends with _yasp
1888
1889 if test "$enable_yasp" = yes; then
1890    AC_CONFIG_FILES([
1891    modules/development_tools/src/fake/Makefile
1892   ])
1893 fi
1894
1895 # This script is used by Xcos in order to regenerate the function/block list
1896 AC_CONFIG_COMMANDS_POST([chmod +x $SCI_SRCDIR_FULL/modules/scicos_blocks/src/scripts/GenBlocks.sh $SCI_SRCDIR_FULL/modules/dynamic_link/src/scripts/scicompile.sh $SCI_SRCDIR_FULL/modules/dynamic_link/src/scripts/compilerDetection.sh $SCI_SRCDIR_FULL/modules/dynamic_link/src/scripts/configure])
1897
1898
1899 #MAN_FR MAN_ENG
1900 #modules/mpi/Makefile
1901 #for top_builddir in . .. ../.. $ac_auxdir $ac_auxdir/..; do
1902 #  test -f $top_builddir/configure && break
1903 #done
1904
1905
1906 #if test "$with_mpi" = yes; then
1907 #AC_CONFIG_FILES([modules/mpi/Makefile])
1908 #fi
1909
1910 # Generate stack.h
1911 if test "$IS_64_BITS_CPU" = true -o "$MACOSX" = "1"; then
1912    stack_h_cpp_flags=-DUSE_DYNAMIC_STACK
1913 else
1914    stack_h_cpp_flags=
1915 fi
1916
1917 AC_CONFIG_COMMANDS([modules/core/includes/stack.h],
1918   [if ! $CPP $stack_h_cpp_flags - < $srcdir/modules/core/includes/stack.h.in |\
1919               $GREP -v '^#' > $srcdir/modules/core/includes/stack.h ; then
1920      AC_MSG_ERROR([stack.h generation failed])
1921    fi],
1922   [CPP="$CPP"
1923    GREP="$GREP"
1924    stack_h_cpp_flags="$stack_h_cpp_flags"
1925   ])
1926
1927 AC_OUTPUT
1928
1929 # To distribution packager, you can uncomment this stuff is you want to
1930 # disable the rpath issue
1931 # However, you will have to set all the LD_LIBRARY_PATH to .libs/ directory
1932 # since scilab is compiling macros and help into the source tree (ie before
1933 # the "make install")
1934 # You should consider using chrpath:
1935 # http://directory.fsf.org/project/chrpath/
1936 # to remove it before the make install
1937
1938 #case ${host} in
1939 #  *-pc-linux-gnu)
1940 #    AC_MSG_RESULT([Fixing libtool for -rpath problems.])
1941 #    sed < libtool > libtool-2 \
1942 #    's/^hardcode_libdir_flag_spec.*$/hardcode_libdir_flag_spec=" -D__LIBTOOL_IS_A_FOOL__ "/'
1943 #    mv libtool-2 libtool
1944 #    chmod 755 libtool
1945 #  ;;
1946 #esac
1947 #
1948
1949 echo ""
1950
1951 echo "Scilab is configured as follows. Please verify that this configuration"
1952 echo "matches your expectations."
1953 echo ""
1954 echo "Host system type : $host"
1955 echo ""
1956 echo "                  Option                        Value"
1957 echo "-------------------------------------------------------------------------"
1958 echo "Shared libraries.......      --enable-shared=$libtool_build_shared_libs"
1959 echo "Static libraries.......      --enable-static=$libtool_build_static_libs"
1960 echo "GNU ld.................      --with-gnu-ld=$with_gnu_ld"
1961 echo "Enable debug ..........      --enable-debug=$enable_debug"
1962 echo "Enable debug C.........      --enable-debug-C=$enable_debug_C"
1963 echo "Enable debug C++.......      --enable-debug-CXX=$enable_debug_CXX"
1964 echo "Enable debug Java......      --enable-debug-java=$enable_debug_java"
1965 echo "Enable debug Fortran...      --enable-debug-fortran=$enable_debug_fortran"
1966 echo "Enable stop on warning.      --enable-stop-on-warning=$enable_stop_on_warning"
1967
1968 echo ""
1969 echo "Compiler Configuration:"
1970 echo "  Intel (--with-intelcompilers) .... =        $with_intelcompilers"
1971 echo "  GNU gcc (--with-gcc) ............. =        $with_gcc"
1972 echo "  GNU Fortran 95 (--with-gfortran) . =        $with_gfortran"
1973 echo ""
1974 echo "Options:"
1975 echo "  Do not use TCL/TK (--without-tk) ................. = $with_tk"
1976 echo "  TCL include (--with-tcl-include) ................. = $USER_TCL_INC_PATH"
1977 echo "  TCL library (--with-tcl-library) ................. = $USER_TCL_LIB_PATH"
1978 echo "  TK include (--with-tk-include) ................... = $USER_TK_INC_PATH"
1979 echo "  TK library (--with-tk-library) ................... = $USER_TK_LIB_PATH"
1980 echo "  Install XML Help (--with-install-help-xml) ....... = $with_install_help_xml"
1981 echo "  Compilation tests (--enable-compilation-tests) ... = $COMPILATION_TESTS"
1982 echo "  Make the package relocatable (--enable-relocatable)= $RELOCATABLE"
1983 echo "  Use FFTW (--without-fftw) ........................ = $with_fftw"
1984 echo "  Use MATIO (--without-matio) ...................... = $with_matio"
1985
1986 echo ""
1987 if test "$with_gui" = no; then
1988    echo "Not using Xcos because of the option --without-gui"
1989 else
1990 if test $XCOS_ENABLE = yes; then
1991    echo "Xcos enable"
1992    echo "Build modelica compiler (--without-modelica) ....... = $with_modelica"
1993    echo ""
1994    if test "$with_ocaml" != no -a "$OCAMLC" != no -a "$OCAMLOPT" != no; then
1995      echo "Ocaml Configuration (for Modelica compiler):"
1996      echo "  OCAMLC ............. = $OCAMLC"
1997      echo "  OCAMLOPT ........... = $OCAMLOPT"
1998      echo "  OCAMLDEP ........... = $OCAMLDEP"
1999    else
2000      echo "Will not build Modelica compiler"
2001    fi
2002 else
2003    echo "Not using Xcos"
2004 fi
2005 fi
2006
2007 echo ""
2008 if test "$enable_code_coverage" = yes;  then
2009    echo "Code coverage configuration:"
2010    echo "  LCOV .............. = $LCOV"
2011    echo "  GENHTML ........... = $GENHTML"
2012 else
2013    echo "Not using code coverage"
2014 fi
2015
2016 echo ""
2017 if test $OPENMP_ENABLE = yes; then
2018    echo "OpenMP Configuration:"
2019    echo "OpenMP CFLAGS ...... = $OPENMP_CFLAGS"
2020    echo "OpenMP CXXFLAGS .... = $OPENMP_CXXFLAGS"
2021    echo "OpenMP LIBS ........ = $OPENMP_LIBS"
2022    echo "OpenMP FFLAGS ...... = $OPENMP_LDFLAGS"
2023 else
2024    echo "Not using OpenMP"
2025 fi
2026
2027 echo ""
2028 if test $FFTW_ENABLE = yes;  then
2029    echo "FFTW Configuration:"
2030    echo "  FFTW LIBS .......... = $FFTW3_LIB"
2031    echo "  FFTW CFLAGS ........ = $FFTW3_CFLAGS"
2032 else
2033    echo "Not using FFTW"
2034 fi
2035
2036 echo ""
2037 if test $MATIO_ENABLE = yes;  then
2038    echo "MATIO Configuration:"
2039    echo "  MATIO LIBS .......... = $MATIO_LIBS"
2040    echo "  MATIO CFLAGS ........ = $MATIO_CFLAGS"
2041 else
2042    echo "Not using MATIO"
2043 fi
2044
2045 echo ""
2046 if test $UMFPACK_ENABLE = yes;  then
2047    echo "UMFPACK Configuration:"
2048    echo "  UMFPACK LIBS ....... = $UMFPACK_LIB"
2049    echo "  UMFPACK CFLAGS ..... = $UMFPACK_CFLAGS"
2050    if test $SUITESPARSE = yes; then
2051       echo "  UMFPACK SUITESPARSE  = Yes"
2052    else
2053       echo "  UMFPACK SUITESPARSE  = No"
2054    fi
2055 else
2056    echo "Not using UMFPACK"
2057 fi
2058
2059
2060 echo ""
2061 echo "BLAS/LAPACK/ATLAS Configuration:"
2062 echo "  BLAS LIBS ............. = $BLAS_LIBS"
2063 echo "  BLAS TYPE ............. = $BLAS_TYPE"
2064 echo "  LAPACK LIBS ........... = $LAPACK_LIBS"
2065 echo "  LAPACK TYPE ........... = $LAPACK_TYPE"
2066 echo "  ARPACK LIBS ........... = $ARPACK_LIBS"
2067 echo ""
2068
2069 #if test "$with_mpi" = yes; then
2070 #   echo "MPI Configuration:"
2071 #   echo "  MPI LIBS ........... = $MPILIBS"
2072 #   echo "  MPI C Compiler ..... = $MPICC"
2073 #   echo "  MPI C++ Compiler ... = $MPICXX"
2074 #   echo "  MPI F77 Compiler ... = $MPIF77"
2075 #else
2076 #   echo "Not using MPI"
2077 #fi
2078
2079 #if test "$with_openmpi" != "no"; then
2080 #   echo "OpenMPI Configuration:"
2081 #   echo "  OpenMPI LIBS ........... = $OPENMPI_LIBS"
2082 #   echo "  OpenMPI C Compiler ..... = $OPENMPI_CC"
2083 #   echo "  OpenMPI F77 Compiler ... = $MPIF77"
2084 #else
2085 #   echo "Not using MPI"
2086 #fi
2087
2088 echo ""
2089 if test $BUILD_LOCALIZATION_ENABLE != no; then
2090    echo "Gettext/localization configuration:"
2091    echo "  xgettext ............... = $XGETTEXT"
2092    echo "  msgfmt  ................ = $MSGFMT"
2093    echo "  msgfmt_opts ............ = $MSGFMT_OPTS"
2094    echo "  msgcat  ................ = $MSGCAT"
2095 else
2096    echo "Won't generate localization files"
2097 fi
2098
2099 echo ""
2100 if test $HELP_ENABLE = yes; then
2101    echo "Documentation building configuration:"
2102    echo "  Docbook XSL path ....... = $DOCBOOK_ROOT"
2103    echo "  Saxon XSLT ............. = $SAXON"
2104    echo "  XML commons external ... = $XML_APIS_EXT"
2105 else
2106    echo "No documentation generated"
2107 fi
2108
2109 echo ""
2110 echo "Java Configuration:"
2111 if test ! -z "$JAVAC"; then
2112 echo "  JAVA_HOME ........... = $JAVA_HOME"
2113 echo "  JAVAC ............... = $JAVAC"
2114 echo "  JAVA_CLASSPATH ...... = $JAVA_CLASSPATH"
2115 echo "  JAVA_VERSION ........ = $JAVA_VERSION"
2116 echo "  JAVAC_FLAGS ......... = $JAVAC_FLAGS"
2117 echo "  JAVA_JNI_INCLUDE .... = $JAVA_JNI_INCLUDE"
2118 echo "  JAVA_JNI_LIBS ....... = $JAVA_JNI_LIBS"
2119 echo "  JAVA_JNI_LIBS_PRELOAD = $JAVA_JNI_LIBS_PRELOAD"
2120 echo "  JAVA ................ = $JAVA"
2121 echo "  JAVADOC ............. = $JAVADOC"
2122 echo "  JAR ................. = $JAR"
2123 echo "  ANT ................. = $ANT"
2124 else
2125 echo "  JAVA disabled"
2126 fi
2127
2128
2129 echo ""
2130 echo "Java dependencies:"
2131 if test ! -z "$JAVAC"; then
2132 echo "  Flexdock ............ = $FLEXDOCK"
2133 echo "  JOGL 2............... = $JOGL2"
2134 echo "  JOGL 2 LIBS (JNI) ... = $JOGL2_LIBS"
2135 echo "  Gluegen 2 ........... = $GLUEGEN2_RT"
2136 echo "  Gluegen 2 LIBS (JNI)  = $GLUEGEN2_RT_LIBS"
2137 echo "  Jeuclid (MathML) .... = $JEUCLID_CORE"
2138 echo "  Jhall  .............. = $JHALL"
2139 echo "  Jrosetta (API) ...... = $JROSETTA_API"
2140 echo "  Jrosetta (Engine) ... = $JROSETTA_ENGINE"
2141 echo "  Commons Logging ..... = $COMMONS_LOGGING"
2142 echo "  JGraph X ............ = $JGRAPHX"
2143 echo "  SciRenderer ......... = $SCIRENDERER"
2144 echo "  JLaTeXMath .......... = $JLATEXMATH"
2145 fi
2146
2147 echo ""
2148 if test ! -z "$JAVAC"; then
2149 echo "Documentation, graphic export:"
2150 echo "  FOP (XML => PDF) .... = $FOP"
2151 echo "  JLaTeXMath Fop ...... = $JLATEXMATH_FOP"
2152 echo "  Batik (SVG) ......... = $BATIK"
2153 echo "  Avalon Framework .... = $AVALON_FRAMEWORK"
2154 echo "  Commons I/O ......... = $COMMONS_IO"
2155 echo "  XML graphics commons  = $XMLGRAPHICS_COMMONS"
2156 fi
2157
2158
2159 echo ""
2160 echo "Code quality (optional):"
2161 echo "  Checkstyle .......... = $CHECKSTYLE"
2162 echo "  Commons-beanutils ... = $COMMONS_BEANUTILS"
2163 echo "  Antlr ............... = $ANTLR"
2164 echo "  Junit4 .............. = $JUNIT4"
2165 echo "  Cobertura ........... = $COBERTURA"
2166 echo "  splint .............. = $SPLINT"
2167
2168 echo ""
2169 echo "TCL/TK configuration:"
2170 echo "  TK_INC_PATH ........ = $TK_INC_PATH"
2171 echo "  TCL_INC_PATH ....... = $TCL_INC_PATH"
2172 echo "  TCLTK_LIBS ......... = $TCLTK_LIBS"
2173 echo "  TCL_SERIAL_VERSION . = $TCL_SERIAL_VERSION"
2174 echo "  TK_SERIAL_VERSION .. = $TK_SERIAL_VERSION"
2175
2176 echo ""
2177 echo "XML configuration:"
2178 echo "  XML_FLAGS .......... = $XML_FLAGS"
2179 echo "  XML_LIBS ........... = $XML_LIBS"
2180 echo "  XML_VERSION ........ = $XML_VERSION"
2181
2182 echo ""
2183 echo "HDF5 configuration:"
2184 echo "  HDF5 CFLAGS ......... = $HDF5_CFLAGS"
2185 echo "  HDF5 LIBS ........... = $HDF5_LIBS"
2186
2187 echo ""
2188 echo "PCRE configuration:"
2189 echo "  PCRE_CFLAGS ........ = $PCRE_CFLAGS"
2190 echo "  PCRE_LIBS .......... = $PCRE_LIBS"
2191 echo "  PCRE_VERSION ....... = $PCRE_VERSION"
2192
2193
2194 echo ""
2195 echo "SWIG Configuration:"
2196 if test ! -z "$SWIG_BIN"; then
2197 echo "  SWIG_BIN ........... = $SWIG_BIN"
2198 echo "  SWIG_JAVA .......... = $SWIG_JAVA"
2199 else
2200 echo "  SWIG generation disabled"
2201 fi
2202
2203 echo ""
2204 echo "GIWS Configuration:"
2205 if test ! -z "$GIWS_BIN"; then
2206 echo "  GIWS_BIN ........... = $GIWS_BIN"
2207 else
2208 echo "  GIWS generation disabled"
2209 fi
2210
2211 echo ""
2212 echo "Libtool config:"
2213 echo "  objext .............. = $objext"
2214 echo "  libext (static) ..... = $libext"
2215 echo "  shrext_cmds ......... = $shrext_cmds"
2216 echo "  exeext .............. = $exeext"
2217
2218 echo ""
2219
2220 echo "Compilation paths:"
2221 echo "  srcdir .............. = $SCI_SRCDIR"
2222 echo "  srcdir_full ......... = $SCI_SRCDIR_FULL"
2223 echo "  builddir ............ = $SCI_BUILDDIR"
2224 if test "$SCI_SRCDIR_FULL" != "$SCI_BUILDDIR"; then
2225 echo "  VPATH build ......... = Activated"
2226 fi
2227
2228 echo ""
2229 echo "Platform informations:"
2230 echo "  host ........... = $host"
2231 echo "  host_cpu ....... = $host_cpu"
2232 echo "  host_vendor .... = $host_vendor"
2233 echo "  host_os ... .... = $host_os"
2234 echo "  hostname ....... = $ac_hostname"
2235 echo "  CPU 64 bits .... = $IS_64_BITS_CPU"
2236 if test -n "$MAC_DETECTED_ARCH"; then
2237 echo "  Mac OS X arch .. = $MAC_DETECTED_ARCH"
2238 echo "  Mac OS X version = $macosx_version"
2239 fi
2240
2241 echo ""
2242 echo "Options used to compile and link:"
2243 echo "  prefix ......... = $prefix"
2244 echo "  localedir ...... = $localedir"
2245 echo "  VERSION ........ = $PACKAGE_VERSION"
2246 echo "  CC ............. = $CC"
2247 echo "  CFLAGS ......... = $CFLAGS"
2248 echo "  SCI_CFLAGS ..... = $SCI_CFLAGS"
2249 echo "  DEFS ........... = $DEFS"
2250 echo "  LD ............. = $LD"
2251 echo "  LDFLAGS ........ = $LDFLAGS"
2252 echo "  SCI_LDFLAGS .... = $SCI_LDFLAGS"
2253 echo "  LIBS ........... = $LIBS"
2254 echo "  CXX ............ = $CXX"
2255 echo "  CXXFLAGS ....... = $CXXFLAGS"
2256 echo "  SCI_CXXFLAGS ... = $SCI_CXXFLAGS"
2257 echo "  F77 ............ = $F77"
2258 echo "  FFLAGS ......... = $FFLAGS"
2259 echo "  SCI_FFLAGS ..... = $SCI_FFLAGS"
2260 echo "  F77_LDFLAGS .... = $F77_LDFLAGS"
2261 echo "  TERMCAP_LIB .... = $TERMCAP_LIB"
2262 echo ""