7442ca4b26bfc14c0b506b63196d84ee97196800
[scilab.git] / scilab / modules / cacsd / macros / csim.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) INRIA -
3 //
4 // Copyright (C) 2012 - 2016 - Scilab Enterprises
5 //
6 // This file is hereby licensed under the terms of the GNU GPL v2.0,
7 // pursuant to article 5.3.4 of the CeCILL v.2.1.
8 // This file was originally licensed under the terms of the CeCILL v2.1,
9 // and continues to be available under such terms.
10 // For more information, see the COPYING file which you should have received
11 // along with this program.
12
13
14 function [y,x]=csim(u,dt,sl,x0,tol)
15     //Syntax:
16     //  [y [,x]]=csim(u,dt,sl,[x0])
17     // simulation of the controlled linear system sl.
18     // sl is assumed to be a continuous-time system.
19     // u is the control and x0 the initial state.
20     //
21     //u can be:
22     // - a function
23     //    [inputs]=u(t)
24     // - a list
25     //    list(ut,parameter1,....,parametern) such that
26     //    inputs=ut(t,parameter1,....,parametern)
27     // - the character string 'impuls' for impulse response calculation
28     //    (here sl is assumed SISO without direct feedthrough and x0=0)
29     // - the character string 'step' for step response calculation
30     //    (here sl is assumed SISO without direct feedthrough and x0=0)
31     //dt is a vector of instants with dt(1) = initial time
32     //                   that is:           x0=x
33     //                                          dt(1)
34     //
35     //y matrix such that:
36     //  y=[y       y  ...  y     ]
37     //      dt(1)   dt(2)   dt(n)
38     //x matrix such that:
39     //  x=[x       x  ...  x     ]
40     //      dt(1)   dt(2)   dt(n)
41     //
42     //See also:
43     // dsimul flts ltitr rtitr ode impl
44     //!
45
46     [lhs,rhs]=argn(0)
47     //
48     if rhs<3 then error(39),end
49     sltyp=typeof(sl)
50     if and(sltyp<>["state-space" "rational"]) then
51         error(msprintf(_("%s: Wrong type for input argument #%d: %s data structure expected.\n"),"csim",3,"syslin"))
52     end
53     if sltyp=="rational" then sl=tf2ss(sl),end
54     if sl.dt<>"c" then
55         warning(msprintf(gettext("%s: Input argument #%d is assumed continuous time.\n"),"csim",1));
56     end
57     //
58     [a,b,c,d]=sl(2:5);
59     if degree(d)>0 then
60         error(msprintf(gettext("%s: Wrong type for input argument #%d: A proper system expected\n"),"csim",1));
61     end
62     [ma,mb]=size(b);
63     //
64     imp=0;step=0
65     text="if t==0 then y=0, else y=1,end"
66     //
67     select type(u)
68     case 10 then //input given by its type (step or impuls)
69         if mb<>1 then
70             error(msprintf(gettext("%s: Wrong type for input argument #%d: A SIMO expected.\n"),"csim",1));
71         end;
72         if part(u,1)=="i" then
73             //impulse response
74             imp=1;
75             dt(dt==0)=%eps^2;
76         elseif part(u,1)=="s" then
77             step=1
78             if norm(d,1)<>0 then
79                 dt(dt==0)=%eps^2;
80             end;
81         else
82             error(msprintf(gettext("%s: Wrong value for input argument #%d: Must be in the set {%s}.\n"),"csim",1,"""step"",""impuls"""))
83         end;
84         deff("[y]=u(t)",text);
85     case 11 then //input given by a function of time
86         comp(u)
87     case 13 then //input given by a function of time
88     case 1 then //input given by a vector of data
89         [mbu,ntu]=size(u);
90         if mbu<>mb | ntu<>size(dt,"*") then
91             error(msprintf(gettext("%s: Incompatible input arguments #%d and #%d: Same column dimensions expected.\n"),"csim",1,2))
92         end
93     case 15 then  //input given by a list: function of time with parameters
94         uu=u(1),
95         if type(uu)==11 then
96             comp(uu),
97             u(1)=uu,
98         end
99     else error(msprintf(gettext("%s: Wrong type for input argument #%d: Function expected"), "csim", 2));
100     end;
101     //
102     if isempty(dt) then
103         y = [];
104         x = [];
105         return
106     end
107     if rhs==3 then x0=sl(6),end
108     if imp==1|step==1 then x0=0*x0,end
109     nt=size(dt,"*");x=0*ones(ma,nt);
110     [a,v]=balanc(a);
111     v1=v;//save for backward transformation
112
113     //apply transformation u without matrix inversion
114     [k,l]=find(v<>0) //get the permutation
115
116     //apply right transformation
117     v=v(k,l);//diagonal matrix
118     c=c(:,k)*v;
119     //apply left transformation
120     v=diag(1 ./diag(v));b=v*b(k,:);x0=v*x0(k)
121
122     [a,v2,bs]=bdiag(a,1);b=v2\b;c=c*v2;x0=v2\x0;
123     //form the differential equation function
124     if type(u)==1 then
125         //form a continuous time interpolation of the given data
126         ut=u;
127         if min(size(ut))==1 then ut=matrix(ut,1,-1),end
128         deff("[y]=u(t)",["ind=find(dt<=t);nn=ind($)"
129         "if (t==dt(nn)|nn==nt) then "
130         "   y=ut(:,nn)"
131         "else "
132         "   y=ut(:,nn)+(t-dt(nn))/(dt(nn+1)-dt(nn))*(ut(:,nn+1)-ut(:,nn))"
133         "end"]);
134         deff("[ydot]=%sim2(%tt,%y)","ydot=ak*%y+bk*u(%tt)");
135     elseif type(u)<>15 then
136         deff("[ydot]=%sim2(%tt,%y)","ydot=ak*%y+bk*u(%tt)");
137         ut=ones(mb,nt);for k=1:nt, ut(:,k)=u(dt(k)),end
138     else
139         %sim2=u
140         tx=" ";for l=2:size(u), tx=tx+",%"+string(l-1);end;
141         deff("[ydot]=sk(%tt,%y,u"+tx+")","ydot=ak*%y+bk*u(%tt"+tx+")");
142         %sim2(0)=sk;u=u(1)
143         deff("[ut]=uu(t)",...
144         ["["+part(tx,3:length(tx))+"]=%sim2(3:"+string(size(%sim2))+")";
145         "ut=ones(mb,nt);for k=1:nt, ut(:,k)=u(t(k)"+tx+"),end"])
146         ut=uu(dt);
147     end;
148
149     //simulation
150     k=1;
151     for n=bs',
152         kk=k:k+n-1;
153         ak=a(kk,kk);
154         bk=b(kk,:);
155         nrmu=max([norm(bk*ut,1),norm(x0(kk))]);
156         if nrmu > 0 then
157             if rhs<5 then
158                 atol=1.d-12*nrmu;rtol=atol/100;
159             else
160                 atol=tol(1);rtol=tol(2);
161             end
162             xkk=ode("adams",x0(kk),0,dt,rtol,atol,%sim2);
163             if size(xkk,2)<>size(x,2) then
164                 error(msprintf(_("%s: Simulation failed before final time is reached.\n"),"csim"))
165             end
166             x(kk,:)=xkk;
167             if imp==1 then x(kk,:)=ak*x(kk,:)+bk*ut,end
168         end;
169         k=k+n
170     end;
171     y = c*x + d*ut
172     if lhs==2 then x=v1*v2*x,end
173 endfunction