3b706fbf38c90efe05586bbff99464940a41f5e2
[scilab.git] / scilab / modules / cacsd / macros / p_margin.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) INRIA -  Author: Serge Steer
3 // 
4 // This file must be used under the terms of the CeCILL.
5 // This source file is licensed as described in the file COPYING, which
6 // you should have received as part of this distribution.  The terms
7 // are also available at    
8 // http://www.cecill.info/licences/Licence_CeCILL_V2-en.txt
9
10 function [phm,fr]=p_margin(h)
11   //compute the phase margin of a SISO transfer function
12   select typeof(h)
13   case 'rational' then 
14   case 'state-space' then 
15     h=ss2tf(h)
16   else 
17     error(97,1)
18   end
19   if or(size(h)<>[1 1]) then 
20    error(msprintf(_("%s: Wrong size for input argument #%d: Single input, single output system expected.\n"),"p_margin",1))
21   end
22   eps=1.e-7// threshold used for testing if complex numbers are real or pure imaginary
23   
24   if h.dt=='c' then  //continuous time case
25     w=poly(0,'w');
26     niw=horner(h.num,%i*w);diw=horner(h.den,%i*w);
27     // |n(iw)/d(iw)|=1 <-- (n(iw)*n(-iw))/(d(iw)*d(-iw))=1 <--  (n(iw)*n(-iw)) - (d(iw)*d(-iw))=0
28     w=roots(real(niw*conj(niw)-diw*conj(diw)))
29     //select positive real roots
30     ws=w(find((abs(imag(w))<eps)&(real(w)>0))) //frequency points with unitary modulus
31     if ws==[] then phm=[],fr=[],return,end
32     f=horner(h,%i*ws);
33   else  //discrete time case
34     if h.dt=='d' then dt=1,else dt=h.dt,end
35     // |h(e^(i*w*dt))|=1 <-- h(e^(i*w*dt))*h(e^(-i*w*dt))
36     z=poly(0,varn(h.den));
37     sm=simp_mode();simp_mode(%f);hh=h*horner(h,1/z)-1;simp_mode(sm)
38     //find the numerator roots
39     z=roots(hh.num);
40     z(abs(abs(z)-1)>eps)=[];// retain only roots with modulus equal to 1
41     w=log(z)/(%i*dt);
42     ws=real(w(abs(imag(w))<eps&real(w)>0)); //frequency points with unitary modulus
43     if ws==[] then phm=%inf,fr=[],return,end
44     f=horner(h,exp(%i*ws*dt));
45   end
46   phm=atan(imag(f),real(f))// phase of the frequency response in [-%pi %pi]
47   phm=pmodulo(phm,2*%pi)-%pi
48   phm=phm*180/%pi; //transform in degree
49   [phm,k]=min(phm);ws=ws(k) //select the minimum
50   //disp([phm,ws])
51   fr=real(ws)/(2*%pi) 
52 endfunction