Fix some typos
[scilab.git] / scilab / modules / core / macros / toolboxes.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) INRIA
3 // Copyright (C) DIGITEO - 2009 - Allan CORNET
4 // Copyright (C) 2012 - Samuel GOUGEON
5 // 
6 // This file must be used under the terms of the CeCILL.
7 // This source file is licensed as described in the file COPYING, which
8 // you should have received as part of this distribution.  The terms
9 // are also available at    
10 // http://www.cecill.info/licences/Licence_CeCILL_V2-en.txt
11
12 //===========================================================
13 function [y] = toolboxes(path)
14 // INTERNAL macro should NOT used by users
15 // toolboxes loading
16 // path is a directory to explore for contribs
17 //===========================================================
18   global %toolboxes
19   global %toolboxes_dir
20 //===========================================================
21   [lhs,rhs] = argn(0) 
22   y = [];
23   if (rhs == 1) & typeof(path)=="constant" then 
24     // return string to exec
25     y = 'exec(""" + %toolboxes_dir + %toolboxes(path) + filesep() + "loader.sce" + """);';
26     return 
27   end
28
29 // Non ATOMS modules
30   if rhs == 0 then 
31     path = SCI + filesep() + 'contrib';
32   end
33   
34   cur_wd = pwd();
35   chdir(path);
36   files = listfiles('.');
37   contribs = [];
38   for k = 1:size(files,'*') 
39     if isfile(files(k)+'/loader.sce') then 
40       contribs = [contribs ; files(k)];
41     end
42   end
43
44     // ATOMS modules without autoloading
45     installed   = atomsGetInstalled()
46     autoloading = atomsAutoloadList() 
47     for i = 1:size(installed,1)
48          if and(installed(i,1)~=autoloading(:,1)) then
49               tmpath = installed(i,4)+filesep()+"loader.sce"
50               if isfile(tmpath) then 
51                    contribs = [contribs ; installed(i,1)+filesep()+installed(i,2)]
52               end
53          end
54     end
55
56   if (contribs <> []) & (getscilabmode() == 'STD') then 
57     delmenu(gettext("&Toolboxes"));
58     h = uimenu("parent", 0, "label", gettext("&Toolboxes"));
59     for k=1:size(contribs,'*')
60       m = uimenu(h,'label', string(contribs(k)), 'callback','execstr(toolboxes('+string(k)+'))');
61     end
62     unsetmenu(gettext("&Toolboxes"));
63   end
64   
65   %toolboxes = contribs;
66   %toolboxes_dir = pathconvert(path);
67   chdir(cur_wd);
68   
69 endfunction
70 //===========================================================
71
72
73
74
75
76
77