Fix ARPACK detection when using prerequirements
[scilab.git] / scilab / m4 / libsmath.m4
1 dnl ----------------------------------------------------------------------------
2 dnl @synopsis ACX_BLAS([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
3 dnl
4 dnl This macro looks for a library that implements the BLAS
5 dnl linear-algebra interface (see http://www.netlib.org/blas/).
6 dnl On success, it sets the BLAS_LIBS output variable to
7 dnl hold the requisite library linkages.
8 dnl
9 dnl To link with BLAS, you should link with:
10 dnl
11 dnl     $BLAS_LIBS $LIBS $FLIBS
12 dnl
13 dnl in that order.  FLIBS is the output variable of the
14 dnl AC_F77_LIBRARY_LDFLAGS macro (called if necessary by ACX_BLAS),
15 dnl and is sometimes necessary in order to link with F77 libraries.
16 dnl Users will also need to use AC_F77_DUMMY_MAIN (see the autoconf
17 dnl manual), for the same reason.
18 dnl
19 dnl Many libraries are searched for, from ATLAS to CXML to ESSL.
20 dnl The user may also use --with-blas=<lib> in order to use some
21 dnl specific BLAS library <lib>.  In order to link successfully,
22 dnl however, be aware that you will probably need to use the same
23 dnl Fortran compiler (which can be set via the F77 env. var.) as
24 dnl was used to compile the BLAS library.
25 dnl
26 dnl ACTION-IF-FOUND is a list of shell commands to run if a BLAS
27 dnl library is found, and ACTION-IF-NOT-FOUND is a list of commands
28 dnl to run it if it is not found.  If ACTION-IF-FOUND is not specified,
29 dnl the default action will define HAVE_BLAS.
30 dnl
31 dnl This macro requires autoconf 2.50 or later.
32 dnl
33 dnl @version acsite.m4,v 1.3 2002/08/02 09:28:12 steve Exp
34 dnl @author Steven G. Johnson <stevenj@alum.mit.edu>
35 dnl
36 AC_DEFUN([ACX_BLAS], [
37 AC_PREREQ(2.50)
38 AC_REQUIRE([AC_F77_LIBRARY_LDFLAGS])
39 acx_blas_ok=no
40 acx_blas_save_LIBS="$LIBS"
41
42 AC_ARG_WITH(blas-library,
43             AC_HELP_STRING([--with-blas-library=DIR], [set the path to the BLAS (refblas, Atlas, MKL...) library]))
44 saved_ldflags="$LDFLAGS"
45
46
47 if test "$with_blas_library" != no -a "$with_blas_library" != ""; then
48 LDFLAGS="$LDFLAGS -L$with_blas_library"
49 fi
50
51 # Get fortran linker names of BLAS functions to check for.
52 AC_F77_FUNC(sgemm)
53 AC_F77_FUNC(dgemm)
54
55 LIBS="$LIBS $FLIBS"
56
57 # First, check BLAS_LIBS environment variable
58 if test $acx_blas_ok = no; then
59     if test "x$BLAS_LIBS" != x; then
60         save_LIBS="$LIBS"; LIBS="$BLAS_LIBS $LIBS"
61         AC_MSG_CHECKING([for $sgemm in $BLAS_LIBS])
62         AC_TRY_LINK_FUNC($sgemm, [acx_blas_ok=yes; BLAS_TYPE="Using BLAS_LIBS environment variable"], [BLAS_LIBS=""])
63         AC_MSG_RESULT($acx_blas_ok)
64         LIBS="$save_LIBS"
65     elif $WITH_DEVTOOLS; then # Scilab thirdparties
66         BLAS_LIBS="-L$DEVTOOLS_LIBDIR -lblas"
67         BLAS_TYPE="Generic Blas"
68         acx_blas_ok=yes
69     fi
70 fi
71
72 # BLAS linked to by default?  (happens on some supercomputers)
73 if test $acx_blas_ok = no; then
74         save_LIBS="$LIBS"; LIBS="$LIBS"
75         AC_CHECK_FUNC($sgemm, [acx_blas_ok=yes; BLAS_TYPE="Linked"])
76         LIBS="$save_LIBS"
77 fi
78
79 # BLAS in OpenBlas library (http://www.openblas.net/)
80 if test $acx_blas_ok = no; then
81     AC_CHECK_LIB(openblas, $sgemm, [acx_blas_ok=yes; BLAS_TYPE="OpenBLAS"; BLAS_LIBS="-lopenblas"])
82 fi
83
84 # BLAS in ATLAS library (http://math-atlas.sourceforge.net/)
85 if test $acx_blas_ok = no; then
86         AC_CHECK_LIB(f77blas, $sgemm, [acx_blas_ok=yes; BLAS_TYPE="Atlas"; BLAS_LIBS="-lf77blas"], [
87                 AC_CHECK_LIB(f77blas, $sgemm, [acx_blas_ok=yes; BLAS_TYPE="Atlas"; BLAS_LIBS="-lf77blas -latlas"], [], [-latlas])])
88 fi
89
90 # BLAS in Intel MKL libraries (http://software.intel.com/en-us/articles/a-new-linking-model-single-dynamic-library-mkl_rt-since-intel-mkl-103)
91 if test $acx_blas_ok = no; then
92         AC_CHECK_LIB(mkl_rt, $sgemm, [acx_blas_ok=yes; BLAS_TYPE="MKL"; BLAS_LIBS="-lmkl_rt"])
93 fi
94
95 # BLAS in PhiPACK libraries? (requires generic BLAS lib, too)
96 if test $acx_blas_ok = no; then
97         AC_CHECK_LIB(blas, $sgemm,
98                 [AC_CHECK_LIB(dgemm, $dgemm,
99                 [AC_CHECK_LIB(sgemm, $sgemm,
100                         [acx_blas_ok=yes; BLAS_TYPE="PhiPACK"; BLAS_LIBS="-lsgemm -ldgemm -lblas"],
101                         [], [-lblas])],
102                         [], [-lblas])])
103 fi
104
105 # BLAS in Alpha CXML library?
106 if test $acx_blas_ok = no; then
107         AC_CHECK_LIB(cxml, $sgemm, [acx_blas_ok=yes;BLAS_TYPE="Alpha CXML"; BLAS_LIBS="-lcxml"])
108 fi
109
110 # BLAS in Alpha DXML library? (now called CXML, see above)
111 if test $acx_blas_ok = no; then
112         AC_CHECK_LIB(dxml, $sgemm, [acx_blas_ok=yes;BLAS_TYPE="Alpha DXML"; BLAS_LIBS="-ldxml"])
113 fi
114
115 # BLAS in Sun Performance library?
116 if test $acx_blas_ok = no; then
117         if test "x$GCC" != xyes; then # only works with Sun CC
118                 AC_CHECK_LIB(sunmath, acosp,
119                         [AC_CHECK_LIB(sunperf, $sgemm,
120                                 [BLAS_LIBS="-xlic_lib=sunperf -lsunmath";
121                                                                 BLAS_TYPE="Sun Performance library";
122                                  acx_blas_ok=yes],[],[-lsunmath])])
123         fi
124 fi
125
126 # BLAS in SCSL library?  (SGI/Cray Scientific Library)
127 if test $acx_blas_ok = no; then
128         AC_CHECK_LIB(scs, $sgemm, [acx_blas_ok=yes; BLAS_TYPE="SCSL"; BLAS_LIBS="-lscs"])
129 fi
130
131 # BLAS in SGIMATH library?
132 if test $acx_blas_ok = no; then
133         AC_CHECK_LIB(complib.sgimath, $sgemm,
134                      [acx_blas_ok=yes; BLAS_TYPE="SGIMATH"; BLAS_LIBS="-lcomplib.sgimath"])
135 fi
136
137 # BLAS in IBM ESSL library? (requires generic BLAS lib, too)
138 if test $acx_blas_ok = no; then
139         AC_CHECK_LIB(blas, $sgemm,
140                 [AC_CHECK_LIB(essl, $sgemm,
141                         [acx_blas_ok=yes; BLAS_TYPE="IBM ESSL"; BLAS_LIBS="-lessl -lblas"],
142                         [], [-lblas $FLIBS])])
143 fi
144
145 # Generic BLAS library?
146 if test $acx_blas_ok = no; then
147         AC_CHECK_LIB(blas, $sgemm, [acx_blas_ok=yes; BLAS_TYPE="Generic Blas"; BLAS_LIBS="-lblas"])
148 fi
149
150 if test "$with_blas_library" != no -a "$with_blas_library" != ""; then
151 BLAS_LIBS="-L$with_blas_library $BLAS_LIBS"
152 fi
153
154 AC_SUBST(BLAS_LIBS)
155
156 LIBS="$acx_blas_save_LIBS"
157 LDFLAGS="$saved_ldflags"
158
159 # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
160 if test x"$acx_blas_ok" = xyes; then
161         ifelse([$1],,,[$1])
162         :
163 else
164         acx_blas_ok=no
165         $2
166 fi
167 ])dnl ACX_BLAS
168
169
170
171
172
173 dnl ----------------------------------------------------------------------------
174 dnl @synopsis ACX_LAPACK([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
175 dnl
176 dnl This macro looks for a library that implements the LAPACK
177 dnl linear-algebra interface (see http://www.netlib.org/lapack/).
178 dnl On success, it sets the LAPACK_LIBS output variable to
179 dnl hold the requisite library linkages.
180 dnl
181 dnl To link with LAPACK, you should link with:
182 dnl
183 dnl     $LAPACK_LIBS $BLAS_LIBS $LIBS $FLIBS
184 dnl
185 dnl in that order.  BLAS_LIBS is the output variable of the ACX_BLAS
186 dnl macro, called automatically.  FLIBS is the output variable of the
187 dnl AC_F77_LIBRARY_LDFLAGS macro (called if necessary by ACX_BLAS),
188 dnl and is sometimes necessary in order to link with F77 libraries.
189 dnl Users will also need to use AC_F77_DUMMY_MAIN (see the autoconf
190 dnl manual), for the same reason.
191 dnl
192 dnl The user may also use --with-lapack-library=<DIR> in order to use some
193 dnl specific LAPACK library <lib>.  In order to link successfully,
194 dnl however, be aware that you will probably need to use the same
195 dnl Fortran compiler (which can be set via the F77 env. var.) as
196 dnl was used to compile the LAPACK and BLAS libraries.
197 dnl
198 dnl ACTION-IF-FOUND is a list of shell commands to run if a LAPACK
199 dnl library is found, and ACTION-IF-NOT-FOUND is a list of commands
200 dnl to run it if it is not found.  If ACTION-IF-FOUND is not specified,
201 dnl the default action will define HAVE_LAPACK.
202 dnl
203 dnl @version acsite.m4,v 1.3 2002/08/02 09:28:12 steve Exp
204 dnl @author Steven G. Johnson <stevenj@alum.mit.edu>
205
206 AC_DEFUN([ACX_LAPACK], [
207 AC_REQUIRE([ACX_BLAS])
208 acx_lapack_ok=no
209
210 AC_ARG_WITH(lapack-library,
211             AC_HELP_STRING([--with-lapack-library=DIR], [set the path to the LAPACK library]))
212 saved_ldflags="$LDFLAGS"
213
214 if test "$with_lapack_library" != no -a "$with_lapack_library" != ""; then
215 LDFLAGS="$LDFLAGS -L$with_lapack_library"
216 fi
217
218
219 # Get fortran linker name of LAPACK function to check for.
220 AC_F77_FUNC(cheev)
221
222 # We cannot use LAPACK if BLAS is not found
223 if test "x$acx_blas_ok" != xyes; then
224         acx_lapack_ok=noblas
225 fi
226
227 # First, check LAPACK_LIBS environment variable
228 if test "x$LAPACK_LIBS" != x; then
229         save_LIBS="$LIBS"; LIBS="$LAPACK_LIBS $BLAS_LIBS $LIBS $FLIBS"
230         AC_MSG_CHECKING([for $cheev in $LAPACK_LIBS])
231         AC_TRY_LINK_FUNC($cheev, [acx_lapack_ok=yes; LAPACK_TYPE="LAPACK_LIBS env variable"], [LAPACK_LIBS=""])
232         AC_MSG_RESULT($acx_lapack_ok)
233         LIBS="$save_LIBS"
234         if test acx_lapack_ok = no; then
235                 LAPACK_LIBS=""
236         fi
237 elif $WITH_DEVTOOLS; then # Scilab thirdparties
238      LAPACK_LIBS="-L$DEVTOOLS_LIBDIR -llapack"
239      LAPACK_TYPE="Library -llapack"
240      acx_lapack_ok=yes
241 fi
242
243 # LAPACK linked to by default?  (is sometimes included in BLAS lib)
244 if test $acx_lapack_ok = no; then
245         save_LIBS="$LIBS"; LIBS="$LIBS $BLAS_LIBS $FLIBS"
246         AC_CHECK_FUNC($cheev, [acx_lapack_ok=yes; LAPACK_TYPE="Default link (may be provided with BLAS)"])
247         LIBS="$save_LIBS"
248 fi
249
250 # Generic LAPACK library?
251 for lapack in lapack lapack_rs6k; do
252         if test $acx_lapack_ok = no; then
253                 save_LIBS="$LIBS"; LIBS="$BLAS_LIBS $LIBS"
254                 AC_CHECK_LIB($lapack, $cheev,
255                     [acx_lapack_ok=yes; LAPACK_TYPE="Library -l$lapack"; LAPACK_LIBS="-l$lapack"], [], [$FLIBS])
256                 LIBS="$save_LIBS"
257         fi
258 done
259
260 LDFLAGS="$saved_ldflags"
261
262 if test "$with_lapack_library" != no -a "$with_lapack_library" != ""; then
263 LAPACK_LIBS="$LAPACK_LIBS -L$with_lapack_library"
264 fi
265
266 AC_SUBST(LAPACK_LIBS)
267
268 # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
269 if test x"$acx_lapack_ok" = xyes; then
270         ifelse([$1],,,[$1])
271         :
272 else
273         acx_lapack_ok=no
274         $2
275 fi
276 ])dnl ACX_LAPACK
277
278
279 dnl ----------------------------------------------------------------------------
280 dnl @synopsis ACX_ARPACK([ACTION-IF-FOUND[, ACTION-IF-NOT-FOUND]])
281 dnl
282 dnl This macro looks for a library that implements the ARPACK
283 dnl collection of Fortran77 subroutines designed to solve large 
284 dnl scale eigenvalue problems (http://forge.scilab.org/index.php/p/arpack-ng/).
285 dnl On success, it sets the ARPACK_LIBS output variable to
286 dnl hold the requisite library linkages.
287 dnl
288 dnl To link with ARPACK, you should link with:
289 dnl
290 dnl     $ARPACK_LIBS $BLAS_LIBS $LIBS $FLIBS
291 dnl
292 dnl in that order.  BLAS_LIBS is the output variable of the ACX_BLAS
293 dnl macro, called automatically.  FLIBS is the output variable of the
294 dnl AC_F77_LIBRARY_LDFLAGS macro (called if necessary by ACX_BLAS),
295 dnl and is sometimes necessary in order to link with F77 libraries.
296 dnl Users will also need to use AC_F77_DUMMY_MAIN (see the autoconf
297 dnl manual), for the same reason.
298 dnl
299 dnl The user may also use --with-arpack-library=<DIR> in order to use some
300 dnl specific ARPACK library <lib>.  In order to link successfully,
301 dnl however, be aware that you will probably need to use the same
302 dnl Fortran compiler (which can be set via the F77 env. var.) as
303 dnl was used to compile the ARPACK and BLAS libraries.
304 dnl
305 dnl ACTION-IF-FOUND is a list of shell commands to run if a ARPACK
306 dnl library is found, and ACTION-IF-NOT-FOUND is a list of commands
307 dnl to run it if it is not found.  If ACTION-IF-FOUND is not specified,
308 dnl the default action will define HAVE_ARPACK.
309 dnl
310 dnl @version acsite.m4,v 1.3 2002/08/02 09:28:12 steve Exp
311 dnl @author Steven G. Johnson <stevenj@alum.mit.edu>
312 dnl @author Sylvestre Ledru <sylvestre.ledru@scilab-enterprises.com>
313
314 AC_DEFUN([ACX_ARPACK], [
315 AC_REQUIRE([ACX_BLAS])
316 AC_REQUIRE([ACX_LAPACK])
317 acx_arpack_ok=no
318
319 AC_ARG_WITH(arpack-library,
320             AC_HELP_STRING([--with-arpack-library=DIR], [set the path to the ARPACK library]))
321 saved_ldflags="$LDFLAGS"
322
323 if test "$with_arpack_library" != no -a "$with_arpack_library" != ""; then
324 LDFLAGS="$LDFLAGS -L$with_arpack_library"
325 fi
326
327 if $WITH_DEVTOOLS; then # Scilab thirdparties
328     ARPACK_LIBS="-L$DEVTOOLS_LIBDIR -larpack"
329     LDFLAGS="$LDFLAGS -L$DEVTOOLS_LIBDIR"
330     acx_arpack_ok=yes
331 else
332     ARPACK_LIBS="-larpack"
333 fi
334 # Get fortran linker name of ARPACK function to check for.
335 AC_F77_FUNC(znaupd)
336
337 # We cannot use ARPACK if BLAS is not found
338 if test "x$acx_blas_ok" != xyes -a "x$acx_lapack_ok" != xyes ; then
339         acx_arpack_ok=noblas
340 fi
341
342 # First, check ARPACK_LIBS environment variable
343 if test "x$ARPACK_LIBS" != x; then
344         save_LIBS="$LIBS"; LIBS="$ARPACK_LIBS $LAPACK_LIBS $BLAS_LIBS $LIBS $FLIBS"
345         AC_MSG_CHECKING([for $znaupd in $ARPACK_LIBS])
346         AC_TRY_LINK_FUNC($znaupd, [acx_arpack_ok=yes], [ARPACK_LIBS="-larpack"])
347         AC_MSG_RESULT($acx_arpack_ok)
348         LIBS="$save_LIBS"
349         if test acx_arpack_ok = no; then
350                 ARPACK_LIBS=""
351         fi
352 fi
353
354
355 LDFLAGS="$saved_ldflags"
356
357 if test "$with_arpack_library" != no -a "$with_arpack_library" != ""; then
358 ARPACK_LIBS="$ARPACK_LIBS -L$with_arpack_library"
359 fi
360
361 AC_SUBST(ARPACK_LIBS)
362
363 # Finally, execute ACTION-IF-FOUND/ACTION-IF-NOT-FOUND:
364 if test x"$acx_arpack_ok" = xyes; then
365         ifelse([$1],,,[$1])
366         :
367 else
368         acx_arpack_ok=no
369         $2
370 fi
371 ])dnl ACX_ARPACK
372 dnl
373 dnl Check whether ARPACK works (does not crash)
374 dnl
375 dnl Using a pure Fortran program doesn't seem to crash when linked
376 dnl with the buggy ARPACK library but the C++ program does.  Maybe
377 dnl it is the memory allocation that exposes the bug and using statically
378 dnl allocated arrays in Fortran does not?
379 dnl
380 dnl Copyright (C) 1995-2012 John W. Eaton
381 dnl
382 dnl This code is released under the GPL license.
383 dnl
384 AC_DEFUN([CHECK_ARPACK_OK], [
385   AC_LANG_PUSH(C++)
386   save_LIBS="$LIBS";
387   LIBS="$ARPACK_LIBS $LAPACK_LIBS $BLAS_LIBS $LIBS $FLIBS"
388   save_LD_LIBRARY_PATH="$LD_LIBRARY_PATH"
389   if $WITH_DEVTOOLS; then # Scilab thirdparties
390       LD_LIBRARY_PATH="$DEVTOOLS_LIBDIR:$LD_LIBRARY_PATH"
391   fi
392   AC_CACHE_CHECK([whether the arpack library works],
393     [lib_cv_arpack_ok], [
394       AC_RUN_IFELSE([AC_LANG_PROGRAM([[
395 // External functions from ARPACK library
396 extern "C" int
397 C2F(dnaupd) (int&, const char *, const int&, const char *,
398                            int&, const double&, double*, const int&,
399                            double*, const int&, int*, int*, double*,
400                            double*, const int&, int&, long int, long int);
401
402 extern "C" int
403 C2F(dneupd) (const int&, const char *, int*, double*,
404                            double*, double*, const int&,
405                            const double&, const double&, double*,
406                            const char*, const int&, const char *,
407                            int&, const double&, double*, const int&,
408                            double*, const int&, int*, int*, double*,
409                            double*, const int&, int&, long int,
410                            long int, long int);
411
412 extern "C" int
413 C2F(dgemv) (const char *, const int&, const int&,
414                          const double&, const double*, const int&,
415                          const double*, const int&, const double&,
416                          double*, const int&, long int);
417
418 #include <cfloat>
419
420 void
421 doit (void)
422 {
423   // Based on Octave function EigsRealNonSymmetricMatrix from liboctave/eigs-base.cc.
424
425   // Problem matrix.  See bug #31479
426   int n = 4;
427   double *m = new double [n * n];
428   m[0] = 1, m[4] = 0, m[8]  = 0, m[12] = -1;
429   m[1] = 0, m[5] = 1, m[9]  = 0, m[13] = 0;
430   m[2] = 0, m[6] = 0, m[10] = 1, m[14] = 0;
431   m[3] = 0, m[7] = 0, m[11] = 2, m[15] = 1;
432
433   double *resid = new double [4];
434
435   resid[0] = 0.960966;
436   resid[1] = 0.741195;
437   resid[2] = 0.150143;
438   resid[3] = 0.868067;
439
440   int *ip = new int [11];
441
442   ip[0] = 1;   // ishift
443   ip[1] = 0;   // ip[1] not referenced
444   ip[2] = 300; // mxiter, maximum number of iterations
445   ip[3] = 1;   // NB blocksize in recurrence
446   ip[4] = 0;   // nconv, number of Ritz values that satisfy convergence
447   ip[5] = 0;   // ip[5] not referenced
448   ip[6] = 1;   // mode
449   ip[7] = 0;   // ip[7] to ip[10] are return values
450   ip[8] = 0;
451   ip[9] = 0;
452   ip[10] = 0;
453  
454   int *ipntr = new int [14];
455
456   int k = 1;
457   int p = 3;
458   int lwork = 3 * p * (p + 2);
459
460   double *v = new double [n * (p + 1)];
461   double *workl = new double [lwork + 1];
462   double *workd = new double [3 * n + 1];
463
464   int ido = 0;
465   int info = 0;
466
467   double tol = DBL_EPSILON;
468
469   do 
470     {
471       C2F(dnaupd) (ido, "I", n, "LM", k, tol, resid, p,
472                                  v, n, ip, ipntr, workd, workl, lwork,
473                                  info, 1L, 2L);
474
475       if (ido == -1 || ido == 1 || ido == 2)
476         {
477           double *x = workd + ipntr[0] - 1;
478           double *y = workd + ipntr[1] - 1;
479
480           C2F(dgemv) ("N", n, n, 1.0, m, n, x, 1, 0.0,
481                                    y, 1, 1L);
482         }
483       else
484         {
485           if (info < 0)
486             {
487               return;  // Error
488             }
489
490           break;
491         }
492     } 
493   while (1);
494
495   int *sel = new int [p];
496
497   // The dimensions of dr and di are k+1, but k+2 avoids segfault
498   double *dr = new double [k + 1];
499   double *di = new double [k + 1];
500   double *workev = new double [3 * p];
501
502   for (int i = 0; i < k + 1; i++)
503     dr[i] = di[i] = 0.;
504
505   int rvec = 1;
506
507   double sigmar = 0.0;
508   double sigmai = 0.0;
509
510   // This is n*(k+1), but k+2 avoids segfault
511   double *z = new double [n * (k + 1)];
512
513   C2F(dneupd) (rvec, "A", sel, dr, di, z, n, sigmar,
514                              sigmai, workev, "I", n, "LM", k, tol,
515                              resid, p, v, n, ip, ipntr, workd,
516                              workl, lwork, info, 1L, 1L, 2L);
517 }
518 ]], [[
519   for (int i = 0; i < 10; i++)
520     doit ();
521 ]])],
522   [cv_lib_arpack_ok=yes],
523   [cv_lib_arpack_ok=no],
524   [cv_lib_arpack_ok=yes])])
525   LIBS="$save_LIBS"
526   LD_LIBRARY_PATH="$save_LD_LIBRARY_PATH"
527   AC_LANG_POP(C++)
528   if test "$cv_lib_arpack_ok" = "yes"; then
529     $1
530   else
531     $2
532   fi
533 ])