* Bug #14557 fixed - csim fail is the system has no state
[scilab.git] / scilab / modules / cacsd / macros / csim.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) ???? - 2016 - Serge Steer - INRIA 
3 //
4 // This file is hereby licensed under the terms of the GNU GPL v2.0,
5 // pursuant to article 5.3.4 of the CeCILL v.2.1.
6 // This file was originally licensed under the terms of the CeCILL v2.1,
7 // and continues to be available under such terms.
8 // For more information, see the COPYING file which you should have received
9 // along with this program.
10
11
12 function [y,x]=csim(u,dt,sl,x0,tol)
13     //Syntax:
14     //  [y [,x]]=csim(u,dt,sl,[x0])
15     // simulation of the controlled linear system sl.
16     // sl is assumed to be a continuous-time system.
17     // u is the control and x0 the initial state.
18     //
19     //u can be:
20     // - a function
21     //    [inputs]=u(t)
22     // - a list
23     //    list(ut,parameter1,....,parametern) such that
24     //    inputs=ut(t,parameter1,....,parametern)
25     // - the character string 'impuls' for impulse response calculation
26     //    (here sl is assumed SISO without direct feedthrough and x0=0)
27     // - the character string 'step' for step response calculation
28     //    (here sl is assumed SISO without direct feedthrough and x0=0)
29     //dt is a vector of instants with dt(1) = initial time
30     //                   that is:           x0=x
31     //                                          dt(1)
32     //
33     //y matrix such that:
34     //  y=[y       y  ...  y     ]
35     //      dt(1)   dt(2)   dt(n)
36     //x matrix such that:
37     //  x=[x       x  ...  x     ]
38     //      dt(1)   dt(2)   dt(n)
39     //
40     //See also:
41     // dsimul flts ltitr rtitr ode impl
42     //!
43
44     [lhs,rhs]=argn(0)
45     //
46     if rhs<3 then error(39),end
47     sltyp=typeof(sl)
48     if and(sltyp<>["state-space" "rational"]) then
49         error(msprintf(_("%s: Wrong type for input argument #%d: %s data structure expected.\n"),"csim",3,"syslin"))
50     end
51     if sltyp=="rational" then sl=tf2ss(sl),end
52     if sl.dt<>"c" then
53         warning(msprintf(gettext("%s: Input argument #%d is assumed continuous time.\n"),"csim",1));
54     end
55     //
56     [a,b,c,d]=abcd(sl);
57     if degree(d)>0 then
58         error(msprintf(gettext("%s: Wrong type for input argument #%d: A proper system expected\n"),"csim",1));
59     end
60     ma=size(a,1);
61     mb=size(d,2);
62     //
63     imp=0;step=0
64     text="if t==0 then y=0, else y=1,end"
65     //
66     select type(u)
67     case 10 then //input given by its type (step or impuls)
68         if mb<>1 then
69           error(msprintf(gettext("%s: Wrong type for input argument #%d: A SIMO expected.\n"),"csim",1));
70         end;
71         if part(u,1)=="i" then
72             //impulse response
73             imp=1;
74             dt(dt==0)=%eps^2;
75         elseif part(u,1)=="s" then
76             step=1
77             if norm(d,1)<>0 then
78                 dt(dt==0)=%eps^2;
79             end;
80         else
81             error(msprintf(gettext("%s: Wrong value for input argument #%d: Must be in the set {%s}.\n"),"csim",1,"""step"",""impuls"""))
82         end;
83         deff("[y]=u(t)",text);
84     case 11 then //input given by a function of time
85         comp(u)
86     case 13 then //input given by a function of time
87     case 1 then //input given by a vector of data
88         [mbu,ntu]=size(u);
89         if mbu<>mb | ntu<>size(dt,"*") then
90             error(msprintf(gettext("%s: Incompatible input arguments #%d and #%d: Same column dimensions expected.\n"),"csim",1,2))
91         end
92     case 15 then  //input given by a list: function of time with parameters
93         uu=u(1),
94         if type(uu)==11 then
95             comp(uu),
96             u(1)=uu,
97         end
98     else error(msprintf(gettext("%s: Wrong type for input argument #%d: Function expected"), "csim", 2));
99     end;
100     //
101     if isempty(dt) then
102         y = [];
103         x = [];
104         return
105     end
106     if rhs==3 then x0=sl(6),end
107     if imp==1|step==1 then x0=0*x0,end
108     nt=size(dt,"*");x=0*ones(ma,nt);
109     [a,v]=balanc(a);
110     v1=v;//save for backward transformation
111
112     //apply transformation u without matrix inversion
113     [k,l]=find(v<>0) //get the permutation
114
115     //apply right transformation
116     v=v(k,l);//diagonal matrix
117     c=c(:,k)*v;
118     //apply left transformation
119     v=diag(1 ./diag(v));b=v*b(k,:);x0=v*x0(k)
120
121     [a,v2,bs]=bdiag(a,1);b=v2\b;c=c*v2;x0=v2\x0;
122     //form the differential equation function
123     if type(u)==1 then
124         //form a continuous time interpolation of the given data
125         ut=u;
126         if min(size(ut))==1 then ut=matrix(ut,1,-1),end
127         deff("[y]=u(t)",["ind=find(dt<=t);nn=ind($)"
128         "if (t==dt(nn)|nn==nt) then "
129         "   y=ut(:,nn)"
130         "else "
131         "   y=ut(:,nn)+(t-dt(nn))/(dt(nn+1)-dt(nn))*(ut(:,nn+1)-ut(:,nn))"
132         "end"]);
133         deff("[ydot]=%sim2(%tt,%y)","ydot=ak*%y+bk*u(%tt)");
134     elseif type(u)<>15 then
135         deff("[ydot]=%sim2(%tt,%y)","ydot=ak*%y+bk*u(%tt)");
136         ut=ones(mb,nt);for k=1:nt, ut(:,k)=u(dt(k)),end
137     else
138         %sim2=u
139         tx=" ";for l=2:size(u), tx=tx+",%"+string(l-1);end;
140         deff("[ydot]=sk(%tt,%y,u"+tx+")","ydot=ak*%y+bk*u(%tt"+tx+")");
141         %sim2(0)=sk;u=u(1)
142         deff("[ut]=uu(t)",...
143         ["["+part(tx,3:length(tx))+"]=%sim2(3:"+string(size(%sim2))+")";
144         "ut=ones(mb,nt);for k=1:nt, ut(:,k)=u(t(k)"+tx+"),end"])
145         ut=uu(dt);
146     end;
147
148     //simulation
149     k=1;
150     for n=bs',
151         kk=k:k+n-1;
152         ak=a(kk,kk);
153         bk=b(kk,:);
154         nrmu=max([norm(bk*ut,1),norm(x0(kk))]);
155         if nrmu > 0 then
156             if rhs<5 then
157                 atol=1.d-12*nrmu;rtol=atol/100;
158             else
159                 atol=tol(1);rtol=tol(2);
160             end
161             xkk=ode("adams",x0(kk),0,dt,rtol,atol,%sim2);
162             if size(xkk,2)<>size(x,2) then
163                 error(msprintf(_("%s: Simulation failed before final time is reached.\n"),"csim"))
164             end
165             x(kk,:)=xkk;
166             if imp==1 then x(kk,:)=ak*x(kk,:)+bk*ut,end
167         end;
168         k=k+n
169     end;
170     y = c*x + d*ut
171     if lhs==2 then x=v1*v2*x,end
172 endfunction