We no longer need jhdf5. deleting all dependencies. Closes bug #11556 and remove...
[scilab.git] / scilab / configure.ac
1 #
2 # Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
3 # Copyright (C) INRIA - 2006-2008 - Sylvestre Ledru
4 # Copyright (C) DIGITEO - 2009-2011 - Sylvestre Ledru
5 # Copyright (C) DIGITEO - 2009 - Pierre MARECHAL <pierre.marechal@scilab.org>
6 #
7 # This file must be used under the terms of the CeCILL.
8 # This source file is licensed as described in the file COPYING, which
9 # you should have received as part of this distribution.  The terms
10 # are also available at
11 # http://www.cecill.info/licences/Licence_CeCILL_V2-en.txt
12 #
13
14 dnl Process this file with autoconf to produce a configure script.
15
16
17 AC_REVISION($Revision$)dnl
18 AC_INIT([Scilab],[5],[http://bugzilla.scilab.org/])
19 AC_PREREQ(2.62)
20 AC_CONFIG_MACRO_DIR([m4/])
21
22 SCI_BUILDDIR="`pwd`"
23 SCI_SRCDIR="$srcdir"
24 SCI_SRCDIR_FULL="`cd $SCI_SRCDIR && pwd`"
25
26 SCILAB_VERSION_MAJOR=5
27 SCILAB_VERSION_MINOR=4
28 SCILAB_VERSION_MAINTENANCE=0
29 AC_SUBST(SCILAB_VERSION_MAJOR)
30 AC_SUBST(SCILAB_VERSION_MINOR)
31 AC_SUBST(SCILAB_VERSION_MAINTENANCE)
32
33
34 SCILAB_LIBRARY_VERSION=$SCILAB_VERSION_MAJOR:$SCILAB_VERSION_MINOR:$SCILAB_VERSION_MAINTENANCE
35 AC_SUBST(SCILAB_LIBRARY_VERSION)
36
37 SCILAB_BINARY_VERSION=$SCILAB_VERSION_MAJOR.$SCILAB_VERSION_MINOR.$SCILAB_VERSION_MAINTENANCE
38 AC_SUBST(SCILAB_BINARY_VERSION)
39
40 #shared library versioning
41 #GENERIC_LIBRARY_VERSION=1:2:0
42 #                       | | |
43 #                +------+ | +---+
44 #                |        |     |
45 #             current:revision:age
46 #                |        |     |
47 #                |        |     +- increment if interfaces have been added
48 #                |        |        set to zero if interfaces have been removed
49 #                                  or changed
50 #                |        +- increment if source code has changed
51 #                |           set to zero if current is incremented
52 #                +- increment if interfaces have been added, removed or changed
53
54 # Check if we have a space in the path to the source tree
55 SPACE_IN_PATH=`echo "$SCI_SRCDIR_FULL"|grep " " > /dev/null; echo $?`
56 if test "$SPACE_IN_PATH" = "0"; then
57    AC_MSG_WARN([=====================================])
58    AC_MSG_WARN([Configure thinks that there is a space in the path to the source. This may cause problem with libtool and some other things...])
59    AC_MSG_WARN([=====================================])
60    sleep 180
61 fi
62
63 AC_CONFIG_AUX_DIR(config)
64 AC_CONFIG_HEADERS([modules/core/includes/machine.h])
65
66 # strip executable
67 AM_PROG_INSTALL_STRIP
68 AC_PROG_LN_S
69
70 AC_CUSTOM_LARGE_FILE
71
72 # In order to be able to change the scilab directory
73 # See http://wiki.debian.org/RpathIssue
74 AC_RELOCATABLE
75 AC_RELOCATABLE_LIBRARY
76 AC_LIB_RPATH
77
78 # If configure detect that timestamp changed,
79 # it tries to rebuild configure & makefile which can be a painmaker
80 # if the version is different
81 AM_MAINTAINER_MODE
82
83 AM_INIT_AUTOMAKE([-Wall foreign]) # Not using -Werror because we override {C,F}FLAGS in order to disable optimisation
84
85 AC_CANONICAL_HOST
86
87 #################################
88 ## all the --with-* argument help
89 #################################
90
91
92 AC_ARG_ENABLE(debug,
93    AC_HELP_STRING([--enable-debug],[Do not optimize and print warning messages (C/C++/Fortran/Java code)]))
94
95 AC_ARG_ENABLE(debug-C,
96    AC_HELP_STRING([--enable-debug-C],[Do not optimize and print warning messages (C code)]))
97
98 AC_ARG_ENABLE(debug-CXX,
99    AC_HELP_STRING([--enable-debug-CXX],[Do not optimize and print warning messages (C++ code)]))
100
101 AC_ARG_ENABLE(debug-java,
102    AC_HELP_STRING([--enable-debug-java],[Print warning messages and line numbers (Java code)]))
103
104 AC_ARG_ENABLE(debug-fortran,
105    AC_HELP_STRING([--enable-debug-fortran],[Do not optimize and print warning messages (Fortran code)]))
106
107 AC_ARG_ENABLE(debug-linker,
108    AC_HELP_STRING([--enable-debug-linker],[Print warning messages from the linker (ld)]))
109
110 AC_ARG_ENABLE(code-coverage,
111    AC_HELP_STRING([--enable-code-coverage],[Enable code coverage]))
112
113 AC_ARG_ENABLE(stop-on-warning,
114    AC_HELP_STRING([--enable-stop-on-warning],[Stop the compilation on the first warning found in the C/C++ code]))
115
116 AC_ARG_WITH(gcc,
117     AC_HELP_STRING([--with-gcc],[Use gcc C compiler ]))
118
119 AC_ARG_WITH(gfortran,
120     AC_HELP_STRING([--with-gfortran],[Use gfortran, GNU Fortran 95 compiler]))
121
122 AC_ARG_WITH(intelcompilers,
123     AC_HELP_STRING([--with-intelcompilers],[Use Intel C (icc) and Fortran (ifort) proprietary compilers (GNU/Linux only) ]))
124
125 AC_ARG_WITH(tk,
126     AC_HELP_STRING([--without-tk],[Disable the interface to Tcl/Tk ]))
127
128 AC_ARG_WITH(javasci,
129     AC_HELP_STRING([--without-javasci],[Disable the Java/Scilab interface (javasci)]))
130
131 AC_ARG_ENABLE(compilation-tests,
132     AC_HELP_STRING([--enable-compilation-tests],[Enable unitary tests and checks at compilation time]))
133
134 AC_ARG_WITH(gui,
135     AC_HELP_STRING([--without-gui],[Disable the Scilab Graphical User Interface (GUI). Intended for embedded/clustering/grid Scilab ]))
136
137 AC_ARG_ENABLE(build-swig,
138     AC_HELP_STRING([--enable-build-swig],[Regenerate Java => C wrappers produces by Swig (A Java Development Kit (JDK) is mandatory for this option)]))
139
140 AC_ARG_ENABLE(build-giws,
141     AC_HELP_STRING([--enable-build-giws],[Regenerate C/C++ => Java wrappers produces by Giws (A Java Development Kit (JDK) is mandatory for this option)]))
142
143
144 ################################################
145 ########## compilator & misc programs detection
146 ################################################
147
148 AC_PROG_CPP
149 AC_PROG_GREP
150
151 ######
152 #### Mac OS X set of fink path with provided
153 ######
154
155 AC_ARG_WITH(fink_prefix,
156 AC_HELP_STRING([--with-fink-prefix],[Provide a fink prefix. Default: /sw/ ]))
157 # Need MacosX Version to specify some path.                                  
158 case "$host_os" in
159      *Darwin* | *darwin*)
160               AC_GET_MACOSX_VERSION
161      ;;
162 esac
163
164 case "$host" in
165     *darwin*)
166         if test -n "$with_fink_prefix"; then
167             # If with-fink-prefix is provided, use the provided path to make sure that we will
168             # use it to detect dependencies (for example, gfortran is not provided in xcode.
169             # Therefor, we use the one in fink)
170             FINK_PREFIX="$with_fink_prefix/"
171
172             # Exec the init script of fink to make sure that the env is set
173             if test -f $with_fink_prefix/bin/init.sh; then
174                 echo "source $with_fink_prefix/bin/init.sh executed to set the env"
175                 source $with_fink_prefix/bin/init.sh
176             else
177                 AC_MSG_WARN([Could not find the fink init.sh script: $with_fink_prefix/bin/init.sh])
178             fi
179         else
180             FINK_PREFIX="/sw/"
181         fi
182
183         #Append to the default flags on Apple machines
184         CPPFLAGS="$CPPFLAGS -I$FINK_PREFIX/include/"
185         LDFLAGS="$LDFLAGS -L$FINK_PREFIX/lib/"
186         ;;
187 esac
188
189 AC_ARG_WITH(min_macosx_version,
190 AC_HELP_STRING([--with-min-macosx-version],[Force compilers to generate binaries compatible with MacOSX minimal version.]))
191 case "$host" in
192     *darwin*)
193     if test -n "$with_min_macosx_version"; then
194        MIN_MACOSX_VERSION=$with_min_macosx_version
195        #Append to the default flags on Apple machines
196        ARCH_CFLAGS="-mmacosx-version-min=$MIN_MACOSX_VERSION"
197        ARCH_CXXFLAGS="-mmacosx-version-min=$MIN_MACOSX_VERSION"
198        ARCH_FFLAGS="-mmacosx-version-min=$MIN_MACOSX_VERSION"
199        ARCH_LDFLAGS="-mmacosx-version-min=$MIN_MACOSX_VERSION"
200        # We need this to be passed to all linker commands
201        LDFLAGS="$LDFLAGS -mmacosx-version-min=$MIN_MACOSX_VERSION"
202     fi
203 ;;
204 esac
205
206
207 #####################################################
208 ## Look for pkg-config
209 #####################################################
210 PKG_PROG_PKG_CONFIG
211
212 #####################################################
213 ## check if options are correct (or not)
214 #####################################################
215
216 if test "$with_intelcompilers" = yes -a "$with_gcc" = yes; then
217     AC_MSG_ERROR([Conflicting options : you specified two compiler series])
218 fi
219
220 ######## fortran ########
221
222 if test "$with_gfortran" = yes; then
223    AC_PROG_F77(gfortran)
224    if test -z "$F77"; then
225      AC_MSG_ERROR([You asked me to use gfortran but i haven't been able to find it])
226     fi
227 fi
228
229 if test "$with_intelcompilers" = yes; then
230    AC_PROG_F77(ifc ifort)
231    if test -z "$F77"; then
232      AC_MSG_ERROR([You asked me to use ifc (intel fortran compiler) but i haven't been able to find it])
233     fi
234 fi
235
236 if test -z "$F77"; then
237 ## No Fortran compiler specified... Prefer gfortran and intel compilers
238    AC_PROG_F77([gfortran ifc ifort])
239    if test -z "$F77"; then
240         # Best effort to find a compiler (might be g77)
241         AC_PROG_F77
242    fi
243 fi
244
245
246 # case statements were introduced in fortran 90 so we can use that
247 # as a test to see if our compiler is fortran 90 compatible.
248 f90compatible=false
249 if test -z "$F77"; then
250   AC_MSG_ERROR([No fortran compiler found. Cannot compile scilab without a fortran compiler])
251 fi
252
253 AC_MSG_CHECKING([if $F77 is a fortran 90 compatible compiler])
254  f90compatible=false
255 AC_LANG_PUSH([Fortran 77])
256 AC_COMPILE_IFELSE([
257       PROGRAM hello
258         do 50 i = 1, 5
259            select case ( i )
260               case (1)
261                  print*, "case is 1, i is ", i
262               case ( 2 : 3 )
263                  print*, "case is 2 to 3, i is ", i
264               case default
265                  print*, "default case, i is ", i
266               end select
267  50           continue
268       END
269     ],
270     [AC_MSG_RESULT([yes])
271      AC_DEFINE([G95_FORTRAN],[],[uses G95 fortran])
272      f90compatible=true
273     ],
274     [AC_MSG_RESULT([no])]
275 )
276 AC_LANG_POP([Fortran 77])
277
278 ############ C ###############
279
280
281 if test "$with_gcc" = yes; then
282    AC_PROG_CC(gcc)
283    if test -z "$CC"; then
284      AC_MSG_ERROR([You asked me to use gcc but i haven't been able to find it])
285     fi
286 fi
287
288 if test "$with_intelcompilers" = yes; then
289    AC_PROG_CC(icc ecc)
290    if test -z "$CC"; then
291      AC_MSG_ERROR([You asked me to use icc (intel C compiler) but I haven't been able to find it])
292     fi
293 fi
294
295 if test -z "$CC"; then
296 # No C compiler specified... We rely on Autoconf to find the best
297    AC_PROG_CC
298 fi
299
300 if test -z "$CC"; then
301   AC_MSG_ERROR([No C Compiler found. Cannot compile Scilab without a C compiler])
302 fi
303
304 AC_CHECK_SIZEOF([int])
305 AC_CHECK_SIZEOF([long])
306
307 ### C++ ###
308 AC_PROG_CXX
309 # we can't just do something like
310 # AC_CHECK_PROG(cxx_present, $CXX, "yes", "no")
311 # because if the user has specified the full path of the desired C++ compiler then AC_CHECK_PROG
312 # will fail.  If AC_PROG_CXX fails to find a c++ compiler it will set CXX=g++ so just run AC_CHECK_PROG
313 # in this special case
314 case $CXX in
315     g++)
316         AC_CHECK_PROG([cxx_present], [$CXX], [yes], [no])
317         if test "x$cxx_present" != "xyes"; then
318             AC_MSG_ERROR([No C++ compiler found. Cannot compile scilab without a C++ compiler])
319         fi
320         ;;
321 esac
322
323 # for "subdir-objects"
324
325 AM_PROG_CC_C_O
326 AC_PROG_F77_C_O
327
328
329 # If this option is provided, enable the debug on C & C++
330 if test "$enable_stop_on_warning" = yes; then
331    enable_debug_C=yes
332    enable_debug_CXX=yes
333 fi
334
335 if test "$enable_debug" = yes; then
336    enable_debug_fortran=yes
337    enable_debug_C=yes
338    enable_debug_CXX=yes
339    enable_debug_java=yes
340 else
341    enable_debug=no
342 fi
343
344 if test "$enable_debug_fortran" = yes; then
345    FFLAGS="`echo "$FFLAGS"| sed -e 's|-O[0-9+]|-O0|'`"
346 else
347    enable_debug_fortran=no
348 fi
349
350 if test "$enable_debug_C" = yes; then
351    CFLAGS="`echo "$CFLAGS"| sed -e 's|-O[0-9+]|-O0|'`"
352 else
353    enable_debug_C=no
354 fi
355
356 if test "$enable_debug_CXX" = yes; then
357    CXXFLAGS="`echo "$CXXFLAGS"| sed -e 's|-O[0-9+]|-O0|'`"
358 else
359    enable_debug_CXX=no
360 fi
361
362 if test "$enable_debug_java" = yes; then
363    LOGGING_LEVEL="INFO"
364 else
365    LOGGING_LEVEL="SEVERE"
366 fi
367 AC_SUBST(LOGGING_LEVEL)
368
369 if test "x${prefix}" = "xNONE"; then
370   prefix="${ac_default_prefix}"
371 fi
372
373 ###############################
374 ## get the version
375 ###############################
376
377 SCIVERSION=`cat $SCI_SRCDIR/Version.incl | sed -e "s/SCIVERSION=//" `
378
379 #############################################
380 ## Compilers and options according to machine
381 #############################################
382
383 ######################
384 ######## Set compilation options for intel C/Fortran compilers
385 ######################
386
387 if test "$with_intelcompilers" = yes; then
388    SCI_INTEL_COMPILER()
389 fi
390
391 ########### FORTRAN ######################
392
393
394 ######################
395 ######## With gfortran ...
396 ######################
397 if test -n "$F77"; then
398    case "$F77" in
399      gfortran*)
400         ## With GNU Compiler enable the code coverage
401         if test "$enable_code_coverage" = yes; then
402             CODE_COVERAGE_FFLAGS="-fprofile-arcs -ftest-coverage"
403         fi
404      ;;
405      g77*)
406         AC_MSG_ERROR([g77 is no longer supported. Please consider switching to gfortran])
407      ;;
408    esac
409
410    if test "$enable_debug_fortran" = yes; then
411     AC_LANG_PUSH([Fortran 77])
412     for flag in -g -Wall -Wsurprising; do
413         case " ${FFLAGS} " in
414             *\ ${flag}\ *)
415                 # flag is already present
416                 ;;
417
418             *)
419                 AC_MSG_CHECKING([if the Fortran compiler accepts ${flag}])
420                 ac_save_FFLAGS="$FFLAGS"
421                 FFLAGS="$FFLAGS ${flag}"
422                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM()],
423                     [AC_MSG_RESULT([yes])
424                      DEBUG_FFLAGS="${flag}"
425                     ],
426                     [AC_MSG_RESULT([no])]
427                 )
428                 ;;
429         esac
430     done
431     AC_LANG_POP([Fortran 77])
432    else
433       DEBUG_FFLAGS="-DNDEBUG"
434    fi
435       case "$host" in
436          x86_64-*-linux*)
437             ARCH_FFLAGS="-m64 -fPIC"
438                     ;;
439         # Dec Alpha OSF 4
440         alpha*-dec-osf4.*)
441           ARCH_FFLAGS="-fpe3"
442         ;;
443         alpha*-dec-osf*)
444             ARCH_FFLAGS="-fpe3 -switch nosqrt_recip"
445         ;;
446         rs6000-*-*)
447             ARCH_FFLAGS="-qcharlen=4096"
448             ;;
449         mips-*-ultrix*)
450             ARCH_FFLAGS="-O0 -fpe1"
451         ;;
452           *-*-hpux9.*)
453             ARCH_FFLAGS="+Obb1200 +E4 -Dhpux"
454         ;;
455           *-*-hpux10.*)
456             if test "$enable_debug_fortran" = yes; then
457                 ARCH_FFLAGS="+E4 +Z +DAportable -Dhpux"
458             else
459                 ARCH_FFLAGS="+O2 +E4 +Z +DAportable -Dhpux"
460             fi
461 #            ARCH_LDFLAGS="-Wl,+vnocompatwarnings,-E /usr/lib/libdld.sl"
462
463             ;;
464           *-*-hpux11.*)
465            if test "$enable_debug_fortran" = yes; then
466               ARCH_FFLAGS=" +Z +DAportable -Dhpux"
467              else
468               ARCH_FFLAGS="+O2 +Z +DAportable -Dhpux"
469            fi
470            ARCH_LDFLAGS="-ldld -lnsl -lU77 -lm"
471
472      ;;
473       esac
474
475 fi
476
477 #########################
478 # setting parameters according to system types
479 #########################
480
481 case "$host" in
482     *-*-hpux9.*|*-*-hpux10.*|*-*-hpux11.*)
483         HPUX=1
484     ;;
485     sparc-*)
486         SPARC=1
487     ;;
488     mips-sgi-irix*)
489       MIPS_SGI_IRIX=1
490     ;;
491      *-*-solaris*)
492      SOLARIS=1
493      ;;
494     *darwin*)
495       MACOSX=1
496     ;;
497 esac
498
499 AM_CONDITIONAL(IS_MACOSX, test -n "$MACOSX")
500 AM_CONDITIONAL(IS_HPUX, test -n "$HPUX")
501 AM_CONDITIONAL(IS_SPARC, test -n "$SPARC")
502 AM_CONDITIONAL(IS_SOLARIS, test -n "$SOLARIS")
503 AM_CONDITIONAL(IS_MIPS_SGI_IRIX, test -n "$MIPS_SGI_IRIX")
504
505
506
507 ############
508 ## C++
509 ############
510
511
512 if test -z "$CXX"; then
513   AC_MSG_ERROR([No C++ compiler found. Cannot compile scilab without a C++ compiler])
514 fi
515
516 case "$CXX" in
517     g++-* | g++ | ccache*g++ | ccache*g++-* )
518         ## With GNU C++ Compiler
519
520         # enable the code coverage
521         if test "$enable_code_coverage" = yes; then
522             CODE_COVERAGE_CXXFLAGS="-fprofile-arcs -ftest-coverage"
523         fi
524
525         if test "$enable_debug_CXX" = yes; then
526             DEBUG_CXXFLAGS="-pipe -Wshadow -Wpointer-arith -Wcast-align -Wreturn-type -Wswitch -Wtrigraphs -Wcomment -W -Wchar-subscripts -Wformat -Wparentheses -Wsign-compare -Wwrite-strings -Wunused -Wno-strict-aliasing -Wextra -Wall -g3 -Wunsafe-loop-optimizations"
527             case "$host" in
528                 *-linux-gnu )
529                     # Only doing that under Linux
530                     DEBUG_CXXFLAGS="$DEBUG_CXXFLAGS -fdiagnostics-show-option -Werror=format-security"
531                 ;;
532             esac
533         else
534             DEBUG_CXXFLAGS="-DNDEBUG"
535         fi
536         COMPILER_CXXFLAGS="-fno-stack-protector " # bug 3131
537         COMPILER_LDFLAGS="-lstdc++"
538     ;;
539
540     clang-* | clang)
541         # clang linker expect an explict declaration
542         #¬†until the http://libcxx.llvm.org/ release, we select the GNU one.
543         COMPILER_LDFLAGS="-lstdc++"
544     ;;
545 esac
546
547 #### 64 bits detection
548 IS_64_BITS_CPU=false
549 case "$host" in
550          x86_64-*-linux-gnu | x86_64-linux-gnu | ia64-*-linux-gnu | alpha-*-linux-gnu | alpha-*-netbsd* | x86_64-*-netbsd* | sparc64-*-netbsd*)
551                 IS_64_BITS_CPU=true
552     ;;
553 esac
554
555 ##########"
556
557 case "$CC" in
558      gcc-* | gcc | ccache*gcc | ccache*gcc-* )
559    ## With GNU Compiler
560
561    # enable the code coverage
562    if test "$enable_code_coverage" = yes; then
563     CODE_COVERAGE_CFLAGS="-fprofile-arcs -ftest-coverage"
564    fi
565
566    if test "$enable_debug_C" = yes; then
567       DEBUG_CFLAGS="-pipe -Wformat -Wshadow -Wfloat-equal -Wpointer-arith -Wcast-align -Wmissing-prototypes -Wmissing-declarations  -Wstrict-prototypes  -Wmissing-noreturn -Wendif-labels -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wwrite-strings -Winline -Wredundant-decls -Wall -Wchar-subscripts -Wextra  -Wuninitialized -Wno-format-y2k -Wmissing-format-attribute -Wno-missing-field-initializers -Wno-strict-aliasing  -Wold-style-definition -g3 -Wunsafe-loop-optimizations"
568       # used to be -O
569       # -D_FORTIFY_SOURCE=2
570       case "$host" in
571       *-linux-gnu )
572       # Only doing that under Linux
573         if test "$enable_debug_linker" = yes; then
574             LDFLAGS="$LDFLAGS -Wl,--warn-common,-x"
575         fi
576           DEBUG_CFLAGS="$DEBUG_CFLAGS -fdiagnostics-show-option -Werror=format-security"
577           ;;
578           esac
579    else
580       DEBUG_CFLAGS="-DNDEBUG"
581    fi
582
583    COMPILER_CFLAGS="-fno-stack-protector " # bug 3131
584    # Explictly disable the as needed. It was disable by default but Ubuntu
585    # activated it by default since release 11.04. See bug #8961.
586    # Once all cyclic dependencies have been dropped, this line could be removed.
587    # Check if linker supports --as-needed and --no-as-needed options
588    if $LD --help 2>/dev/null | grep no-as-needed > /dev/null; then
589       COMPILER_LDFLAGS="$COMPILER_LDFLAGS -Wl,--no-as-needed"
590    fi
591
592
593    case "$host" in
594      x86_64-*-linux-gnu | x86_64-linux-gnu)
595         ARCH_CFLAGS="-m64"
596     ;;
597      alpha-*-linux-gnu)
598         ARCH_CFLAGS="-mieee-with-inexact"
599         ARCH_LDFLAGS="-mieee-with-inexact"
600     ;;
601      powerpc-*-linux-gnu)
602         ARCH_CFLAGS="-D_GNU_SOURCE"
603     ;;
604      *-*-solaris*)
605         ARCH_CFLAGS="-DSVR4 -DSYSV -Dsolaris"
606     ;;
607    *-*-freebsd*)
608      ARCH_CFLAGS="-Dfreebsd"
609      ARCH_LDFLAGS="-lm"
610      ;;
611
612   alpha-*-netbsd*)
613     ARCH_CFLAGS="-Dnetbsd -mieee"
614     ARCH_FFLAGS="-Dnetbsd -mieee"
615     ;;
616
617   *-*-netbsd*)
618     ARCH_CFLAGS="-Dnetbsd"
619     ;;
620
621   *-*-darwin*)
622     ARCH_CFLAGS="$ARCH_CFLAGS -no_compact_linkedit"
623     ARCH_CXXFLAGS="$ARCH_CXXFLAGS -no_compact_linkedit"
624     ARCH_LDFLAGS="$ARCH_LDFLAGS -no_compact_linkedit"
625     # We need this to be passed to all linker commands
626     LDFLAGS="$LDFLAGS -no_compact_linkedit"
627
628     case "$F77" in
629          gfortran-*|gfortran)
630              # Extract from gfortran -v the version it has been built for
631                MAC_DETECTED_ARCH="`$F77 -v 2>&1|grep "Target:"|sed -e "s/Target: \([[a-z0-9A-Z_]]*\).*/\1/g"`"
632          ;;
633          *)
634         AC_MSG_WARN([gfortran not used. Could not detect the architecture. Switch to the default case: x86_64])
635         MAC_DETECTED_ARCH="x86_64"
636          ;;
637     esac
638     CC="$CC -arch $MAC_DETECTED_ARCH"
639     CXX="$CXX -arch $MAC_DETECTED_ARCH"
640     ;;
641 esac
642 ;; # end of the gcc case on the $CC
643    *)
644
645         ## CC compiler (not GCC)
646         if test "$enable_debug_C" != yes; then
647              ARCH_CFLAGS="-DNDEBUG"
648         fi
649
650 case "$host" in
651 # Dec Alpha OSF 4
652   alpha*-dec-osf4.*)
653       ARCH_CFLAGS="-std -ieee_with_inexact"
654       ARCH_LDFLAGS="-ieee_with_inexact"
655       ;;
656   alpha*-dec-osf*)
657       ARCH_CFLAGS="-ieee_with_inexact"
658       ARCH_LDFLAGS="-ieee_with_inexact"
659       ;;
660   rs6000-*-*) # IBM AIX RS 6000 (NO LONGER SUPPORTED)
661     ARCH_CFLAGS="-Daix -DSYSV"
662   ;;
663   mips-sgi-irix*) # SGI
664     ARCH_CFLAGS="-DSYSV -DSVR4"
665   ;;
666   *-*-hpux9.*)
667     ARCH_CFLAGS="-DSYSV -Dhpux"
668   ;;
669   *-*-hpux10.*) # HP 10
670     if test "$enable_debug_C" = yes; then
671       ARCH_CFLAGS="-DSYSV -Dhpux"
672     else
673       ARCH_CFLAGS="-DSYSV -Dhpux +Z +DAportable"
674     fi
675   ;;
676
677   *-*-hpux11.*) # HP 11
678     ARCH_CFLAGS="-DSYSV -Dhpux -Dhppa +Z +DAportable"
679   ;;
680   *-*-solaris*) # SUN SOLARIS
681     ARCH_CFLAGS="-DSVR4 -DSYSV -Dsolaris -I/usr/local/include/"
682     ARCH_LDFLAGS="-L/usr/local/lib/"
683   ;;
684 esac
685 ;; # end of not a gcc compiler
686 esac
687
688
689 # enable the code coverage
690 if test "$enable_code_coverage" = yes; then
691    AC_PATH_PROG(LCOV, lcov)
692    if test -z "$LCOV" ; then
693         AC_MSG_ERROR([Cannot find lcov. Please install it (package lcov under Debian) or remove the option --enable-code-coverage])
694    fi
695    AC_PATH_PROG(GENHTML, genhtml)
696    if test -z "$GENHTML" ; then
697         AC_MSG_ERROR([Cannot find genhtml. Please install it (package lcov under Debian) or remove the option --enable-code-coverage])
698    fi
699    CODE_COVERAGE_LDFLAGS="-coverage"
700 fi
701 AM_CONDITIONAL(CODE_COVERAGE, test "$enable_code_coverage" = yes)
702
703 # flag for possible compilations in configure
704 SCILIBS_CFLAGS=''
705 SCILIBS_CXXFLAGS=''
706 SCILIBS_FFLAGS=''
707
708 if test $IS_64_BITS_CPU = true -o "$MACOSX" = "1"; then
709    if test $f90compatible = false; then
710       AC_MSG_ERROR([64 bits support needs a fortran 90 compiler (try --with-gfortran).])
711    fi
712    AC_DEFINE([USE_DYNAMIC_STACK], [], [If we are building a 64 bits version])
713 fi
714
715 AM_CONDITIONAL(IS_64_BITS_CPU, test $IS_64_BITS_CPU = true)
716 AM_CONDITIONAL(USE_DYNAMIC_STACK, test $IS_64_BITS_CPU = true -o "$MACOSX" = "1")
717
718 ################
719 ## SSE
720 ## By default, for x86 CPU, enable the SSE.
721 ## Note that it is already the case with 64 bits CPU
722 ## (these extensions are enabled by default by gcc)
723 ################
724
725 case "$host" in
726      i*86-linux-gnu|i*86-*-linux-gnu)
727         SSE_CFLAGS="-msse"
728         SSE_FFLAGS="-msse"
729         SSE_CXXFLAGS="-msse"
730      ;;
731 esac
732
733 #######################
734 ## test for underscores (name mangling issues between C and fortran)
735 #######################
736 AC_CHECK_UNDERSCORE_FORTRAN()
737
738
739 #################
740 ## HDF5
741 #################
742
743 AC_HDF5()
744 # The Java detection is done after in this file.
745
746 #################
747 ## XCOS
748 #################
749
750 AC_ARG_WITH(xcos,
751     AC_HELP_STRING([--without-xcos],[Disable Xcos]))
752
753 AC_ARG_WITH(modelica,
754     AC_HELP_STRING([--without-modelica],[Disable the OCaml module (modelica)]))
755
756
757 if test "$with_gui" = no; then
758    AC_MSG_WARN([GUI is disabled. Disabling then xcos])
759    with_xcos=no
760 fi
761
762 XCOS_ENABLE=no
763
764 if test "$with_xcos" != no -a "$with_gui" != no; then
765    AC_DEFINE([WITH_XCOS], [], [With XCOS])
766
767    save_LIBS="$LIBS"
768
769    AC_CHECK_LIB([rt], [clock_gettime],
770               [RT_LIB="-lrt";
771               AC_DEFINE([HAVE_CLOCK_GETTIME], [1],[Whether clock_gettime is available]) ],
772         [AC_MSG_WARN([librt: library missing (Cannot find symbol clock_gettime). Check if librt is installed (it is usually provided by the libc) and if the version is correct])]
773    )
774    LIBS="$save_LIBS"
775    AC_SUBST(RT_LIB)
776
777
778 #################
779 ## ocaml which only called when using Xcos
780 #################
781
782    if test "$with_modelica" != no; then
783       AC_CHECK_PROG_OCAML()
784    fi
785    XCOS_ENABLE=yes
786
787 fi
788
789 AC_SUBST(XCOS_ENABLE)
790
791 AM_CONDITIONAL(OCAML, test "$with_modelica" != no -a "$OCAMLC" != no -a "$OCAMLOPT" != no)
792 AM_CONDITIONAL(XCOS, test "$XCOS_ENABLE" != no)
793
794 ###########################
795 ## test for JAVA compiler
796 ###########################
797
798 if test "$with_javasci" != no -o "$with_gui" != no -o "$enable_build_help" != no; then
799
800    # See if --with-jdk command line argument is given
801      # Try to detect the installed JVM, this could be controlled
802      # by the above --with options
803      AC_JAVA_WITH_JDK
804      AC_JAVA_DETECT_JVM
805      case "$ac_java_jvm_version" in
806         1.6 | 1.7)
807         ;;
808         *)
809             AC_MSG_ERROR([Wrong version of Java. Expected at least 1.6. Found $ac_java_jvm_version])
810         ;;
811      esac
812
813    if test "$ac_java_jvm_name" = "jdk"; then
814         JAVA_HOME=$ac_java_jvm_dir
815         JAVA_VERSION=$ac_java_jvm_version
816 #     AC_JAVA_TOOLS
817         AC_JAVA_JNI_INCLUDE
818         JAVA_JNI_INCLUDE=$ac_java_jvm_jni_include_flags
819
820         case "$host_os" in
821              *Darwin* | *darwin*)
822                # Mac OS X does not link against the lib but uses -framework
823                JAVA_JNI_LIBS="-framework JavaVM"
824              ;;
825              *)
826                AC_JAVA_JNI_LIBS
827                JAVA_JNI_LIBS=$ac_java_jvm_jni_lib_flags
828                JAVA_JNI_LIBS_PRELOAD=$ac_java_jvm_ld_preload
829              ;;
830         esac
831
832         AC_JAVA_CLASSPATH
833         JAVA_CLASSPATH=$ac_java_classpath
834         AC_JAVA_TOOLS
835         AC_JAVA_ANT
836
837         case "$host_os" in
838              *Darwin* | *darwin*)
839                   JAVA_HOME=""
840              ;;
841         esac
842
843
844         if test "$with_gui" != no; then
845
846                 if test $XCOS_ENABLE = yes; then
847                    # jgraphx
848                    AC_JAVA_CHECK_PACKAGE([jgraphx],[com.mxgraph.model.mxCell],[Diagram design])
849                    JGRAPHX=$PACKAGE_JAR_FILE
850                    AC_SUBST(JGRAPHX)
851
852                    AC_JAVA_CHECK_VERSION_PACKAGE([jgraphx],[import com.mxgraph.view.mxGraph;],$JGRAPHX,[1.8.0.0],[mxGraph.VERSION],[],[])
853
854                 fi
855
856
857                 # scirenderer
858                 AC_JAVA_CHECK_PACKAGE([scirenderer],[org.scilab.forge.scirenderer.PackageInfo],[Scilab Renderer])
859                 SCIRENDERER=$PACKAGE_JAR_FILE
860                 AC_SUBST(SCIRENDERER)
861
862                 AC_JAVA_CHECK_VERSION_PACKAGE([scirenderer],[import org.scilab.forge.scirenderer.PackageInfo;],$SCIRENDERER,[0.5.6],[PackageInfo.VERSION])
863
864                # Docking system
865                 AC_JAVA_CHECK_PACKAGE([flexdock],[org.flexdock.docking.DockingManager],[Scilab Gui])
866                 FLEXDOCK=$PACKAGE_JAR_FILE
867                 AC_SUBST(FLEXDOCK)
868
869                 AC_JAVA_CHECK_VERSION_PACKAGE([flexdock],[import org.flexdock.util.Utilities;],$FLEXDOCK,[1.2.0],[Utilities.VERSION])
870
871                 # Swing look&feel implementations
872                 AC_JAVA_CHECK_PACKAGE([looks],[com.jgoodies.looks.common.MenuItemRenderer],[Scilab Gui - Look and feel],"yes")
873                 LOOKS=$PACKAGE_JAR_FILE
874
875                 # Named differently under ArchLinux or Fedora
876                 if test -z "$LOOKS"; then
877                     AC_JAVA_CHECK_PACKAGE([jgoodies-looks],[com.jgoodies.looks.common.MenuItemRenderer],[Scilab Gui - Look and feel])
878                     LOOKS=$PACKAGE_JAR_FILE
879                 fi
880                 AC_SUBST(LOOKS)
881
882                 #  Skin Look and Feel
883                 AC_JAVA_CHECK_PACKAGE([skinlf],[com.l2fprod.util.AccessUtils],[Scilab Gui - Skin Look and Feel])
884                 SKINLF=$PACKAGE_JAR_FILE
885                 AC_SUBST(SKINLF)
886
887                 # JOGL 2
888                 AC_JAVA_CHECK_PACKAGE([jogl2],[javax.media.opengl.glu.GLUnurbs],[Scilab 3D rendering - Version 2.0])
889                 JOGL2=$PACKAGE_JAR_FILE
890                 AC_SUBST(JOGL2)
891
892                 if test "$MACOSX" = 1; then
893                    echo "Check of the presence of libjogl.jnilib and libjogl_awt.jnilib disabled under Mac OS X"
894                 else
895                    LDFLAGS_save=$LDFLAGS
896                    # Provide known paths where distribs/OS can store JNI libs
897                    LDFLAGS="$LDFLAGS -L/usr/lib/jni -L/usr/lib64/jni"                   # Debian
898                    LDFLAGS="$LDFLAGS -L/usr/lib/java -L/usr/lib64/java"                 # jpackage.org
899                    LDFLAGS="$LDFLAGS -L/usr/lib/jogl -L/usr/lib64/jogl"                 # RedHat
900                    LDFLAGS="$LDFLAGS -L$SCI_SRCDIR/thirdparty -L$SCI_SRCDIR/bin"        # Scilab thirdparties
901                    AC_CHECK_LIB([jogl_desktop], [glTexParameterf], [JOGL2_LIBS="-ljogl"],[AC_MSG_WARN([Could not link against -ljogl_desktop. Will try against -ljogl2 -lGL])])
902                    if test -z "$JOGL2_LIBS"; then # The previous test failed add more options to the LDFLAGS
903                        # the space after "jogl" in the following line is on
904                        # purpose to disable the cache
905                           AC_CHECK_LIB([jogl_desktop ], [glTexParameterf],
906                        [JOGL2_LIBS="-ljogl_desktop -lGL"],
907                        [AC_MSG_ERROR(["libjogl: Library
908 missing (Cannot find symbol glTexParameterf). Check if libjogl - C/Java (JNI)
909 interface for JOGL - or libGL are installed and if the version is correct. Note
910 that you might have to update etc/librarypath.xml to provide the actual path
911 the the JNI libraries."])],
912                        [-lGL])
913                    fi
914
915                    LDFLAGS=$LDFLAGS_save
916                 fi
917
918                 # JoGL Native <=> Java connector
919                 AC_JAVA_CHECK_PACKAGE([gluegen2-rt],[jogamp.common.os.MachineDescriptionRuntime],[Scilab 3D rendering])
920                 GLUEGEN2_RT=$PACKAGE_JAR_FILE
921                 AC_SUBST(GLUEGEN2_RT)
922
923                 if test "$MACOSX" = 1; then
924                    echo "Check of the presence of libgluegen-rt.jnilib disabled under Mac OS X"
925                 else
926                    LDFLAGS_save=$LDFLAGS
927                    # Provide known paths where distribs/OS can store JNI libs
928                    LDFLAGS="$LDFLAGS -L/usr/lib/jni -L/usr/lib64/jni"                   # Debian
929                    LDFLAGS="$LDFLAGS -L/usr/lib/java -L/usr/lib64/java"                 # jpackage.org
930                    LDFLAGS="$LDFLAGS -L/usr/lib/gluegen -L/usr/lib64/gluegen"           # RedHat
931                    LDFLAGS="$LDFLAGS -L$SCI_SRCDIR/thirdparty -L$SCI_SRCDIR/bin"        # Scilab thirdparties
932                    symbol="Java_jogamp_common_jvm_JVMUtil_initialize"
933                    AC_CHECK_LIB([gluegen2-rt], [$symbol], [GLUEGEN_RT_LIBS="-lgluegen-rt"],
934                    [AC_MSG_ERROR([libgluegen2-rt: Library missing (Cannot find symbol $symbol). Check if libgluegen-rt - C/Java (JNI) interface for GLUEGEN2 - is installed and if the version is correct. Note that you might have to update etc/librarypath.xml to provide the actual path the the JNI libraries.])],
935                    [-ldl])
936                    LDFLAGS=$LDFLAGS_save
937                 fi
938
939                 # Jhall
940                 AC_JAVA_CHECK_PACKAGE([jhall],[javax.help.JHelp],[Scilab Help Browser],"yes")
941                 JHALL=$PACKAGE_JAR_FILE
942
943                 # Named differently under Mandriva or Fedora
944                 if test -z "$JHALL"; then
945                     AC_JAVA_CHECK_PACKAGE([javahelp2],[javax.help.JHelp],[Scilab Help Browser])
946                     JHALL=$PACKAGE_JAR_FILE
947                 fi
948                 AC_SUBST(JHALL)
949
950                 # Console API
951                 AC_JAVA_CHECK_PACKAGE([jrosetta-API],[com.artenum.rosetta.interfaces.core.ConsoleConfiguration],[JRosetta : Console API Artenum / Scilab],"yes")
952                 JROSETTA_API=$PACKAGE_JAR_FILE
953                 if test -z "$JROSETTA_API"; then
954                         AC_JAVA_CHECK_PACKAGE([jrosetta-api],[com.artenum.rosetta.interfaces.core.ConsoleConfiguration],[JRosetta : Console API Artenum / Scilab])
955                         JROSETTA_API=$PACKAGE_JAR_FILE
956                 fi
957                 AC_SUBST(JROSETTA_API)
958
959                 # Console Core
960                 AC_JAVA_CHECK_PACKAGE([jrosetta-engine],[com.artenum.rosetta.core.action.AbstractConsoleAction],[JRosetta : Console Core Artenum / Scilab])
961                 JROSETTA_ENGINE=$PACKAGE_JAR_FILE
962                 AC_SUBST(JROSETTA_ENGINE)
963                 AC_JAVA_CHECK_VERSION_PACKAGE([jrosetta-engine],[import com.artenum.rosetta.util.ConfigurationBuilder;],$JROSETTA_ENGINE,[1.0.4],[ConfigurationBuilder.getVersion()])
964
965
966                 # MathML rendering solution
967                 # Used in both graphic & help
968                 AC_JAVA_CHECK_PACKAGE([jeuclid-core],[net.sourceforge.jeuclid.LayoutContext],[MathML rendering solution (at least version 3.1.X)])
969                 JEUCLID_CORE=$PACKAGE_JAR_FILE
970                 AC_SUBST(JEUCLID_CORE)
971
972
973                 ################ Mandatory for graphic_export features #####
974                 # XML to PDF/other Translator
975                 AC_JAVA_CHECK_PACKAGE([fop],[org.apache.fop.pdf.PDFInfo],[XML to PDF Translator (fop)])
976                 FOP=$PACKAGE_JAR_FILE
977                 AC_SUBST(FOP)
978
979                 # xml.apache.org SVG Library (under mandriva for example)
980                 AC_JAVA_CHECK_PACKAGE([batik-all],[org.apache.batik.parser.Parser],[Apache SVG Library],"yes")
981                 BATIK=$PACKAGE_JAR_FILE
982
983                 if test -z "$BATIK"; then
984                    # Other other distribs
985                    AC_JAVA_CHECK_PACKAGE([batik],[org.apache.batik.parser.Parser],[Apache SVG Library])
986                    BATIK=$PACKAGE_JAR_FILE
987                 fi
988                 AC_SUBST(BATIK)
989                 AC_JAVA_CHECK_VERSION_PACKAGE([batik],[import org.apache.batik.Version;],$BATIK,[1.7],[Version.getVersion()])
990
991                 # Commons I/O library
992                 AC_JAVA_CHECK_PACKAGE([commons-io],[org.apache.commons.io.output.CountingOutputStream],[Commons I/O library])
993                 COMMONS_IO=$PACKAGE_JAR_FILE
994                 AC_SUBST(COMMONS_IO)
995
996                 # XML graphics common
997                 AC_JAVA_CHECK_PACKAGE([xmlgraphics-commons],[org.apache.xmlgraphics.util.Service],[Commons graphics library])
998                 XMLGRAPHICS_COMMONS=$PACKAGE_JAR_FILE
999                 AC_SUBST(XMLGRAPHICS_COMMONS)
1000
1001                 # Avalon Framework (PDF)
1002                 AC_JAVA_CHECK_PACKAGE([avalon-framework],[org.apache.avalon.framework.configuration.ConfigurationException],[Common framework for Java server application])
1003                 AVALON_FRAMEWORK=$PACKAGE_JAR_FILE
1004                 AC_SUBST(AVALON_FRAMEWORK)
1005
1006                 # XML API EXT (conversion of a SVG => PNG)
1007                 AC_JAVA_CHECK_PACKAGE([xml-apis-ext],[org.w3c.dom.svg.SVGDocument],[XML Commons external code],"yes")
1008                 XML_APIS_EXT=$PACKAGE_JAR_FILE
1009
1010                 if test -z "$XML_APIS_EXT"; then
1011                     # Other other distribs (Ex: Fedora/Redhat)
1012                     AC_JAVA_CHECK_PACKAGE([xml-commons-apis-ext],[org.w3c.dom.svg.SVGDocument],[XML Commons external code])
1013                     XML_APIS_EXT=$PACKAGE_JAR_FILE
1014                 fi
1015                 AC_SUBST(XML_APIS_EXT)
1016
1017                 ################ END Mandatory for graphic_export features #####
1018
1019
1020                 # Logging (flexdock dep)
1021                 AC_JAVA_CHECK_PACKAGE([commons-logging],[org.apache.commons.logging.LogFactory],[Apache logging])
1022                 COMMONS_LOGGING=$PACKAGE_JAR_FILE
1023                 AC_SUBST(COMMONS_LOGGING)
1024
1025                 # JLaTeXMath
1026                 AC_JAVA_CHECK_PACKAGE([jlatexmath],[org.scilab.forge.jlatexmath.TeXFormula],[LaTex Rendering])
1027                 JLATEXMATH=$PACKAGE_JAR_FILE
1028                 AC_SUBST(JLATEXMATH)
1029
1030                 AC_JAVA_CHECK_VERSION_PACKAGE([jlatexmath],[import org.scilab.forge.jlatexmath.TeXFormula;],$JLATEXMATH,[0.9.7],[TeXFormula.VERSION])
1031
1032                 AC_DEFINE([WITH_GUI],[],[With the JAVA stuff (GUI, Console, JOGL...)])
1033
1034         fi
1035
1036         # Checkstyle (code checking)
1037         AC_JAVA_CHECK_PACKAGE([checkstyle],[com.puppycrawl.tools.checkstyle.CheckStyleTask],[Checkstyle - code checking],"yes")
1038         CHECKSTYLE=$PACKAGE_JAR_FILE
1039         AC_SUBST(CHECKSTYLE)
1040
1041         # Commons beanutils (dependency of checkstyle)
1042         AC_JAVA_CHECK_PACKAGE([commons-beanutils],[org.apache.commons.beanutils.Converter],[Bean utility],"yes")
1043         COMMONS_BEANUTILS=$PACKAGE_JAR_FILE
1044         AC_SUBST(COMMONS_BEANUTILS)
1045
1046         # antlr (dependency of checkstyle)
1047         AC_JAVA_CHECK_PACKAGE([antlr],[antlr.TokenStreamException],[language tool for constructing recognizers],"yes")
1048         ANTLR=$PACKAGE_JAR_FILE
1049         AC_SUBST(ANTLR)
1050
1051         # Junit 4 (java unitary test)
1052         AC_JAVA_CHECK_PACKAGE([junit4],[org.junit.Assert],[Junit4 - Unit tests],"yes")
1053         JUNIT4=$PACKAGE_JAR_FILE
1054         AC_SUBST(JUNIT4)
1055
1056         # Cobertura (java code coverage)
1057         AC_JAVA_CHECK_PACKAGE([cobertura],[net.sourceforge.cobertura.merge.Main],[cobertura - Java code coverage],"yes")
1058         COBERTURA=$PACKAGE_JAR_FILE
1059         AC_SUBST(COBERTURA)
1060
1061         # ASM (a dependency of Cobertura)
1062         AC_JAVA_CHECK_PACKAGE([asm3],[org.objectweb.asm.Type],[Java bytecode manipulation (dep of cobertura)],"yes")
1063         ASM3=$PACKAGE_JAR_FILE
1064         AC_SUBST(ASM3)
1065         if test -z "$ASM3"; then
1066                 AC_JAVA_CHECK_PACKAGE([asm],[org.objectweb.asm.Type],[Java bytecode manipulation (dep of cobertura)],"yes")
1067                 ASM3=$PACKAGE_JAR_FILE
1068         fi
1069
1070     else
1071         AC_MSG_WARN([Sun javac not found: I will not build the java interface])
1072         if test "$ac_java_jvm_name" != ""; then
1073             AC_MSG_WARN([We do not support $ac_java_jvm_name yet])
1074         fi
1075     fi
1076     AC_SUBST(JAVA_JNI_INCLUDE)
1077     AC_SUBST(JAVA_JNI_LIBS)
1078     AC_SUBST(JAVA_HOME)
1079
1080
1081     if test "$enable_debug_java" = yes; then
1082         JAVAC_DEBUG="on"
1083     else
1084         JAVAC_DEBUG="off"
1085     fi
1086     AC_SUBST(JAVAC_DEBUG)
1087
1088     if test "$enable_build_swig" != no -a "$enable_build_swig" != ""; then
1089         SWIG_PROG()
1090         SWIG_ENABLE_JAVA()
1091         AC_SUBST(SWIG_BIN)
1092         AC_SUBST(SWIG_JAVA)
1093
1094     fi
1095
1096     # Giws is the equivalent of Swig developed by the Scilab team
1097     # in order to provide a wrapper to Java from C/C++
1098     if test "$enable_build_giws" != no -a "$enable_build_giws" != ""; then
1099         AC_GIWS([1.3.0])
1100     fi
1101 fi
1102
1103 JAVA_ENABLE=yes
1104
1105 if test -z "$JAVAC"; then
1106    JAVA_ENABLE=no
1107 fi
1108
1109 AC_SUBST(JAVA_ENABLE)
1110
1111 # Xcos is not checked here because gui=no disables it
1112 AM_CONDITIONAL(NEED_JAVA, test "$with_javasci" != no -o "$with_gui" != no -o "$enable_build_help" != no)
1113 AM_CONDITIONAL(GUI, test "$with_gui" != no)
1114 AM_CONDITIONAL(JAVASCI, test "$with_javasci" != no)
1115 AM_CONDITIONAL(SWIG, test "$enable_build_swig" != no -a "$enable_build_swig" != "")
1116 AM_CONDITIONAL(GIWS, test "$enable_build_giws" != no  -a "$enable_build_giws" != "")
1117
1118 ##############################################################
1119 ## GUI module
1120 ##############################################################
1121
1122 GUI_ENABLE=no
1123
1124 if test "$JAVA_ENABLE" != no; then
1125    GUI_ENABLE=yes
1126 fi
1127
1128 if test "$with_gui" != no; then
1129    GUI_ENABLE=yes
1130 fi
1131
1132 AC_SUBST(GUI_ENABLE)
1133
1134 ##############################################################
1135 ## test for functions in standard C library and C math library
1136 ##############################################################
1137
1138 # Provided by unistd.h
1139 AC_CHECK_FUNCS([sleep] [usleep] [dup2] [getcwd] [getpagesize] [getpass])
1140 AC_CHECK_FUNCS([rmdir])
1141
1142 AC_CHECK_FUNC([getwd],AC_DEFINE([HAVE_GETWD],[1],[Define to 1 if you have the `getwd' function.]),[AC_DEFINE([getwd(x)],[getcwd(x,1024)],[Don't use getwd but getcwd])])
1143
1144 # Provided by <regex.h>
1145 AC_CHECK_FUNCS([regcomp])
1146
1147 # Provided by stdlib.h
1148 AC_CHECK_FUNCS([atexit] [putenv] [setenv])
1149
1150 # Provided by String.h
1151 AC_CHECK_FUNCS([bzero] [memmove] [memset] [strcasecmp] [strerror] [strchr] [strdup] [strpbrk] [strrchr] [strstr] [strtol])
1152
1153 # Provided by select.h
1154 AC_CHECK_FUNCS([select])
1155
1156 # Provided by pwd.h
1157 AC_CHECK_FUNCS([endpwent])
1158
1159 # Provided by netdb.h
1160 AC_CHECK_FUNCS([gethostbyaddr] [gethostbyname] [gethostname])
1161
1162 # Provided by time.h
1163 AC_CHECK_FUNCS([gettimeofday])
1164
1165 # Provided by ctype.h
1166 AC_CHECK_FUNCS([isascii])
1167
1168 # Provided by wctype.h
1169 AC_CHECK_FUNCS([iswprint])
1170
1171 # Provided by types.h
1172 AC_CHECK_FUNCS([mkdir])
1173
1174 # Provided by mman.h
1175 AC_CHECK_FUNCS([munmap])
1176
1177 # Provided by signal.h
1178 AC_CHECK_FUNCS([strsignal])
1179
1180
1181 # Check of the libm (lib math). Macro provided by libtool.
1182 save_LDFLAGS="$LDFLAGS"
1183 LT_LIB_M()
1184
1185 # Provided by math.h
1186
1187 LDFLAGS="$LDFLAGS $LIBM"
1188 AC_CHECK_FUNCS([pow] [sqrt] [finite] [floor] [exp10])
1189
1190 ### If isinf exists or not (used to not be the case under Solaris)
1191 ### See bug #4164
1192 AC_CHECK_FUNC([isinf],,[
1193         AC_DEFINE([isinf(x)],[(!finite(x) && x==x)],[Provide a macro to do isinf])
1194 ])
1195 LIBS="$LIBS $LIBM"
1196 LDFLAGS="$save_LDFLAGS"
1197
1198 # Provided by regex.h
1199 AC_CHECK_FUNCS([re_comp])
1200
1201 # Provided by socket.h
1202 AC_CHECK_FUNCS([socket])
1203
1204 # Provided by utsname.h
1205 AC_CHECK_FUNCS([uname])
1206
1207 # Provided by wtloop.c
1208 AC_CHECK_FUNCS([setlocale])
1209
1210 # Function memcmp used in modules/fileio/src/c/xls.c
1211 AC_FUNC_MEMCMP
1212
1213 # function stat used in modules/core/src/c/link_std.c
1214 AC_FUNC_STAT
1215
1216 # function strtod used in modules/core/src/c/getval.c
1217 AC_FUNC_STRTOD
1218
1219 ########################
1220 ## test for header files
1221 ########################
1222
1223 AC_CHECK_HEADERS([limits.h values.h])
1224
1225 AC_CHECK_HEADERS([fcntl.h float.h libintl.h locale.h malloc.h netdb.h netinet/in.h nlist.h sgtty.h stddef.h sys/file.h sys/ioctl.h sys/param.h sys/socket.h sys/time.h sys/timeb.h sys/utsname.h syslog.h term.h termcap.h termio.h termios.h wchar.h wctype.h time.h])
1226
1227 # check header dirent
1228 AC_HEADER_DIRENT
1229
1230 # static struct timeval defined or not | used in modules/core/src/c/timer.c
1231 AC_HEADER_TIME
1232
1233 # check if the specific header is available or not | used in modules/core/src/c/link_SYSV.c
1234 AC_HEADER_SYS_WAIT
1235
1236
1237 #######################
1238 ## Test for structures ##
1239 #######################
1240 AC_CHECK_MEMBERS([struct stat.st_blksize])
1241 AC_CHECK_MEMBERS([struct stat.st_rdev])
1242
1243
1244 #######################
1245 ## MISC Test
1246 #######################
1247
1248 # gettext.  See http://www.gnu.org/software/hello/manual/gettext/AM_005fGNU_005fGETTEXT.html
1249 AM_GNU_GETTEXT([external])
1250 AM_GNU_GETTEXT_VERSION([0.16])
1251
1252 # function closedir used in modules/metanet/src/c/files.c
1253 AC_FUNC_CLOSEDIR_VOID
1254
1255 # Signals used in modules/core/src/c/realmain.c
1256 AC_TYPE_SIGNAL
1257
1258 # struct tm used in modules/core/src/c/history.c
1259 AC_STRUCT_TM
1260
1261 # st_blocks in the struct in modules/io/sci_gateway/c/intfilestat.c
1262 AC_STRUCT_ST_BLOCKS
1263
1264
1265 ##################
1266 ## termcap library
1267 ##################
1268
1269 # some systems may have a system curses implementation as well as ncurses
1270 # installed.  We need to be consistent in making sure we get the correct
1271 # library to go with the correct header and also provide a way for the user
1272 # to have some control over which is picked when both are available.
1273 #
1274 # For now, just check for -lcurses and then -lncurses.  The user control
1275 # may need to be revisited
1276
1277 TERMCAP_LIB=no
1278
1279 # Various observations:
1280 #
1281 #  ncurses
1282 #    - installs ncurses.h and possibly curses.h as a link to ncurses.h
1283 #    - installs -lncurses.
1284 #    - need to include term.h for tgetent() but tgetent() is in -lncurses.a
1285 #
1286 # curses as found in NetBSD-4 and NetBSD-5
1287 #    - installs curses.h
1288 #    - need to include termcap.h and link with -ltermcap for tgetent()
1289 #
1290
1291 AC_CHECK_LIB([curses],[main])
1292 if test $ac_cv_lib_curses_main = no ; then
1293     AC_CHECK_LIB([ncurses],[main])
1294 fi
1295
1296 # make sure we have what we need for tgetent
1297 AC_SEARCH_LIBS([tgetent],[termcap])
1298
1299 AC_CHECK_HEADERS([ncurses.h curses.h])
1300
1301 if test "x$ac_cv_lib_curses_main" = "xyes" -o "x$ac_cv_lib_ncurses_main" = "xyes" ; then
1302   AC_DEFINE([HAVE_TERMCAP],[],[Have Term Cap])
1303 else
1304  AC_MSG_ERROR([No termcap library detected. Please install ncurses dev library (or termcap library)])
1305 fi
1306
1307 ##################
1308 ## other libraries
1309 ##################
1310
1311 AC_CHECK_LIB(dl, dlopen)
1312
1313 AC_SEARCH_LIBS([pthread_join],[pthread])
1314
1315 #################
1316 ## FFTW
1317 #################
1318
1319 AC_ARG_WITH(fftw,
1320     AC_HELP_STRING([--without-fftw],[Disable the interface to the FFTW 3 library]))
1321
1322 FFTW_ENABLE=no
1323 if test "$with_fftw" != no; then
1324    AC_FFTW()
1325    FFTW_ENABLE=yes
1326 fi
1327
1328 AC_SUBST(FFTW_ENABLE)
1329 AM_CONDITIONAL(FFTW, test "$with_fftw" != no)
1330
1331
1332 #################
1333 ## MPI
1334 #################
1335
1336 # Not in Scilab 5.0
1337 #AC_ARG_WITH(mpi,
1338 #    [  --with-mpi               compile with MPI library])
1339 #
1340 #if test "$with_mpi" = yes; then
1341 #   AC_OPENMPI()
1342 #   # We will have to detect other implementation of OpenMPI
1343 #fi
1344 #AM_CONDITIONAL(MPI, test "$with_mpi" = yes)
1345
1346 #################
1347 ## OpenMP
1348 #################
1349
1350 AC_ARG_WITH(openmp,
1351     AC_HELP_STRING([--without-openmp],[Disable the usage of OpenMP (parallelization of some algoritms)]))
1352
1353 OPENMP_ENABLE=no
1354 if test "$with_openmp" != no; then
1355 #   AC_OPENMP
1356     OPENMP_CFLAGS="-fopenmp"
1357     OPENMP_CXXFLAGS="-fopenmp"
1358     OPENMP_LIBS="-lgomp"
1359
1360     AC_CHECK_HEADERS([omp.h], [],
1361      [AC_MSG_ERROR([Could not find omp.h])])
1362
1363     OPENMP_ENABLE=yes
1364 fi
1365 AC_SUBST(OPENMP_ENABLE)
1366 AC_SUBST(OPENMP_CFLAGS)
1367 AC_SUBST(OPENMP_CXXFLAGS)
1368 AC_SUBST(OPENMP_LIBS)
1369
1370 AM_CONDITIONAL(OPENMP, test "$with_openmp" != no)
1371
1372
1373 #######################
1374 ## Test for libxml
1375 #######################
1376
1377 AC_LIBXML2()
1378
1379 #######################
1380 ## Test for gettext
1381 #######################
1382
1383 ALL_LINGUAS="en_US fr_FR zh_CN zh_TW ru_RU ca_ES de_DE es_ES pt_BR ja_JP it_IT uk_UA pl_PL cs_CZ"
1384 ALL_LINGUAS_DOC="en_US fr_FR pt_BR ja_JP ru_RU"
1385
1386 AC_ARG_ENABLE(build-localization,
1387         AC_HELP_STRING([--disable-build-localization],[Disable the localization build])
1388         )
1389 BUILD_LOCALIZATION_ENABLE=no
1390
1391 if test "$enable_build_localization" != no; then
1392
1393    AC_SUBST(ALL_LINGUAS)
1394    AC_SUBST(ALL_LINGUAS_DOC)
1395    AC_CHECK_FUNCS([bind_textdomain_codeset])
1396
1397    AC_PATH_PROG(MSGCAT, msgcat, no)
1398 #   AC_PATH_PROG(MSGFMT, msgfmt, no)
1399 #   AC_PATH_PROG(XGETTEXT, xgettext, no)
1400
1401    if test x$MSGFMT = xno; then
1402       AC_ERROR([The msgfmt command is required to build Scilab.  If it is installed on your system, ensure that it is in your path.  If it is not, install GNU gettext to continue or use the option --disable-build-localization ])
1403       fi
1404     if test x$MSGCAT = xno; then
1405       AC_ERROR([The msgcat command is required to build Scilab.  If it is installed on your system, ensure that it is in your path.  If it is not, install GNU gettext to continue or use the option --disable-build-localization ])
1406     fi
1407     BUILD_LOCALIZATION_ENABLE=yes
1408 fi
1409 AM_CONDITIONAL(GENERATE_LOCALIZATION_FILES, test "$BUILD_LOCALIZATION_ENABLE" = yes)
1410
1411 #######################
1412 ## Test for blas/Atlas and lapack
1413 #######################
1414 AC_MSG_CHECKING([if BLAS, ATLAS or MKL is available])
1415 echo ""
1416 ACX_BLAS(
1417         [AC_MSG_RESULT([$BLAS_TYPE found])]
1418         ,
1419         AC_MSG_ERROR([Impossible to find a BLAS compatible library (see BLAS or ATLAS).])
1420         )
1421
1422 AC_MSG_CHECKING([if LAPACK is available])
1423 echo ""
1424 ACX_LAPACK(
1425         [AC_MSG_RESULT([$LAPACK_TYPE found])],
1426         AC_MSG_ERROR([Impossible to find the LAPACK library.])
1427         )
1428
1429
1430 AC_ARG_WITH(arpack-ng,
1431     AC_HELP_STRING([--without-arpack-ng],[Disable the interface to ARPACK-NG]))
1432
1433 ARPACK_NG=no
1434 if test "$with_arpack_ng" != no; then
1435    ARPACK_NG=yes
1436    AC_MSG_CHECKING([if ARPACK-NG is available])
1437 echo ""
1438 ACX_ARPACK(
1439         [AC_MSG_RESULT([ARPACK-NG library found])],
1440         AC_MSG_ERROR([Impossible to find the ARPACK library. Please note that arpack was bundled with version prior to 5.4.0 and Scilab requires arpack-ng ( http://forge.scilab.org/index.php/p/arpack-ng/ ).])
1441         )
1442
1443 CHECK_ARPACK_OK(
1444 [AC_MSG_RESULT([Working ARPACK-NG library found (probably ARPACK-NG or a patched version of ARPACK)])],
1445 [AC_MSG_ERROR([ARPACK library found, but seems not to work properly. Please make sure you are using arpack-ng])
1446 ])
1447 else
1448    AC_MSG_CHECKING([Skip ARPACK-NG detection])
1449 fi
1450
1451 AM_CONDITIONAL(ARPACK_NG, test "$ARPACK_NG" != "no")
1452
1453
1454 #################
1455 ## UMFPACK
1456 #################
1457
1458 AC_ARG_WITH(umfpack,
1459     AC_HELP_STRING([--without-umfpack],[Disable the interface to the UMFPACK library]))
1460
1461 UMFPACK_ENABLE=no
1462 if test "$with_umfpack" != no; then
1463    AC_UMFPACK([$BLAS_LIBS])
1464    UMFPACK_ENABLE=yes
1465 fi
1466
1467 AC_SUBST(UMFPACK_ENABLE)
1468 AM_CONDITIONAL(UMFPACK, test "$with_umfpack" != no)
1469
1470 #######################
1471 ## Test for PCRE
1472 #######################
1473
1474 AC_PCRE()
1475
1476 #################
1477 ## Tcl/Tk library
1478 #################
1479
1480 WITH_TKSCI=no
1481 if test "$with_tk" != no; then
1482    if test "$MACOSX" = "1"; then
1483       AC_MSG_ERROR([Due to technical constraints, Tcl/Tk must be disabled under Mac OS X (--without-tk)])
1484    fi
1485
1486     # check user arguments
1487     USER_TCL_LIB_PATH=""
1488     USER_TCL_INC_PATH=""
1489     AC_ARG_WITH(tcl-library,
1490         AC_HELP_STRING([--with-tcl-library=DIR],[Set the path to the TCL library]),
1491         [  USER_TCL_LIB_PATH=$withval
1492     ])
1493     AC_ARG_WITH(tcl-include,
1494         AC_HELP_STRING([--with-tcl-include=DIR],[Set the path to the TCL headers]),
1495         [  USER_TCL_INC_PATH=$withval
1496     ])
1497
1498     USER_TK_LIB_PATH=$USER_TCL_LIB_PATH
1499     USER_TK_INC_PATH=$USER_TCL_INC_PATH
1500
1501     AC_ARG_WITH(tk-library,
1502         AC_HELP_STRING([--with-tk-library=DIR],[Set the path to the TK library]),
1503         [  USER_TK_LIB_PATH=$withval
1504     ])
1505
1506     AC_ARG_WITH(tk-include,
1507         AC_HELP_STRING([--with-tk-include=DIR],[Set the path to the TK headers]),
1508         [  USER_TK_INC_PATH=$withval
1509     ])
1510
1511 ###########################
1512 ########## X11 checks
1513 ###########################
1514         ## This check is mandatory since tk needs Xlib headers and libs
1515         AC_PATH_XTRA
1516         ##
1517
1518     saved_cflags="$CFLAGS"
1519     saved_ldflags="$LDFLAGS"
1520     saved_cppflags="$CXXFLAGS"
1521
1522     AC_CHECK_LIB([dl], [main], [TCLTK_LIBS=" -ldl"])
1523     AC_CHECK_TCLTK
1524
1525     # set variables
1526     if test "$WITH_TKSCI" = yes; then
1527         AC_DEFINE([WITH_TK], [], [With TK])
1528     else
1529         AC_MSG_ERROR([TCL/TK not found. Use --without-tk or specify the librairies and include paths manually])
1530     fi
1531
1532     AC_SUBST(TCLTK_LIBS)
1533     AC_SUBST(TCL_INC_PATH)
1534     AC_SUBST(TK_INC_PATH)
1535
1536 fi
1537 AC_SUBST(WITH_TKSCI)
1538 AM_CONDITIONAL(TCLTK, test "$WITH_TKSCI" = yes)
1539
1540 #################
1541 ## MATIO LIBRARY (MAT File I/O Library)
1542 #################
1543
1544
1545 AC_ARG_WITH(matio,
1546     AC_HELP_STRING([--without-matio],[Disable the interface to Matio (MAT File I/O library)]))
1547
1548 AC_ARG_WITH(matio_include,
1549         AC_HELP_STRING([--with-matio-include=DIR],[Set the path to the MATIO headers]),
1550         [with_matio_include="-I$withval"], [])
1551
1552 AC_ARG_WITH(matio_library,
1553         AC_HELP_STRING([--with-matio-library=DIR],[Set the path to the MATIO libraries]),
1554         [with_matio_library="-L$withval"], [])
1555
1556 MATIO_ENABLE=no
1557
1558 if test "$with_matio" != no; then
1559    if test -n "$with_matio_include" -o -n "$with_matio_library" ; then
1560       MATIO_CFLAGS="$with_matio_include"
1561       MATIO_LIBS="$with_matio_library -lm -lz -lmatio"
1562    else
1563       PKG_CHECK_MODULES(MATIO, [matio >= 1.3.3])
1564    fi
1565
1566    save_CFLAGS="$CFLAGS"
1567    save_LIBS="$LIBS"
1568
1569    CFLAGS="$CFLAGS $MATIO_CFLAGS"
1570    LIBS="$LIBS $MATIO_LIBS"
1571
1572    AC_CHECK_HEADERS([matio.h matioConfig.h], [],
1573      [AC_MSG_ERROR([Invalid MATIO_CFLAGS returned by pkg-config. Try to define MATIO_CFLAGS.])])
1574    AC_CHECK_LIB([matio], [Mat_Open], [],
1575      [AC_MSG_ERROR([Invalid MATIO_LIBS returned by pkg-config. Try to define MATIO_LIBS.])])
1576
1577    LIBS="$save_LIBS"
1578    CFLAGS="$save_CFLAGS"
1579
1580    AC_DEFINE([WITH_MATIO], [], [With the MATIO library])
1581    MATIO_ENABLE=yes
1582 fi
1583
1584
1585 AC_SUBST(MATIO_ENABLE)
1586 AM_CONDITIONAL(MATIO, test "$with_matio" != no)
1587
1588 #############################
1589 ## Documentation management #
1590 #############################
1591
1592 HELP_ENABLE=yes
1593
1594 AC_ARG_ENABLE(build-help,
1595         AC_HELP_STRING([--disable-build-help],[Disable the help build])
1596         )
1597
1598 if test "$enable_build_help" != no; then
1599     AC_DOCBOOK()
1600 else
1601     HELP_ENABLE=no
1602 fi
1603
1604 if test "$JAVA_ENABLE" = no; then
1605     HELP_ENABLE=no
1606 fi
1607
1608 AC_SUBST(HELP_ENABLE)
1609
1610 AM_CONDITIONAL(BUILD_HELP, test $HELP_ENABLE = yes)
1611
1612 ## Install XML help files ###
1613
1614 AC_ARG_WITH(install-help-xml,
1615         AC_HELP_STRING([--with-install-help-xml],[make install will install XML files])
1616         )
1617 HELP_INSTALL_ENABLE=no
1618 if test "$with_install_help_xml" != no -a "$with_install_help_xml" != ""; then
1619    HELP_INSTALL_ENABLE=yes
1620 fi
1621 AM_CONDITIONAL(INSTALL_HELP_XML, test "$HELP_INSTALL_ENABLE" != "")
1622
1623 ##############################################################
1624 ## Javasci module
1625 ##############################################################
1626
1627 JAVASCI_ENABLE=yes
1628
1629 if test "$JAVA_ENABLE" = no -o "$JAVASCI" = no; then
1630    JAVASCI_ENABLE=no
1631 fi
1632
1633 AC_SUBST(JAVASCI_ENABLE)
1634
1635
1636 ##############################################################
1637 ## Enable test a compilation time
1638 ##############################################################
1639
1640 COMPILATION_TESTS=no
1641 if test "$enable_compilation_tests" != no -a "$enable_compilation_tests" != ""; then
1642    COMPILATION_TESTS=yes
1643 fi
1644
1645 if test COMPILATION_TESTS=yes -a "$JUNIT4" == ""; then
1646    AC_MSG_WARN([--enable-compilation-tests deactivated: Could not find Junit4"])
1647    COMPILATION_TESTS=no
1648 fi
1649
1650 AM_CONDITIONAL(COMPILATION_TESTS, test "$COMPILATION_TESTS" != "no")
1651
1652 ##############################################################
1653 ## demo_tools module
1654 ##############################################################
1655
1656 DEMOTOOLS_ENABLE=yes
1657
1658 if test "$GUI_ENABLE" = no; then
1659    DEMOTOOLS_ENABLE=no
1660 fi
1661
1662 AC_SUBST(DEMOTOOLS_ENABLE)
1663
1664 ##############################################################
1665 ## graphics/renderer/graphic_export module
1666 ##############################################################
1667
1668 GRAPHICS_ENABLE=yes
1669
1670 if test "$GUI_ENABLE" = no; then
1671    GRAPHICS_ENABLE=no
1672 fi
1673
1674 AC_SUBST(GRAPHICS_ENABLE)
1675
1676 #########################
1677 ## libtool
1678 #########################
1679
1680 AM_DISABLE_STATIC
1681 LT_PREREQ([2.2.7])
1682 AC_PROG_LIBTOOL([shared dlopen])
1683 AM_PROG_LIBTOOL
1684
1685
1686 # Avoid to link all the dep from others libraries (*.la included by LIBADD)
1687 link_all_deplibs=no
1688
1689 # Check to see if building shared libraries
1690 libtool_build_shared_libs=no
1691 if test "$enable_shared" = "yes"; then
1692   libtool_build_shared_libs=yes
1693 fi
1694
1695 # Check to see if building static libraries
1696 libtool_build_static_libs=no
1697 if test "$enable_static" = "yes"; then
1698   libtool_build_static_libs=yes
1699 fi
1700
1701 # AM_CONDITIONAL(ENABLE_STATIC, test "$libtool_build_static_libs" = yes)
1702 # Fake to disable the static build
1703 AM_CONDITIONAL(ENABLE_STATIC, test "$libtool_build_static_libs" = xxxx)
1704
1705 AC_C_CONST()
1706 AC_C_INLINE()
1707
1708 AC_BACKTRACE()
1709
1710 ##########
1711 ##### Code quality
1712 ##########
1713 AC_PATH_PROG(SPLINT, splint, no)
1714
1715 ##########
1716 ##### Detect ccache and use it by default if available
1717 ##########
1718
1719 AC_ARG_ENABLE(ccache,
1720         AC_HELP_STRING([--disable-ccache],[Disable the use of ccache])
1721         )
1722 AC_PATH_PROG(CCACHE, ccache)
1723 if test x"$CCACHE" != x -a "$enable_ccache" != no; then
1724   CC="$CCACHE $CC"
1725   CXX="$CCACHE $CXX"
1726 fi
1727
1728 #######################
1729 ###### Creation of the header file (machine.h)
1730 #######################
1731
1732 AC_DEFINE_UNQUOTED([PATH_SEPARATOR], ["$PATH_SEPARATOR"],
1733 [The default path separator character.])
1734
1735 AH_TOP([#ifndef MACHINE_H
1736 #define MACHINE_H
1737 /* This file defines global element configuration of the build host */
1738 ])
1739
1740 AH_BOTTOM([
1741
1742 #ifdef DIR_SEPARATOR
1743        #undef DIR_SEPARATOR
1744 #endif
1745 #define DIR_SEPARATOR "/"
1746
1747 #endif /* MACHINE_H  */
1748 ])
1749
1750 # Define the standard extension of a dynamic library
1751 AC_DEFINE_UNQUOTED([SHARED_LIB_EXT],["$shrext_cmds"],[Extension of a shared library])
1752
1753 #################
1754 ## stop on warning
1755 #################
1756
1757 # Stop to compile scilab when a warning is found ...
1758 # This stuff is at the end of the configure.ac because it causes some
1759 # problem with AC_COMPILE (the -Werror is added to the test)
1760 #
1761 dnl @TODO : -O0 is only to bypass Stack shit... Must be removed.
1762 if test "$enable_stop_on_warning" = yes; then
1763     WARNING_CFLAGS="-Werror=implicit-function-declaration -O0"
1764     WARNING_CXXFLAGS="-Werror=implicit-function-declaration -O0"
1765 fi
1766
1767 # SCI_*FLAGS contains all defaults values detected on configure
1768 SCI_CFLAGS=$(echo   $LARGEFILE_CFLAGS   $CODECOVERAGE_CFLAGS   $DEBUG_CFLAGS   $ARCH_CFLAGS   $COMPILER_CFLAGS   $SCILIBS_CFLAGS   $SSE_CFLAGS   $BACKTRACE_CFLAGS   $WARNING_CFLAGS)
1769 SCI_CXXFLAGS=$(echo $LARGEFILE_CXXFLAGS $CODECOVERAGE_CXXFLAGS $DEBUG_CXXFLAGS $ARCH_CXXFLAGS $COMPILER_CXXFLAGS $SCILIBS_CXXFLAGS $SSE_CXXFLAGS $BACKTRACE_CXXFLAGS $WARNING_CXXFLAGS)
1770 SCI_FFLAGS=$(echo   $LARGEFILE_FFLAGS   $CODECOVERAGE_FFLAGS   $DEBUG_FFLAGS   $ARCH_FFLAGS   $COMPILER_FFLAGS   $SCILIBS_FFLAGS   $SSE_FFLAGS   $BACKTRACE_FFLAGS   $WARNING_FFLAGS)
1771 SCI_LDFLAGS=$(echo  $LARGEFILE_LDFLAGS  $CODECOVERAGE_LDFLAGS  $DEBUG_LDFLAGS  $ARCH_LDFLAGS  $COMPILER_LDFLAGS  $SCILIBS_LDFLAGS  $SSE_LDFLAGS  $BACKTRACE_LDFLAGS  $WARNING_LDFLAGS)
1772 AC_SUBST(SCI_CFLAGS)
1773 AC_SUBST(SCI_CXXFLAGS)
1774 AC_SUBST(SCI_FFLAGS)
1775 AC_SUBST(SCI_LDFLAGS)
1776
1777 AC_CONFIG_FILES([
1778 libs/MALLOC/Makefile
1779 libs/dynamiclibrary/Makefile
1780 libs/doublylinkedlist/Makefile
1781 libs/hashtable/Makefile
1782 libs/libst/Makefile
1783 contrib/Makefile
1784 desktop/images/icons/Makefile
1785 desktop/Makefile
1786 modules/helptools/Makefile
1787 modules/data_structures/Makefile
1788 modules/differential_equations/Makefile
1789 modules/optimization/Makefile
1790 modules/elementary_functions/Makefile
1791 modules/special_functions/Makefile
1792 modules/io/Makefile
1793 modules/completion/Makefile
1794 modules/history_manager/Makefile
1795 modules/jvm/Makefile
1796 modules/commons/Makefile
1797 modules/sound/Makefile
1798 modules/statistics/Makefile
1799 modules/mexlib/Makefile
1800 modules/sparse/Makefile
1801 modules/linear_algebra/Makefile
1802 modules/polynomials/Makefile
1803 modules/symbolic/Makefile
1804 modules/signal_processing/Makefile
1805 modules/arnoldi/Makefile
1806 modules/interpolation/Makefile
1807 modules/intersci/Makefile
1808 modules/localization/Makefile
1809 modules/cacsd/Makefile
1810 modules/boolean/Makefile
1811 modules/integer/Makefile
1812 modules/double/Makefile
1813 modules/fileio/Makefile
1814 modules/spreadsheet/Makefile
1815 modules/string/Makefile
1816 modules/time/Makefile
1817 modules/graphics/Makefile
1818 modules/graphic_export/Makefile
1819 modules/graphic_objects/Makefile
1820 modules/renderer/Makefile
1821 modules/action_binding/Makefile
1822 modules/gui/Makefile
1823 modules/randlib/Makefile
1824 modules/tclsci/Makefile
1825 modules/windows_tools/Makefile
1826 modules/core/Makefile
1827 modules/prebuildjava/Makefile
1828 modules/api_scilab/Makefile
1829 modules/call_scilab/Makefile
1830 modules/types/Makefile
1831 modules/hdf5/Makefile
1832 modules/fftw/Makefile
1833 modules/umfpack/Makefile
1834 modules/scicos/Makefile
1835 modules/scicos_blocks/Makefile
1836 modules/functions/Makefile
1837 modules/dynamic_link/Makefile
1838 modules/overloading/Makefile
1839 modules/javasci/Makefile
1840 modules/m2sci/Makefile
1841 modules/compatibility_functions/Makefile
1842 modules/development_tools/Makefile
1843 modules/output_stream/Makefile
1844 modules/console/Makefile
1845 modules/demo_tools/Makefile
1846 modules/genetic_algorithms/Makefile
1847 modules/simulated_annealing/Makefile
1848 modules/parameters/Makefile
1849 modules/matio/Makefile
1850 modules/atoms/Makefile
1851 modules/xcos/Makefile
1852 modules/scinotes/Makefile
1853 modules/ui_data/Makefile
1854 modules/graph/Makefile
1855 modules/parallel/Makefile
1856 modules/modules_manager/Makefile
1857 modules/history_browser/Makefile
1858 modules/preferences/Makefile
1859 modules/xml/Makefile
1860 modules/external_objects/Makefile
1861 modules/Makefile
1862 libs/Makefile
1863 Makefile
1864 scilab.pc
1865 etc/modules.xml
1866 etc/classpath.xml
1867 etc/Info.plist
1868 etc/logging.properties
1869 scilab.properties
1870 scilab-lib.properties
1871 scilab-lib-doc.properties
1872 modules/helptools/etc/SciDocConf.xml
1873 modules/core/includes/version.h
1874 ])
1875
1876 # Detection of the module for the future version of Scilab 6
1877 # ie we detect module which ends with _yasp
1878
1879 if test "$enable_yasp" = yes; then
1880    AC_CONFIG_FILES([
1881    modules/development_tools/src/fake/Makefile
1882   ])
1883 fi
1884
1885 # This script is used by Xcos in order to regenerate the function/block list
1886 AC_CONFIG_COMMANDS_POST([chmod +x $SCI_SRCDIR_FULL/modules/scicos_blocks/src/scripts/GenBlocks.sh $SCI_SRCDIR_FULL/modules/dynamic_link/src/scripts/scicompile.sh $SCI_SRCDIR_FULL/modules/dynamic_link/src/scripts/compilerDetection.sh $SCI_SRCDIR_FULL/modules/dynamic_link/src/scripts/configure])
1887
1888
1889 #MAN_FR MAN_ENG
1890 #modules/mpi/Makefile
1891 #for top_builddir in . .. ../.. $ac_auxdir $ac_auxdir/..; do
1892 #  test -f $top_builddir/configure && break
1893 #done
1894
1895
1896 #if test "$with_mpi" = yes; then
1897 #AC_CONFIG_FILES([modules/mpi/Makefile])
1898 #fi
1899
1900 # Generate stack.h
1901 if test "$IS_64_BITS_CPU" = true -o "$MACOSX" = "1"; then
1902    stack_h_cpp_flags=-DUSE_DYNAMIC_STACK
1903 else
1904    stack_h_cpp_flags=
1905 fi
1906
1907 AC_CONFIG_COMMANDS([modules/core/includes/stack.h],
1908   [if ! $CPP $stack_h_cpp_flags - < $srcdir/modules/core/includes/stack.h.in |\
1909               $GREP -v '^#' > $srcdir/modules/core/includes/stack.h ; then
1910      AC_MSG_ERROR([stack.h generation failed])
1911    fi],
1912   [CPP="$CPP"
1913    GREP="$GREP"
1914    stack_h_cpp_flags="$stack_h_cpp_flags"
1915   ])
1916
1917 AC_OUTPUT
1918
1919 # To distribution packager, you can uncomment this stuff is you want to
1920 # disable the rpath issue
1921 # However, you will have to set all the LD_LIBRARY_PATH to .libs/ directory
1922 # since scilab is compiling macros and help into the source tree (ie before
1923 # the "make install")
1924 # You should consider using chrpath:
1925 # http://directory.fsf.org/project/chrpath/
1926 # to remove it before the make install
1927
1928 #case ${host} in
1929 #  *-pc-linux-gnu)
1930 #    AC_MSG_RESULT([Fixing libtool for -rpath problems.])
1931 #    sed < libtool > libtool-2 \
1932 #    's/^hardcode_libdir_flag_spec.*$/hardcode_libdir_flag_spec=" -D__LIBTOOL_IS_A_FOOL__ "/'
1933 #    mv libtool-2 libtool
1934 #    chmod 755 libtool
1935 #  ;;
1936 #esac
1937 #
1938
1939 echo ""
1940
1941 echo "Scilab is configured as follows. Please verify that this configuration"
1942 echo "matches your expectations."
1943 echo ""
1944 echo "Host system type : $host"
1945 echo ""
1946 echo "                  Option                        Value"
1947 echo "-------------------------------------------------------------------------"
1948 echo "Shared libraries.......      --enable-shared=$libtool_build_shared_libs"
1949 echo "Static libraries.......      --enable-static=$libtool_build_static_libs"
1950 echo "GNU ld.................      --with-gnu-ld=$with_gnu_ld"
1951 echo "Enable debug ..........      --enable-debug=$enable_debug"
1952 echo "Enable debug C.........      --enable-debug-C=$enable_debug_C"
1953 echo "Enable debug C++.......      --enable-debug-CXX=$enable_debug_CXX"
1954 echo "Enable debug Java......      --enable-debug-java=$enable_debug_java"
1955 echo "Enable debug Fortran...      --enable-debug-fortran=$enable_debug_fortran"
1956 echo "Enable stop on warning.      --enable-stop-on-warning=$enable_stop_on_warning"
1957
1958 echo ""
1959 echo "Compiler Configuration:"
1960 echo "  Intel (--with-intelcompilers) .... =        $with_intelcompilers"
1961 echo "  GNU gcc (--with-gcc) ............. =        $with_gcc"
1962 echo "  GNU Fortran 95 (--with-gfortran) . =        $with_gfortran"
1963 echo ""
1964 echo "Options:"
1965 echo "  Do not use TCL/TK (--without-tk) ................. = $with_tk"
1966 echo "  TCL include (--with-tcl-include) ................. = $USER_TCL_INC_PATH"
1967 echo "  TCL library (--with-tcl-library) ................. = $USER_TCL_LIB_PATH"
1968 echo "  TK include (--with-tk-include) ................... = $USER_TK_INC_PATH"
1969 echo "  TK library (--with-tk-library) ................... = $USER_TK_LIB_PATH"
1970 echo "  Install XML Help (--with-install-help-xml) ....... = $with_install_help_xml"
1971 echo "  Compilation tests (--enable-compilation-tests) ... = $COMPILATION_TESTS"
1972 echo "  Make the package relocatable (--enable-relocatable)= $RELOCATABLE"
1973 echo "  Use FFTW (--without-fftw) ........................ = $with_fftw"
1974 echo "  Use MATIO (--without-matio) ...................... = $with_matio"
1975
1976 echo ""
1977 if test "$with_gui" = no; then
1978    echo "Not using Xcos because of the option --without-gui"
1979 else
1980 if test $XCOS_ENABLE = yes; then
1981    echo "Xcos enable"
1982    echo "Build modelica compiler (--without-modelica) ....... = $with_modelica"
1983    echo ""
1984    if test "$with_ocaml" != no -a "$OCAMLC" != no -a "$OCAMLOPT" != no; then
1985      echo "Ocaml Configuration (for Modelica compiler):"
1986      echo "  OCAMLC ............. = $OCAMLC"
1987      echo "  OCAMLOPT ........... = $OCAMLOPT"
1988      echo "  OCAMLDEP ........... = $OCAMLDEP"
1989    else
1990      echo "Will not build Modelica compiler"
1991    fi
1992 else
1993    echo "Not using Xcos"
1994 fi
1995 fi
1996
1997 echo ""
1998 if test "$enable_code_coverage" = yes;  then
1999    echo "Code coverage configuration:"
2000    echo "  LCOV .............. = $LCOV"
2001    echo "  GENHTML ........... = $GENHTML"
2002 else
2003    echo "Not using code coverage"
2004 fi
2005
2006 echo ""
2007 if test $OPENMP_ENABLE = yes; then
2008    echo "OpenMP Configuration:"
2009    echo "OpenMP CFLAGS ...... = $OPENMP_CFLAGS"
2010    echo "OpenMP CXXFLAGS .... = $OPENMP_CXXFLAGS"
2011    echo "OpenMP LIBS ........ = $OPENMP_LIBS"
2012    echo "OpenMP FFLAGS ...... = $OPENMP_LDFLAGS"
2013 else
2014    echo "Not using OpenMP"
2015 fi
2016
2017 echo ""
2018 if test $FFTW_ENABLE = yes;  then
2019    echo "FFTW Configuration:"
2020    echo "  FFTW LIBS .......... = $FFTW3_LIB"
2021    echo "  FFTW CFLAGS ........ = $FFTW3_CFLAGS"
2022 else
2023    echo "Not using FFTW"
2024 fi
2025
2026 echo ""
2027 if test $MATIO_ENABLE = yes;  then
2028    echo "MATIO Configuration:"
2029    echo "  MATIO LIBS .......... = $MATIO_LIBS"
2030    echo "  MATIO CFLAGS ........ = $MATIO_CFLAGS"
2031 else
2032    echo "Not using MATIO"
2033 fi
2034
2035 echo ""
2036 if test $UMFPACK_ENABLE = yes;  then
2037    echo "UMFPACK Configuration:"
2038    echo "  UMFPACK LIBS ....... = $UMFPACK_LIB"
2039    echo "  UMFPACK CFLAGS ..... = $UMFPACK_CFLAGS"
2040    if test $SUITESPARSE = yes; then
2041       echo "  UMFPACK SUITESPARSE  = Yes"
2042    else
2043       echo "  UMFPACK SUITESPARSE  = No"
2044    fi
2045 else
2046    echo "Not using UMFPACK"
2047 fi
2048
2049
2050 echo ""
2051 echo "BLAS/LAPACK/ATLAS Configuration:"
2052 echo "  BLAS LIBS ............. = $BLAS_LIBS"
2053 echo "  BLAS TYPE ............. = $BLAS_TYPE"
2054 echo "  LAPACK LIBS ........... = $LAPACK_LIBS"
2055 echo "  LAPACK TYPE ........... = $LAPACK_TYPE"
2056 echo "  ARPACK LIBS ........... = $ARPACK_LIBS"
2057 echo ""
2058
2059 #if test "$with_mpi" = yes; then
2060 #   echo "MPI Configuration:"
2061 #   echo "  MPI LIBS ........... = $MPILIBS"
2062 #   echo "  MPI C Compiler ..... = $MPICC"
2063 #   echo "  MPI C++ Compiler ... = $MPICXX"
2064 #   echo "  MPI F77 Compiler ... = $MPIF77"
2065 #else
2066 #   echo "Not using MPI"
2067 #fi
2068
2069 #if test "$with_openmpi" != "no"; then
2070 #   echo "OpenMPI Configuration:"
2071 #   echo "  OpenMPI LIBS ........... = $OPENMPI_LIBS"
2072 #   echo "  OpenMPI C Compiler ..... = $OPENMPI_CC"
2073 #   echo "  OpenMPI F77 Compiler ... = $MPIF77"
2074 #else
2075 #   echo "Not using MPI"
2076 #fi
2077
2078 echo ""
2079 if test $BUILD_LOCALIZATION_ENABLE != no; then
2080    echo "Gettext/localization configuration:"
2081    echo "  xgettext ............... = $XGETTEXT"
2082    echo "  msgfmt  ................ = $MSGFMT"
2083    echo "  msgfmt_opts ............ = $MSGFMT_OPTS"
2084    echo "  msgcat  ................ = $MSGCAT"
2085 else
2086    echo "Won't generate localization files"
2087 fi
2088
2089 echo ""
2090 if test $HELP_ENABLE = yes; then
2091    echo "Documentation building configuration:"
2092    echo "  Docbook XSL path ....... = $DOCBOOK_ROOT"
2093    echo "  Saxon XSLT ............. = $SAXON"
2094    echo "  XML commons external ... = $XML_APIS_EXT"
2095 else
2096    echo "No documentation generated"
2097 fi
2098
2099 echo ""
2100 echo "Java Configuration:"
2101 if test ! -z "$JAVAC"; then
2102 echo "  JAVA_HOME ........... = $JAVA_HOME"
2103 echo "  JAVAC ............... = $JAVAC"
2104 echo "  JAVA_CLASSPATH ...... = $JAVA_CLASSPATH"
2105 echo "  JAVA_VERSION ........ = $JAVA_VERSION"
2106 echo "  JAVAC_FLAGS ......... = $JAVAC_FLAGS"
2107 echo "  JAVA_JNI_INCLUDE .... = $JAVA_JNI_INCLUDE"
2108 echo "  JAVA_JNI_LIBS ....... = $JAVA_JNI_LIBS"
2109 echo "  JAVA_JNI_LIBS_PRELOAD = $JAVA_JNI_LIBS_PRELOAD"
2110 echo "  JAVA ................ = $JAVA"
2111 echo "  JAVADOC ............. = $JAVADOC"
2112 echo "  JAR ................. = $JAR"
2113 echo "  ANT ................. = $ANT"
2114 else
2115 echo "  JAVA disabled"
2116 fi
2117
2118
2119 echo ""
2120 echo "Java dependencies:"
2121 if test ! -z "$JAVAC"; then
2122 echo "  Flexdock ............ = $FLEXDOCK"
2123 echo "  JOGL 2............... = $JOGL2"
2124 echo "  JOGL 2 LIBS (JNI) ... = $JOGL2_LIBS"
2125 echo "  Gluegen 2 ........... = $GLUEGEN2_RT"
2126 echo "  Gluegen 2 LIBS (JNI)  = $GLUEGEN2_RT_LIBS"
2127 echo "  Jeuclid (MathML) .... = $JEUCLID_CORE"
2128 echo "  Jhall  .............. = $JHALL"
2129 echo "  Jrosetta (API) ...... = $JROSETTA_API"
2130 echo "  Jrosetta (Engine) ... = $JROSETTA_ENGINE"
2131 echo "  Commons Logging ..... = $COMMONS_LOGGING"
2132 echo "  JGraph X ............ = $JGRAPHX"
2133 echo "  SciRenderer ......... = $SCIRENDERER"
2134 echo "  JLaTeXMath .......... = $JLATEXMATH"
2135 fi
2136
2137 echo ""
2138 if test ! -z "$JAVAC"; then
2139 echo "Documentation, graphic export:"
2140 echo "  FOP (XML => PDF) .... = $FOP"
2141 echo "  JLaTeXMath Fop ...... = $JLATEXMATH_FOP"
2142 echo "  Batik (SVG) ......... = $BATIK"
2143 echo "  Avalon Framework .... = $AVALON_FRAMEWORK"
2144 echo "  Commons I/O ......... = $COMMONS_IO"
2145 echo "  XML graphics commons  = $XMLGRAPHICS_COMMONS"
2146 fi
2147
2148
2149 echo ""
2150 echo "Code quality (optional):"
2151 echo "  Checkstyle .......... = $CHECKSTYLE"
2152 echo "  Commons-beanutils ... = $COMMONS_BEANUTILS"
2153 echo "  Antlr ............... = $ANTLR"
2154 echo "  Junit4 .............. = $JUNIT4"
2155 echo "  Cobertura ........... = $COBERTURA"
2156 echo "  splint .............. = $SPLINT"
2157
2158 echo ""
2159 echo "TCL/TK configuration:"
2160 echo "  TK_INC_PATH ........ = $TK_INC_PATH"
2161 echo "  TCL_INC_PATH ....... = $TCL_INC_PATH"
2162 echo "  TCLTK_LIBS ......... = $TCLTK_LIBS"
2163 echo "  TCL_SERIAL_VERSION . = $TCL_SERIAL_VERSION"
2164 echo "  TK_SERIAL_VERSION .. = $TK_SERIAL_VERSION"
2165
2166 echo ""
2167 echo "XML configuration:"
2168 echo "  XML_FLAGS .......... = $XML_FLAGS"
2169 echo "  XML_LIBS ........... = $XML_LIBS"
2170 echo "  XML_VERSION ........ = $XML_VERSION"
2171
2172 echo ""
2173 echo "HDF5 configuration:"
2174 echo "  HDF5 CFLAGS ......... = $HDF5_CFLAGS"
2175 echo "  HDF5 LIBS ........... = $HDF5_LIBS"
2176
2177 echo ""
2178 echo "PCRE configuration:"
2179 echo "  PCRE_CFLAGS ........ = $PCRE_CFLAGS"
2180 echo "  PCRE_LIBS .......... = $PCRE_LIBS"
2181 echo "  PCRE_VERSION ....... = $PCRE_VERSION"
2182
2183
2184 echo ""
2185 echo "SWIG Configuration:"
2186 if test ! -z "$SWIG_BIN"; then
2187 echo "  SWIG_BIN ........... = $SWIG_BIN"
2188 echo "  SWIG_JAVA .......... = $SWIG_JAVA"
2189 else
2190 echo "  SWIG generation disabled"
2191 fi
2192
2193 echo ""
2194 echo "GIWS Configuration:"
2195 if test ! -z "$GIWS_BIN"; then
2196 echo "  GIWS_BIN ........... = $GIWS_BIN"
2197 else
2198 echo "  GIWS generation disabled"
2199 fi
2200
2201 echo ""
2202 echo "Libtool config:"
2203 echo "  objext .............. = $objext"
2204 echo "  libext (static) ..... = $libext"
2205 echo "  shrext_cmds ......... = $shrext_cmds"
2206 echo "  exeext .............. = $exeext"
2207
2208 echo ""
2209
2210 echo "Compilation paths:"
2211 echo "  srcdir .............. = $SCI_SRCDIR"
2212 echo "  srcdir_full ......... = $SCI_SRCDIR_FULL"
2213 echo "  builddir ............ = $SCI_BUILDDIR"
2214 if test "$SCI_SRCDIR_FULL" != "$SCI_BUILDDIR"; then
2215 echo "  VPATH build ......... = Activated"
2216 fi
2217
2218 echo ""
2219 echo "Platform informations:"
2220 echo "  host ........... = $host"
2221 echo "  host_cpu ....... = $host_cpu"
2222 echo "  host_vendor .... = $host_vendor"
2223 echo "  host_os ... .... = $host_os"
2224 echo "  hostname ....... = $ac_hostname"
2225 echo "  CPU 64 bits .... = $IS_64_BITS_CPU"
2226 if test -n "$MAC_DETECTED_ARCH"; then
2227 echo "  Mac OS X arch .. = $MAC_DETECTED_ARCH"
2228 echo "  Mac OS X version = $macosx_version"
2229 fi
2230
2231 echo ""
2232 echo "Options used to compile and link:"
2233 echo "  prefix ......... = $prefix"
2234 echo "  localedir ...... = $localedir"
2235 echo "  VERSION ........ = $PACKAGE_VERSION"
2236 echo "  CC ............. = $CC"
2237 echo "  CFLAGS ......... = $CFLAGS"
2238 echo "  SCI_CFLAGS ..... = $SCI_CFLAGS"
2239 echo "  DEFS ........... = $DEFS"
2240 echo "  LD ............. = $LD"
2241 echo "  LDFLAGS ........ = $LDFLAGS"
2242 echo "  SCI_LDFLAGS .... = $SCI_LDFLAGS"
2243 echo "  LIBS ........... = $LIBS"
2244 echo "  CXX ............ = $CXX"
2245 echo "  CXXFLAGS ....... = $CXXFLAGS"
2246 echo "  SCI_CXXFLAGS ... = $SCI_CXXFLAGS"
2247 echo "  F77 ............ = $F77"
2248 echo "  FFLAGS ......... = $FFLAGS"
2249 echo "  SCI_FFLAGS ..... = $SCI_FFLAGS"
2250 echo "  F77_LDFLAGS .... = $F77_LDFLAGS"
2251 echo "  TERMCAP_LIB .... = $TERMCAP_LIB"
2252 echo ""