ATOMS: homogenize function's profile
[scilab.git] / scilab / modules / atoms / macros / atoms_internals / atomsGetInstalledPath.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) 2009 - DIGITEO - Pierre MARECHAL <pierre.marechal@scilab.org>
3 //
4 // This file must be used under the terms of the CeCILL.
5 // This source file is licensed as described in the file COPYING, which
6 // you should have received as part of this distribution.  The terms
7 // are also available at
8 // http://www.cecill.info/licences/Licence_CeCILL_V2-en.txt
9
10 // Add an URL to the list of repositories, and returns
11
12 function res = atomsGetInstalledPath(packages,section)
13         
14         rhs           = argn(2);
15         res           = [];
16         installed     = []; // Column vector that contain user repositories
17         
18         // Check number of input arguments
19         // =========================================================================
20         
21         if rhs < 1 | rhs > 2 then
22                 error(msprintf(gettext("%s: Wrong number of input argument: %d to %d expected.\n"),"atomsGetInstalledPath",1,2));
23         end
24         
25         // Check input parameters type
26         // =========================================================================
27         
28         if type(packages) <> 10 then
29                 error(msprintf(gettext("%s: Wrong type for input argument #%d: String array expected.\n"),"atomsGetInstalledPath",1));
30         end
31         
32         if size(packages(1,:),"*") <> 2 then
33                 error(msprintf(gettext("%s: Wrong size for input argument #%d: mx2 string matrix expected.\n"),"atomsGetInstalledPath",1));
34         end
35         
36         packages = stripblanks(packages);
37         
38         // Allusers/user management
39         // =========================================================================
40         
41         if rhs < 2 then
42                 section = "all";
43         
44         else
45                 
46                 // Process the 2nd input argument : section
47                 // Allusers can be equal to "user" or "allusers"
48                 
49                 if type(section) <> 10 then
50                         error(msprintf(gettext("%s: Wrong type for input argument #%d: A boolean or a single string expected.\n"),"atomsGetInstalledPath",2));
51                 end
52                 
53                 if (type(section) == 10) & and(section<>["user","allusers","all"]) then
54                         error(msprintf(gettext("%s: Wrong value for input argument #%d: ''user'' or ''allusers'' or ''all'' expected.\n"),"atomsGetInstalledPath",2));
55                 end
56                 
57         end
58         
59         // Get the list of installed packages
60         // =========================================================================
61         installedpackages = atomsGetInstalled(section);
62         
63         // Loop on name
64         // =========================================================================
65         
66         for i=1:size(packages(:,1),"*")
67                 
68                 // Filter on names
69                 this_packages = installedpackages( find(installedpackages(:,1) == packages(i,1))     ,:);
70                 
71                 if this_packages == [] then
72                         res(i) = "";
73                         continue;
74                 end
75                 
76                 // Filter on versions
77                 this_packages = this_packages( find(this_packages(:,2) == packages(i,2)) ,:);
78                 
79                 if this_packages == [] then
80                         res(i) = "";
81                         continue;
82                 end
83                 
84                 res(i) = this_packages(1,4);
85         end
86         
87 endfunction