scilab/etc/scilab.start

   1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
   2 // Copyright (C) 2007-2008 - INRIA
   3 // Copyright (C) 2009-2011 - DIGITEO
   4 //
   5 // Copyright (C) 2012 - 2016 - Scilab Enterprises
   6 //
   7 // This file is hereby licensed under the terms of the GNU GPL v2.0,
   8 // pursuant to article 5.3.4 of the CeCILL v.2.1.
   9 // This file was originally licensed under the terms of the CeCILL v2.1,
  10 // and continues to be available under such terms.
  11 // For more information, see the COPYING file which you should have received
  12 // along with this program.
  13
  14 // Main Scilab initialisation file
  15
  16 mode(-1);  // silent execution mode
  17
  18 // clean database when restarted ======================================
  19 //predef("clear"); //unprotect all variables
  20 clear;  // erase all variables
  21 clearglobal();
  22
  23 %tk = (with_module("tclsci") & getscilabmode() <> "NWNI");
  24
  25 // Default Obsolete Warning policy  ===================================
  26 global %modalWarning;
  27 // False -> Scilab will only display a Warning message in the console
  28 //          if warnings are enabled [warning("on"/"off")].
  29 // True  -> Scilab will show a blocking popup.
  30 %modalWarning = %F;
  31 clear %modalWarning;
  32
  33 // Create some configuration variables ================================
  34 PWD = pwd();
  35
  36 // Startup message  ===================================================
  37 // if (sciargs() <> "-nb") & ~fromjava() & ~fromc() & getscilabmode() == "STD" then
  38 if (sciargs() <> "-nb") & getscilabmode() == "STD" then
  39   printf("\n\n%s\n", gettext("Startup execution:"));
  40   printf(gettext("  loading initial environment") + "\n");
  41 end
  42
  43 //if ((getscilabmode() == "NWNI" | getscilabmode() == "NW") & ~fromjava() & ~fromc() & sciargs()<>"-nb")
  44 if ((getscilabmode() == "NWNI" | getscilabmode() == "NW") & sciargs()<>"-nb")
  45    [v, opts] = getversion()
  46    printf(strsubst(v, "scilab-", "Scilab ") + " (" + opts($-1) + ", " + opts($) + ")\n");
  47    clear v opts;
  48 end
  49
  50 // loads modules ======================================================
  51 modules    = getmodules();
  52 for i=1:size(modules,"*")
  53   startFile = "SCI/modules/" + modules(i) + "/etc/" + modules(i) + ".start";
  54   ierr=exec(startFile, 'errcatch', -1);
  55   if ierr <> 0 then
  56      disp(msprintf(gettext("Failed to execute %s:"),startFile));
  57      disp(lasterror());
  58      exit(2);
  59    end
  60 end
  61 clear modules i ierr startFile;
  62
  63 // Create some configuration variables ================================
  64 //home = getenv("HOME", SCI);
  65 if getos() <> "Windows" then
  66   if getenv("PRINTERS", "ndef") == "ndef" then
  67     setenv("PRINTERS", "lp");
  68   end
  69 end
  70 setenv("VERSION", getversion());
  71
  72 // ATOMS ===============================================================
  73 if with_module("atoms") then
  74   atomsSystemInit();
  75   if sciargs() <> "-noatomsautoload" then
  76     atomsAutoload();
  77     clear atomsAutoload;
  78   end
  79   clear atomsSystemInit;
  80 end
  81
  82
  83 // Protect variable previously defined  ================================
  84 predef("all");
  85
  86 // At startup, no interactive vertical paging by default. ==============
  87 lines(0);
  88
  89 // load contrib menu if present ========================================
  90 function loadContrib()
  91   if isfile(SCI+"/contrib/loader.sce") then
  92     global %toolboxes;
  93     global %toolboxes_dir;
  94     exec(SCI+"/contrib/loader.sce");
  95   end
  96 endfunction
  97 loadContrib();
  98 clear loadContrib;
  99
 100 // calling user initialization =========================================
 101 if ~or(sciargs()=="-nouserstartup") then
 102
 103   startupfiles = [ SCIHOME + filesep() + ".scilab"     ; .. // Home directory startup
 104                    SCIHOME + filesep() + "scilab.ini" ];    //  ""      ""    startup
 105   for f = startupfiles'
 106     if isfile(f) then
 107       exec(f, -1)
 108     end
 109   end
 110
 111   // execute .scilab and scilab.start only
 112   // if last exec does not change current directory to SCIHOME
 113   // See bug #4150
 114   usedwd = getPreferencesValue("//general/body/startup", "use");
 115   if usedwd=="previous"
 116       workingDirectory =  getPreferencesValue("//general/body/startup", "previous");
 117   elseif usedwd=="default"
 118       workingDirectory =  getPreferencesValue("//general/body/startup", "default");
 119   else
 120       workingDirectory = pwd();
 121   end
 122   if SCIHOME <> workingDirectory then
 123       startupfiles = [ workingDirectory + filesep() + ".scilab"     ; .. // Working directory startup
 124                        workingDirectory + filesep() + "scilab.ini" ];    //  ""      ""    startup
 125
 126       for f = startupfiles'
 127         if isfile(f) then
 128           exec(f, -1)
 129         end
 130       end
 131   end
 132
 133   clear usedwd f startupfiles workingDirectory
 134 end
 135
 136 // Menus/toolbar can now be enabled ====================================
 137 if getscilabmode() == "STD" then
 138   setmenu(gettext("&File"));
 139   setmenu(gettext("&Edit"));
 140   setmenu(gettext("&Preferences"));
 141   setmenu(gettext("&Control"));
 142   setmenu(gettext("&Applications"));
 143   if ~with_module("scinotes") then // Desactivate Editor menu
 144     unsetmenu(gettext("&Applications"), 1);
 145   end
 146   if ~with_module("xcos") then // Desactivate xcos menu
 147     unsetmenu(gettext("&Applications"), 3);
 148   end
 149   if ~with_module("m2sci") then // Desactivate mfile2sci menu
 150     unsetmenu(gettext("&Applications"), 5);
 151   end
 152   if ~with_module("atoms") then // Desactivate atoms menu
 153     unsetmenu(gettext("&Applications"), 7);
 154   end
 155   setmenu(gettext("&?"));
 156   setmenu(gettext("&Toolboxes"));
 157   toolbar(-1, "on");
 158 end
 159 // ====================================================================
 160 clear ans