Add unitary tests for arnoldi
[scilab.git] / scilab / modules / arnoldi / tests / unit_tests / dneupd.dia.ref
1 // =============================================================================
2 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
3 // Copyright (C) 2012 - SE - Sylvestre Ledru
4 //
5 //  This file is distributed under the same license as the Scilab package.
6 // =============================================================================
7 // The following sets dimensions for this problem.
8 nx    = 10;
9 nev   = 3;
10 ncv   = 6;
11 bmat  = 'I';
12 which = 'LM';
13 // Local Arrays
14 iparam  = zeros(11, 1);
15 ipntr   = zeros(14, 1);
16 _select = zeros(ncv, 1);
17 dr       = zeros(nev + 1, 1);
18 di      = zeros(nev + 1, 1);
19 z       = zeros(nx, nev + 1);
20 resid   = zeros(nx, 1);
21 v       = zeros(nx, ncv);
22 workd   = zeros(3 * nx, 1);
23 workev  = zeros(3 * ncv, 1);
24 workl   = zeros(3 * ncv * ncv + 6 * ncv, 1);
25 // Build the test matrix
26 A            = diag(10 * ones(nx, 1));
27 A(1:$-1,2:$) = A(1:$-1,2:$) + diag(6 * ones(nx-1,1));
28 A(2:$,1:$-1) = A(2:$,1:$-1) + diag(-6 * ones(nx-1,1));
29 tol    = 0;
30 ido    = 0;
31 ishfts = 1;
32 maxitr = 300;
33 mode1  = 1;
34 iparam(1) = ishfts;
35 iparam(3) = maxitr;
36 iparam(7) = mode1;
37 sigmar = 0; // the real part of the shift
38 sigmai = 0; // the imaginary part of the shift
39 info_dnaupd = 0;
40 // M A I N   L O O P (Reverse communication)
41 while(ido <> 99)
42   // Repeatedly call the routine DNAUPD and take actions indicated by parameter IDO until
43   // either convergence is indicated or maxitr has been exceeded.
44   [ido, resid, v, iparam, ipntr, workd, workl, info_dnaupd] = dnaupd(ido, bmat, nx, which, nev, tol, resid, ncv, v, iparam, ipntr, workd, workl, info_dnaupd);
45   if(info_dnaupd < 0)
46     printf('\nError with dnaupd, info = %d\n',info_dnaupd);
47     printf('Check the documentation of dnaupd\n\n');
48   end
49   if(ido == -1 | ido == 1)
50     // Perform matrix vector multiplication 
51     workd(ipntr(2):ipntr(2) + nx -1) = A * workd(ipntr(1):ipntr(1) + nx - 1);
52   end
53 end
54 // Post-Process using DNEUPD.
55 rvec    = 1;
56 howmany = 'A';
57 info_dneupd = 0;
58 [dr, di, z, resid, v, iparam, ipntr, workd, workl, info_dneupd] = dneupd(rvec, howmany, _select, dr, di, z, sigmar, sigmai, workev, ...
59                                                                        bmat, nx, which, nev, tol, resid, ncv, v, ...
60                                                                        iparam, ipntr, workd, workl, info_dneupd);
61 d = complex(dr, di);
62 d(nev+1) = [];
63 d = diag(d);
64 c1 = 1:2:nev + 1;
65 c2 = 2:2:nev + 1;
66 if(modulo(nev + 1, 2) == 1)
67     c1($) = [];
68 end
69 z(:,[c1, c2]) = [z(:,c1) + z(:,c2) * %i z(:,c1) - z(:,c2) * %i];
70 z(:,$) = [];
71 assert_checkalmostequal(A * z, z * d, sqrt(%eps), 1.e-10);