fe9f5c066725297ad8117b8b0e046f5a163bce7e
[scilab.git] / scilab / modules / cacsd / macros / g_margin.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) 2013 - Scilab Enterprises - Paul Bignier
3 // Copyright (C) INRIA -  Author: Serge Steer
4 //
5 // Copyright (C) 2012 - 2016 - Scilab Enterprises
6 //
7 // This file is hereby licensed under the terms of the GNU GPL v2.0,
8 // pursuant to article 5.3.4 of the CeCILL v.2.1.
9 // This file was originally licensed under the terms of the CeCILL v2.1,
10 // and continues to be available under such terms.
11 // For more information, see the COPYING file which you should have received
12 // along with this program.
13
14 function [gm,fr] = g_margin(h)
15     // Compute the gain margin of a SISO transfer function
16
17     if argn(2) < 1 then
18         error(msprintf(_("%s: Wrong number of input argument(s): %d expected.\n"),"g_margin",1));
19     end
20
21     select typeof(h)
22     case "rational" then
23     case "state-space" then
24         h=ss2tf(h)
25     else
26         error(97,1),
27     end;
28     if or(size(h)<>[1 1]) then
29         error(msprintf(_("%s: Wrong size for input argument #%d: Single input, single output system expected.\n"),"g_margin",1))
30     end
31     //
32     epsr=1.e-7;//used for testing if complex numbers are real
33     eps1=1.e-7;//used for testing if complex numbers have a modulus near 1
34     epssing=1e-10; //used for testing if arguments are not singular points of h
35     if h.dt=="c" then  //continuous time case
36         // get s such as h(s)=h(-s) and s=iw
37         s=%i*poly(0,"w");
38         //compute h(s)-h(-s)=num/den
39         num=imag(horner(h.num,s)*conj(horner(h.den,s)))
40         den=real(horner(h.den,s)*conj(horner(h.den,s)))
41         //necessary condition
42         w=roots(num,"e");
43         ws=real(w(abs(imag(w))<epsr&real(w)<=0)) //points where phase is -180°
44
45         //remove nearly singular points
46         ws(abs(horner(num,ws))>=epssing*abs(horner(den,ws)))=[]
47         if ws==[] then gm=%inf,fr=[],return,end
48         mingain=real(freq(h.num,h.den,%i*ws))
49     else  //discrete time case
50         if h.dt=="d" then dt=1,else dt=h.dt,end
51         //get z such as h(z)=h(1/z) and z=e^(%i*w*dt)
52         //form hh=h(z)-h(1/z)
53         z=poly(0,varn(h.den));
54         sm=simp_mode();simp_mode(%f);hh=h-horner(h,1/z);simp_mode(sm)
55         //find the numerator roots
56         z=roots(hh.num,"e");
57         z(abs(abs(z)-1)>eps1)=[]// retain only roots with modulus equal to 1
58
59         //remove nearly singular points
60         z(abs(horner(hh.num,z))>=epssing*abs(horner(hh.den,z)))=[];
61
62         w=log(z)/(%i*dt)
63         ws=real(w(abs(imag(w))<epsr)) //points where phase is -180°
64         if ws==[] then gm=%inf,fr=[],return,end
65         mingain=real(horner(h,exp(%i*ws*dt)))
66     end
67
68     k=find(mingain<0)
69     if k==[] then gm=%inf,fr=[],return,end
70     mingain=abs(mingain(k));
71     ws=abs(ws(k))// select positive frequency
72
73     gm=-20*log(mingain)/log(10) //tranform into Db
74     [gm,k]=min(gm);ws=ws(k);//select the minimum
75
76     fr=ws/(2*%pi) //transform in Hz
77 endfunction