aca1280d532dd29ac7c41eeba516529d7af8071f
[scilab.git] / scilab / modules / differential_equations / tests / unit_tests / intg.tst
1 // =============================================================================
2 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
3 // Copyright (C) 2007-2008 - INRIA
4 //
5 //  This file is distributed under the same license as the Scilab package.
6 // =============================================================================
7
8 // <-- CLI SHELL MODE -->
9 // <-- ENGLISH IMPOSED -->
10
11 // Run with test_run('differential_equations','intg',['no_check_error_output'])
12
13 // Function written in the Scilab language
14 function y = f(x), y = x*sin(30*x)/sqrt(1-((x/(2*%pi))^2)), endfunction
15 exact = -2.5432596188;
16 I = intg(0, 2*%pi, f);
17 if abs(exact-I) > 1e-9 then pause, end
18
19 // Function with an argument written in the Scilab language
20 function y = f1(x, w), y = x*sin(w*x)/sqrt(1-((x/(2*%pi))^2)), endfunction
21 I = intg(0, 2*%pi, list(f1, 30));
22 if abs(exact-I) > 1e-9 then pause, end
23
24 // Function written in Fortran (a Fortran compiler is required)
25 // define a Fortran function
26 cd TMPDIR;
27 F=['      double precision function ffun(x)'
28    '      double precision x, pi'
29    '      pi = 3.14159265358979312d+0'
30    '      ffun = x*sin(30.0d+0*x)/sqrt(1.0d+0-(x/(2.0d+0*pi))**2)'
31    '      return'
32    '      end'];
33 mputl(F, fullfile(TMPDIR, 'ffun.f'));
34
35 // compile the function
36 l = ilib_for_link('ffun', fullfile(TMPDIR, 'ffun.f'), [], 'f');
37
38 // add the function to the working environment
39 link(l, 'ffun', 'f');
40
41 // integrate the function
42 I = intg(0, 2*%pi, 'ffun');
43 abs(exact-I);
44 if abs(exact-I) > 1e-9 then pause,end
45
46 // Function written in C (a C compiler is required)
47 // define a C function
48 C=['#include <math.h>'
49    'double cfun(double *x)'
50    '{'
51    '  double y, pi = 3.14159265358979312;'
52    '  y = *x/(2.0e0*pi);'
53    '  return *x*sin(30.0e0**x)/sqrt(1.0e0-y*y);'
54    '}'];
55 mputl(C, fullfile(TMPDIR, 'cfun.c'));
56
57 // compile the function
58 l = ilib_for_link('cfun', fullfile(TMPDIR, 'cfun.c'), [], 'c');
59
60 // add the function to the working environment
61 link(l, 'cfun', 'c');
62
63 // integrate the function
64 I = intg(0, 2*%pi, 'cfun');
65 if abs(exact-I) > 1e-9 then pause,end
66
67 // Test third output argument
68 [i, err, ierr] = intg(0, 1, f);
69 if abs(ierr) <> 0 then pause,end
70
71 function y = f(x), y = cos(x); endfunction
72 [i, err, ierr] = intg(0, %pi, f);
73 if abs(ierr) <> 2 then pause,end
74
75 // IEEE compatibility
76 // Error 264: "Wrong value for argument #i: Must not contain NaN or Inf."
77 if execstr("I = intg(%inf, 0, f)", 'errcatch')    <> 264 then pause,end
78 if execstr("I = intg(-%inf, 0, f)", 'errcatch')   <> 264 then pause,end
79 if execstr("I = intg(%nan, 0, f)", 'errcatch')    <> 264 then pause,end
80 if execstr("I = intg(0, %inf, f)", 'errcatch')    <> 264 then pause,end
81 if execstr("I = intg(0, -%inf, f)", 'errcatch')   <> 264 then pause,end
82 if execstr("I = intg(0, %nan, f)", 'errcatch')    <> 264 then pause,end
83 if execstr("I = intg(%nan, %nan, f)", 'errcatch') <> 264 then pause,end