bug 7095 fix, the margins unit_test fails, g_margin, p_margin and unit_test improved
[scilab.git] / scilab / modules / cacsd / macros / g_margin.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) INRIA -  Author: Serge Steer
3 // 
4 // This file must be used under the terms of the CeCILL.
5 // This source file is licensed as described in the file COPYING, which
6 // you should have received as part of this distribution.  The terms
7 // are also available at    
8 // http://www.cecill.info/licences/Licence_CeCILL_V2-en.txt
9
10 function [gm,fr]=g_margin(h)
11   //compute the gain margin of a SISO transfer function
12   select typeof(h)
13   case 'rational' then 
14   case 'state-space' then 
15     h=ss2tf(h)
16   else 
17     error(97,1),
18   end;
19   if or(size(h)<>[1 1]) then 
20     error(msprintf(_("%s: Wrong size for input argument #%d: Single input, single output system expected.\n"),"g_margin",1))
21   end
22   //
23   eps=1.e-7;// threshold used for testing if complex numbers are real or pure imaginary
24   if h.dt=='c' then  //continuous time case
25     // get s such as h(s)=h(-s) and s=iw 
26      s=%i*poly(0,"w");
27      w=roots(imag(horner(h.num,s)*conj(horner(h.den,s))),"e")
28      ws=real(w(abs(imag(w))<eps&real(w)<=0)) //points where phase is -180°
29      ws(abs(horner(h.den,%i*ws))==0)=[];
30      if ws==[] then gm=%inf,fr=[],return,end
31      mingain=real(freq(h.num,h.den,%i*ws))
32   else  //discrete time case
33     if h.dt=='d' then dt=1,else dt=h.dt,end
34     //get z such as h(z)=h(1/z) and z=e^(%i*w*dt)
35     //form hh=h(z)-h(1/z)
36     z=poly(0,varn(h.den));
37     sm=simp_mode();simp_mode(%f);hh=h-horner(h,1/z);simp_mode(sm)
38     //find the numerator roots
39     z=roots(hh.num,"e");
40     z(abs(abs(z)-1)>eps)=[]// retain only roots with modulus equal to 1
41     w=log(z)/(%i*dt)
42     ws=real(w(abs(imag(w))<eps)) //points where phase is -180°
43     if ws==[] then gm=%inf,fr=[],return,end
44     mingain=real(horner(h,exp(%i*ws*dt)))
45   end
46   k=find(mingain<0)
47   if k==[] then gm=%inf,fr=[],return,end
48   mingain=abs(mingain(k));
49   ws=abs(ws(k))// select positive frequency
50
51   gm=-20*log(mingain)/log(10) //tranform into Db
52   [gm,k]=min(gm);ws=ws(k);//select the minimum
53
54   fr=ws/(2*%pi) //transform in Hz
55 endfunction