55426b6fe085f72b5bca4172ccd0025fbb3353b3
[scilab.git] / scilab / modules / cacsd / macros / csim.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) ???? - 2016 - INRIA - Serge Steer
3 //
4 // Copyright (C) 2012 - 2016 - Scilab Enterprises
5 //
6 // This file is hereby licensed under the terms of the GNU GPL v2.0,
7 // pursuant to article 5.3.4 of the CeCILL v.2.1.
8 // This file was originally licensed under the terms of the CeCILL v2.1,
9 // and continues to be available under such terms.
10 // For more information, see the COPYING file which you should have received
11 // along with this program.
12 function [y,x]=csim(u,dt,sl,x0,tol)
13     //Syntax:
14     //  [y [,x]]=csim(u,dt,sl,[x0])
15     // simulation of the controlled linear system sl.
16     // sl is assumed to be a continuous-time system.
17     // u is the control and x0 the initial state.
18     //
19     //u can be:
20     // - a function
21     //    [inputs]=u(t)
22     // - a list
23     //    list(ut,parameter1,....,parametern) such that
24     //    inputs=ut(t,parameter1,....,parametern)
25     // - the character string 'impuls' for impulse response calculation
26     //    (here sl is assumed SISO without direct feedthrough and x0=0)
27     // - the character string 'step' for step response calculation
28     //    (here sl is assumed SISO without direct feedthrough and x0=0)
29     //dt is a vector of instants with dt(1) = initial time
30     //                   that is:           x0=x
31     //                                          dt(1)
32     //
33     //y matrix such that:
34     //  y=[y       y  ...  y     ]
35     //      dt(1)   dt(2)   dt(n)
36     //x matrix such that:
37     //  x=[x       x  ...  x     ]
38     //      dt(1)   dt(2)   dt(n)
39     //
40     //See also:
41     // dsimul flts ltitr rtitr ode impl
42     //!
43
44     [lhs,rhs]=argn(0)
45     //
46     if rhs<3 then
47         msg = _("%s: Wrong number of input arguments: At least %d expected.\n");
48         error(msprintf(msg, "csim", 3));
49     end
50     sltyp=typeof(sl)
51     if and(sltyp<>["state-space" "rational" "zpk"]) then
52         args=["u","dt","sl","x0","tol"];
53         ierr=execstr("[y,x]=%"+overloadname(sl)+"_csim("+strcat(args(1:rhs),",")+")","errcatch")
54         if ierr<>0 then
55             error(msprintf(_("%s: Wrong type for input argument #%d: Linear dynamical system expected.\n"),"csim",3))
56         end
57         return
58     end
59     if sltyp=="rational" then
60         sl=tf2ss(sl)
61     elseif sltyp=="zpk" then
62         sl=zpk2ss(sl),
63     end
64     if sl.dt<>"c" then
65         warning(msprintf(gettext("%s: Input argument #%d is assumed continuous time.\n"),"csim",1));
66     end
67     //
68     [a,b,c,d]=abcd(sl);
69     if degree(d)>0 then
70         error(msprintf(gettext("%s: Wrong type for input argument #%d: A proper system expected\n"),"csim",1));
71     end
72     //[ma,mb]=size(b) replaced by  ma=size(a,1);mb=size(d,2);in case of no-state system
73     ma=size(a,1);
74     mb=size(d,2);
75     //
76     imp=0;step=0
77     text="if t==0 then y=0, else y=1,end"
78     //
79     select type(u)
80     case 10 then //input given by its type (step or impuls)
81         if mb<>1 then
82             error(msprintf(gettext("%s: Wrong type for input argument #%d: A SIMO expected.\n"),"csim",1));
83         end;
84         if part(u,1)=="i" then
85             //impulse response
86             imp=1;
87             dt(dt==0)=%eps^2;
88         elseif part(u,1)=="s" then
89             step=1
90             if norm(d,1)<>0 then
91                 dt(dt==0)=%eps^2;
92             end;
93         else
94             error(msprintf(gettext("%s: Wrong value for input argument #%d: Must be in the set {%s}.\n"),"csim",1,"""step"",""impuls"""))
95         end;
96         deff("[y]=u(t)",text);
97     case 13 then //input given by a function of time
98     case 1 then //input given by a vector of data
99         [mbu,ntu]=size(u);
100         if mbu<>mb | ntu<>size(dt,"*") then
101             error(msprintf(gettext("%s: Incompatible input arguments #%d and #%d: Same column dimensions expected.\n"),"csim",1,2))
102         end
103     case 15 then  //input given by a list: function of time with parameters
104         uu=u(1),
105     else error(msprintf(gettext("%s: Wrong type for input argument #%d: Function expected"), "csim", 2));
106     end;
107     //
108     if isempty(dt) then
109         y = [];
110         x = [];
111         return
112     end
113     if rhs==3 then x0=sl(6),end
114     if imp==1|step==1 then x0=0*x0,end
115     nt=size(dt,"*");x= zeros(ma,nt);
116     [a,v]=balanc(a);
117     v1=v;//save for backward transformation
118
119     //apply transformation u without matrix inversion
120     [k,l]=find(v<>0) //get the permutation
121
122     //apply right transformation
123     v=v(k,l);//diagonal matrix
124     c=c(:,k)*v;
125     //apply left transformation
126     v=diag(1 ./diag(v));b=v*b(k,:);x0=v*x0(k)
127
128     [a,v2,bs]=bdiag(a,1);b=v2\b;c=c*v2;x0=v2\x0;
129     //form the differential equation function
130     if type(u)==1 then
131         //form a continuous time interpolation of the given data
132         ut=u;
133         if min(size(ut))==1 then ut=matrix(ut,1,-1),end
134         deff("[y]=u(t)",["ind=find(dt<=t);nn=ind($)"
135         "if isempty(nn) then"
136         "y=[]"
137         "elseif (t==dt(nn)|nn==nt) then "
138         "   y=ut(:,nn)"
139         "else "
140         "   y=ut(:,nn)+(t-dt(nn))/(dt(nn+1)-dt(nn))*(ut(:,nn+1)-ut(:,nn))"
141         "end"]);
142         deff("[ydot]=%sim2(%tt,%y)","ydot = [];if ~isempty(u(%tt)) then ydot = ak*%y+bk*u(%tt);end");
143     elseif type(u)<>15 then
144         deff("[ydot]=%sim2(%tt,%y)","ydot=ak*%y+bk*u(%tt)");
145         ut=ones(mb,nt);for k=1:nt, ut(:,k)=u(dt(k)),end
146     else
147         %sim2=u
148         tx=" ";for l=2:size(u), tx=tx+",%"+string(l-1);end;
149         deff("[ydot]=sk(%tt,%y,u"+tx+")","ydot=ak*%y+bk*u(%tt"+tx+")");
150         %sim2(0)=sk;u=u(1)
151         deff("[ut]=uu(t)",...
152         ["["+part(tx,3:length(tx))+"]=%sim2(3:"+string(size(%sim2))+")";
153         "ut=ones(mb,nt);for k=1:nt, ut(:,k)=u(t(k)"+tx+"),end"])
154         ut=uu(dt);
155     end;
156
157     //simulation
158     k=1;
159     for n=bs',
160         kk=k:k+n-1;
161         ak=a(kk,kk);
162         bk=b(kk,:);
163         nrmu=max([norm(bk*ut,1),norm(x0(kk))]);
164         if nrmu > 0 then
165             if rhs<5 then
166                 atol=1.d-12*nrmu;rtol=atol/100;
167             else
168                 atol=tol(1);rtol=tol(2);
169             end
170             xkk=ode("adams",x0(kk),0,dt,rtol,atol,%sim2);
171             if size(xkk,2)<>size(x,2) then
172                 error(msprintf(_("%s: Simulation failed before final time is reached.\n"),"csim"))
173             end
174             x(kk,:)=xkk;
175             if imp==1 then x(kk,:)=ak*x(kk,:)+bk*ut,end
176         end;
177         k=k+n
178     end;
179     y = c*x + d*ut
180     if lhs==2 then x=v1*v2*x,end
181 endfunction