Linux build : fix undefined pragma
[scilab.git] / scilab / m4 / pkg.m4
1 # pkg.m4 - Macros to locate and utilise pkg-config.            -*- Autoconf -*-
2
3 # Incorporated into Scilab source tree because aclocal had issue to
4 # find the macro from time to time
5 #
6 # Copyright © 2004 Scott James Remnant <scott@netsplit.com>.
7 #
8 # This program is free software; you can redistribute it and/or modify
9 # it under the terms of the GNU General Public License as published by
10 # the Free Software Foundation; either version 2 of the License, or
11 # (at your option) any later version.
12 #
13 # This program is distributed in the hope that it will be useful, but
14 # WITHOUT ANY WARRANTY; without even the implied warranty of
15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
16 # General Public License for more details.
17 #
18 # You should have received a copy of the GNU General Public License
19 # along with this program; if not, write to the Free Software
20 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
21 #
22 # As a special exception to the GNU General Public License, if you
23 # distribute this file as part of a program that contains a
24 # configuration script generated by Autoconf, you may include it under
25 # the same distribution terms that you use for the rest of that program.
26
27 # PKG_PROG_PKG_CONFIG([MIN-VERSION])
28 # ----------------------------------
29 AC_DEFUN([PKG_PROG_PKG_CONFIG],
30 [m4_pattern_forbid([^_?PKG_[A-Z_]+$])
31 m4_pattern_allow([^PKG_CONFIG(_PATH)?$])
32 AC_ARG_VAR([PKG_CONFIG], [path to pkg-config utility])dnl
33 if test "x$ac_cv_env_PKG_CONFIG_set" != "xset"; then
34         AC_PATH_TOOL([PKG_CONFIG], [pkg-config])
35 fi
36 if test -n "$PKG_CONFIG"; then
37         _pkg_min_version=m4_default([$1], [0.9.0])
38         AC_MSG_CHECKING([pkg-config is at least version $_pkg_min_version])
39         if $PKG_CONFIG --atleast-pkgconfig-version $_pkg_min_version; then
40                 AC_MSG_RESULT([yes])
41         else
42                 AC_MSG_RESULT([no])
43                 PKG_CONFIG=""
44         fi
45                 
46 fi[]dnl
47 ])# PKG_PROG_PKG_CONFIG
48
49 # PKG_CHECK_EXISTS(MODULES, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
50 #
51 # Check to see whether a particular set of modules exists.  Similar
52 # to PKG_CHECK_MODULES(), but does not set variables or print errors.
53 #
54 #
55 # Similar to PKG_CHECK_MODULES, make sure that the first instance of
56 # this or PKG_CHECK_MODULES is called, or make sure to call
57 # PKG_CHECK_EXISTS manually
58 # --------------------------------------------------------------
59 AC_DEFUN([PKG_CHECK_EXISTS],
60 [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
61 if test -n "$PKG_CONFIG" && \
62     AC_RUN_LOG([$PKG_CONFIG --exists --print-errors "$1"]); then
63   m4_ifval([$2], [$2], [:])
64 m4_ifvaln([$3], [else
65   $3])dnl
66 fi])
67
68
69 # _PKG_CONFIG([VARIABLE], [COMMAND], [MODULES])
70 # ---------------------------------------------
71 m4_define([_PKG_CONFIG],
72 [if test -n "$PKG_CONFIG"; then
73     if test -n "$$1"; then
74         pkg_cv_[]$1="$$1"
75     else
76         PKG_CHECK_EXISTS([$3],
77                          [pkg_cv_[]$1=`$PKG_CONFIG --[]$2 "$3" 2>/dev/null`],
78                          [pkg_failed=yes])
79     fi
80 else
81         pkg_failed=untried
82 fi[]dnl
83 ])# _PKG_CONFIG
84
85 # _PKG_SHORT_ERRORS_SUPPORTED
86 # -----------------------------
87 AC_DEFUN([_PKG_SHORT_ERRORS_SUPPORTED],
88 [AC_REQUIRE([PKG_PROG_PKG_CONFIG])
89 if $PKG_CONFIG --atleast-pkgconfig-version 0.20; then
90         _pkg_short_errors_supported=yes
91 else
92         _pkg_short_errors_supported=no
93 fi[]dnl
94 ])# _PKG_SHORT_ERRORS_SUPPORTED
95
96
97 # PKG_CHECK_MODULES(VARIABLE-PREFIX, MODULES, [ACTION-IF-FOUND],
98 # [ACTION-IF-NOT-FOUND])
99 #
100 #
101 # Note that if there is a possibility the first call to
102 # PKG_CHECK_MODULES might not happen, you should be sure to include an
103 # explicit call to PKG_PROG_PKG_CONFIG in your configure.ac
104 #
105 #
106 # --------------------------------------------------------------
107 AC_DEFUN([PKG_CHECK_MODULES],
108 [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
109 AC_ARG_VAR([$1][_CFLAGS], [C compiler flags for $1, overriding pkg-config])dnl
110 AC_ARG_VAR([$1][_LIBS], [linker flags for $1, overriding pkg-config])dnl
111
112 pkg_failed=no
113 AC_MSG_CHECKING([for $1])
114
115 _PKG_CONFIG([$1][_CFLAGS], [cflags], [$2])
116 _PKG_CONFIG([$1][_LIBS], [libs], [$2])
117
118 m4_define([_PKG_TEXT], [Alternatively, you may set the environment variables $1[]_CFLAGS
119 and $1[]_LIBS to avoid the need to call pkg-config.
120 See the pkg-config man page for more details.])
121
122 if test $pkg_failed = yes; then
123         _PKG_SHORT_ERRORS_SUPPORTED
124         if test $_pkg_short_errors_supported = yes; then
125                 $1[]_PKG_ERRORS=`$PKG_CONFIG --short-errors --errors-to-stdout --print-errors "$2"`
126         else 
127                 $1[]_PKG_ERRORS=`$PKG_CONFIG --errors-to-stdout --print-errors "$2"`
128         fi
129         # Put the nasty error message in config.log where it belongs
130         echo "$$1[]_PKG_ERRORS" >&AS_MESSAGE_LOG_FD
131
132         ifelse([$4], , [AC_MSG_ERROR(dnl
133 [Package requirements ($2) were not met:
134
135 $$1_PKG_ERRORS
136
137 Consider adjusting the PKG_CONFIG_PATH environment variable if you
138 installed software in a non-standard prefix.
139
140 _PKG_TEXT
141 ])],
142                 [AC_MSG_RESULT([no])
143                 $4])
144 elif test $pkg_failed = untried; then
145         ifelse([$4], , [AC_MSG_FAILURE(dnl
146 [The pkg-config script could not be found or is too old.  Make sure it
147 is in your PATH or set the PKG_CONFIG environment variable to the full
148 path to pkg-config.
149
150 _PKG_TEXT
151
152 To get pkg-config, see <http://pkg-config.freedesktop.org/>.])],
153                 [$4])
154 else
155         $1[]_CFLAGS=$pkg_cv_[]$1[]_CFLAGS
156         $1[]_LIBS=$pkg_cv_[]$1[]_LIBS
157         AC_MSG_RESULT([yes])
158         ifelse([$3], , :, [$3])
159 fi[]dnl
160 ])# PKG_CHECK_MODULES