bc98b9251717f481140033ecd7d0fcfcf48bd4a7
[scilab.git] / scilab / modules / atoms / macros / atomsGetConfig.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) 2009 - DIGITEO - Pierre MARECHAL <pierre.marechal@scilab.org>
3 // Copyright (C) 2021 - DIGITEO - Allan CORNET
4 //
5 // This file must be used under the terms of the CeCILL.
6 // This source file is licensed as described in the file COPYING, which
7 // you should have received as part of this distribution.  The terms
8 // are also available at
9 // http://www.cecill.info/licences/Licence_CeCILL_V2.1-en.txt
10 //
11 // Get the configuration of the atoms system
12 //
13 function result = atomsGetConfig(field)
14
15     rhs = argn(2);
16
17     // Check number of input arguments
18     // =========================================================================
19     if rhs > 1 then
20         error(msprintf(gettext("%s: Wrong number of input argument: %d to %d expected.\n"), "atomsGetConfig", 0, 1));
21     end
22
23     // Check input parameters type
24     // =========================================================================
25     if (rhs > 0) & (type(field) <> 10) then
26         error(msprintf(gettext("%s: Wrong type for input argument #%d: Single string expected.\n"), "atomsGetConfig", 1));
27     end
28
29     // Check input parameters dimensions
30     // =========================================================================
31     if (rhs > 0) & (size(field, "*") <> 1) then
32         error(msprintf(gettext("%s: Wrong size for input argument #%d: Single string expected.\n"), "atomsGetConfig", 1));
33     end
34
35
36     if rhs <> 0 then
37         supported_field = ["useProxy", "proxyHost", "proxyPort", ..
38         "proxyUser", "proxyPassword", "offline", ..
39         "autoload", "autoloadAddAfterInstall", ..
40         "verbose", "downloadTool", "downloadTimeout", "updateTime"];
41
42         if ~or(convstr(supported_field) == convstr(field)) then
43             error(msprintf(gettext("%s: Wrong value for input argument #%d.\n"),"atomsGetConfig", 1));
44         end
45     end
46
47     pref_attrs = ["useProxy", "proxyHost", "proxyPort", "proxyUser", "proxyPassword";
48     "enabled", "host", "port", "user", "password"];
49
50     // Load Atoms Internals lib if it's not already loaded
51     // =========================================================================
52     if ~ exists("atomsinternalslib") then
53         load("SCI/modules/atoms/macros/atoms_internals/lib");
54     end
55
56     // Define the default value of the result according to the number of input
57     // arguments
58     // =========================================================================
59
60     if rhs == 0 then
61         result = struct();
62     else
63         i = find(pref_attrs(1, :) == field);
64         if ~isempty(i) then
65             result = getPreferencesValue("//web/body/proxy", pref_attrs(2, i));
66             return;
67         end
68
69         result = "";
70     end
71
72     // Define the path of the file that will record the change
73     // =========================================================================
74     atoms_directory = atomsPath("system", "user");
75
76     // Does the SCIHOME/atoms/config exist, if yes load it
77     // =========================================================================
78
79     if fileinfo(atoms_directory + "config") <> [] then
80         config_lines = mgetl(atoms_directory + "config");
81     else
82         if (rhs == 0)
83             values = getPreferencesValue("//web/body/proxy", pref_attrs(2, :));
84             for i = 1:size(pref_attrs, "c")
85                 if ~isempty(values(i)) then
86                     if values(i) == "true" then
87                         values(i) = "True";
88                     elseif values(i) == "false" then
89                         values(i) = "False";
90                     end
91                     result(pref_attrs(1, i)) = values(i);
92                 end
93             end
94         end
95         return;
96     end
97
98     // Loop on each URL specified as input argument
99     // =========================================================================
100
101     for i=1:size(config_lines, "*")
102         if isempty( stripblanks(config_lines(i))) then
103             continue;
104         end
105
106         if regexp(config_lines(i),"/^[a-zA-Z0-9]*\s=\s/","o") == 1 then
107             // process field
108             current_field_length  = regexp(config_lines(i),"/\s=\s/","o")
109             current_field     = part(config_lines(i),1:current_field_length-1);
110             current_value     = part(config_lines(i),current_field_length+3:length(config_lines(i)));
111
112             if (rhs == 1) & (current_field == field) then
113                 result = current_value;
114                 return;
115             elseif(rhs == 0)
116                 result(current_field) = current_value;
117             end
118         else
119             error(msprintf(gettext("%s: The config file (''%s'') is not well formated at line %d\n"),"atomsGetConfig",atoms_directory+"config",i));
120         end
121     end
122
123     if (rhs == 0)
124         values = getPreferencesValue("//web/body/proxy", pref_attrs(2, :));
125         for i = 1:size(pref_attrs, "c")
126             if ~isempty(values(i)) then
127                 if values(i) == "true" then
128                     values(i) = "True";
129                 elseif values(i) == "false" then
130                     values(i) = "False";
131                 end
132                 result(pref_attrs(1, i)) = values(i);
133             end
134         end
135     end
136
137 endfunction