pixmap mode removed + black display fixed + slight improvements
[scilab.git] / scilab / modules / cacsd / demos / mixed.dem
1 //
2 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
3 // Copyright (C) ????-2008 - INRIA
4 //
5 // This file is distributed under the same license as the Scilab package.
6 //
7
8 mode(-1)
9 //display the diagram
10 x=[5,10,20,40,50,70,80,90];xmin=-10;xmax=100;
11 y=[22,28,30,32];ymin=12;ymax=40;
12
13 xx=[xmin,xmin,x([1 2 2 7 4 6 3 4 5 6 3 3 5 5]);xmax,xmax,x([3,2,7,7,5,8,3,4,5,6,4,4,6,6])];
14 yy=[ymin,ymax,y([3,1,1,1,3,3,2,2,2,2,2,4,2,4]);ymin,ymax,y([3,3,1,3,3,3,4,4,4,4,2,4,2,4])];
15     
16 xset("window",0);xbasc();xselect();
17 plot2d(xx,yy,ones(1,16),'022');
18 xstring(28,30,'K');xstring(56,30,'Plant');xstring(12,28.80,'-');
19 xtitle('PLANT   and   CONTROLLER')
20 mode(2)
21
22 x_message(['Mixed Sensitivity Controller Design';
23            'file: '+SCI+'/modules/cacsd/demos/mixed.dem'])
24 mode(1)
25 s=poly(0,'s');
26 str='[(s-1)/((s-1)^2*(s+2))]';
27 rep=x_dialog('Nominal plant?',str)
28 if rep==[] then return,end
29 Plant=evstr(rep);Plant=syslin('c',Plant);
30  //Nominal Plant
31 P22=tf2ss(Plant);    //...in state-space form
32 [ny,nu,nx]=size(P22);
33 [Pms,r]=augment(P22);
34 txt=['W1 (sensitivity function S)';'W2 (K*S)';'W3 (complementary sensitivity T)'];
35 default=['s';'1';'1'];
36 while %t
37   rep=x_mdialog('Set weighting functions',txt,default);
38   if rep==[] then return;end
39   W1=evstr(rep(1));W2=evstr(rep(2));W3=evstr(rep(3));
40   default=rep;
41   Pms=sysdiag(W1,W2,W3,eye(P22))*Pms;
42   gms=['gamma min= ';'gamma max= ';'# iterations'];
43   vals=['0.01';'1000';'50'];
44   reps=x_mdialog('Set interval for gamma and #iterations',gms,vals);
45   if reps==[] then return;end
46   mumin=1/evstr(reps(2))^2;
47   mumax=1/evstr(reps(1))^2;
48   iter=evstr(reps(3));
49   [K,mu]=h_inf(Pms,r,mumin,mumax,iter);
50   if K~=[] then break;end
51 end
52
53 disp(spec(h_cl(Pms,r,K)),'closed loop eigenvalues')    //Check internal stability
54 [Ssens,Rsens,Tsens]=sensi(P22,K);  //Sensitivity functions
55 x_message('Singular values plot')
56 fcts=['S function';'R (=K*S) function';'T function'];
57 www=x_mdialog('Select sensitivity function',fcts,['Yes';'No';'Yes']);
58 if www==[] then return,end
59
60 ww1=part(www(1),1)=='Y';
61 if ww1 then
62   scf(1);clf();xselect();
63   gainplot(Ssens);
64   xtitle('S = Sensitivity function');
65 end
66
67 ww2=part(www(2),1)=='Y';
68 if ww2 then
69   scf(2);clf();xselect();
70   gainplot(Rsens);
71   xtitle('R (=G*S) Sensitivity function');
72 end
73
74 ww3=part(www(3),1)=='Y';
75 if ww3 then
76   scf(3);clf();xselect();
77   gainplot(Tsens);
78   xtitle('T = Complementary Sensitivity function');
79 end