Add unitary tests for arnoldi
[scilab.git] / scilab / modules / arnoldi / tests / unit_tests / dneupd.tst
1 // =============================================================================
2 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
3 // Copyright (C) 2012 - SE - Sylvestre Ledru
4 //
5 //  This file is distributed under the same license as the Scilab package.
6 // =============================================================================
7
8 // The following sets dimensions for this problem.
9
10 nx    = 10;
11
12 nev   = 3;
13 ncv   = 6;
14 bmat  = 'I';
15 which = 'LM';
16
17 // Local Arrays
18
19 iparam  = zeros(11, 1);
20 ipntr   = zeros(14, 1);
21 _select = zeros(ncv, 1);
22 dr       = zeros(nev + 1, 1);
23 di      = zeros(nev + 1, 1);
24 z       = zeros(nx, nev + 1);
25 resid   = zeros(nx, 1);
26 v       = zeros(nx, ncv);
27 workd   = zeros(3 * nx, 1);
28 workev  = zeros(3 * ncv, 1);
29 workl   = zeros(3 * ncv * ncv + 6 * ncv, 1);
30
31 // Build the test matrix
32
33 A            = diag(10 * ones(nx, 1));
34 A(1:$-1,2:$) = A(1:$-1,2:$) + diag(6 * ones(nx-1,1));
35 A(2:$,1:$-1) = A(2:$,1:$-1) + diag(-6 * ones(nx-1,1));
36
37 tol    = 0;
38 ido    = 0;
39
40 ishfts = 1;
41 maxitr = 300;
42 mode1  = 1;
43
44 iparam(1) = ishfts;
45 iparam(3) = maxitr;
46 iparam(7) = mode1;
47
48 sigmar = 0; // the real part of the shift
49 sigmai = 0; // the imaginary part of the shift
50 info_dnaupd = 0;
51
52 // M A I N   L O O P (Reverse communication)
53
54 while(ido <> 99)
55   // Repeatedly call the routine DNAUPD and take actions indicated by parameter IDO until
56   // either convergence is indicated or maxitr has been exceeded.
57
58   [ido, resid, v, iparam, ipntr, workd, workl, info_dnaupd] = dnaupd(ido, bmat, nx, which, nev, tol, resid, ncv, v, iparam, ipntr, workd, workl, info_dnaupd);
59   
60   if(info_dnaupd < 0)
61     printf('\nError with dnaupd, info = %d\n',info_dnaupd);
62     printf('Check the documentation of dnaupd\n\n');
63   end
64   
65   if(ido == -1 | ido == 1)
66     // Perform matrix vector multiplication 
67     workd(ipntr(2):ipntr(2) + nx -1) = A * workd(ipntr(1):ipntr(1) + nx - 1);
68   end
69 end
70
71 // Post-Process using DNEUPD.
72 rvec    = 1;
73 howmany = 'A';
74 info_dneupd = 0;
75
76 [dr, di, z, resid, v, iparam, ipntr, workd, workl, info_dneupd] = dneupd(rvec, howmany, _select, dr, di, z, sigmar, sigmai, workev, ...
77                                                                        bmat, nx, which, nev, tol, resid, ncv, v, ...
78                                                                        iparam, ipntr, workd, workl, info_dneupd);
79
80 d = complex(dr, di);
81 d(nev+1) = [];
82 d = diag(d);
83
84 c1 = 1:2:nev + 1;
85 c2 = 2:2:nev + 1;
86 if(modulo(nev + 1, 2) == 1)
87     c1($) = [];
88 end
89 z(:,[c1, c2]) = [z(:,c1) + z(:,c2) * %i z(:,c1) - z(:,c2) * %i];
90 z(:,$) = [];
91
92 assert_checkalmostequal(A * z, z * d, sqrt(%eps), 1.e-10); 
93