[differential_equations] add sanity check in ode unit test
[scilab.git] / scilab / modules / differential_equations / tests / unit_tests / ode.tst
1 // =============================================================================
2 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
3 // Copyright (C) 2007-2008 - INRIA
4 // Copyright (C) 2011 - DIGITEO - Cedric DELAMARRE
5 // Copyright (C) 2013 - Scilab Enterprises - Adeline CARNIS
6 // Copyright (C) 2019 - St├ęphane MOTTELET
7 //
8 //  This file is distributed under the same license as the Scilab package.
9 // =============================================================================
10
11 // <-- CLI SHELL MODE -->
12 warning("off")
13 ilib_verbose(0);
14
15 version = getversion("scilab");
16
17 // to check that ode works
18 // ---------- Simple one dimension ODE (Scilab function external)
19 // dy/dt=y^2-y sin(t)+cos(t), y(0)=0
20 function ydot=f(t,y),ydot=y^2-y*sin(t)+cos(t),endfunction
21 y0=0;t0=0;t=0:0.1:%pi;
22 y=ode(y0,t0,t,f);
23 assert_checkalmostequal(size(y), [1 32] , %eps, [], "matrix");
24 clear y;
25 clear t;
26
27 // to check that error in rhs is reported without crashing Scilab
28 function ydot=f(t,y),ydot=z,endfunction
29 y0=0;t0=0;t=0:0.1:%pi;
30 message = [msprintf(_("Undefined variable: %s"),"z");
31            "ode: An error occurred in ''lsoda'' subroutine."]
32 assert_checkerror("y=ode(y0,t0,t,f)",message);
33
34
35 //*************************** function F and lsoda ********************************/
36 // create functions
37 cd TMPDIR;
38
39 CC=["void fex1(int* neq, double* t, double* y, double* ydot)"
40 "{"
41 "   ydot[0] = -0.04*y[0] + 1.0e+4*y[1]*y[2];"
42 "   ydot[2] = 3.0e+7*y[1]*y[1];"
43 "   ydot[1] = -ydot[0] - ydot[2];"
44 "}"];
45 mputl(CC,TMPDIR+"/fex1.c");
46 ilib_for_link("fex1","fex1.c",[],"c");
47 exec loader.sce;
48
49 C=[ "void fex2(int* neq, double* t, double* y, double* ydot)"
50 "{"
51 "   ydot[0] = y[4]*y[0] + y[5]*y[1]*y[2];"
52 "   ydot[2] = y[3]*y[1]*y[1];"
53 "   ydot[1] = -ydot[0] - ydot[2];"
54 "}"];
55
56 mputl(C,TMPDIR+"/fex2.c");
57 ilib_for_link("fex2","fex2.c",[],"c");
58 exec loader.sce;
59 clear f;
60 function ydot = f(t,yin)
61     ydot(1)=-0.040*yin(1) + 1.0D4*yin(2)*yin(3);
62     ydot(3)=3.0D7*yin(2)**2;
63     ydot(2)=-ydot(1) - ydot(3);
64 endfunction
65
66 function ydot = f1(t,yin,a,b,c)
67     ydot(1)=b*yin(1) + c*yin(2)*yin(3);
68     ydot(3)=a*yin(2)**2;
69     ydot(2)=-ydot(1) - ydot(3);
70 endfunction
71
72 function ydot = f2(t,yin,a)
73     ydot(1)=a(2)*yin(1) + a(3)*yin(2)*yin(3);
74     ydot(3)=a(1)*yin(2)**2;
75     ydot(2)=-ydot(1) - ydot(3);
76 endfunction
77
78 // init variables
79 y(1)    = 1;
80 y(2)    = 0;
81 y(3)    = 0;
82 t       = 0;
83 tout    = 0.4*exp((0:11)*log(10));
84 rtol    = 1.0d-4;
85 atol(1) = 1.0d-6;
86 atol(2) = 1.0d-10;
87 atol(3) = 1.0d-6;
88
89 // result provide by lsoda documentation.
90 // on a cdc-7600 in single precision.
91 //   at t =  4.0000e-01
92 resDoc(:,1) = [ 9.851712e-01 ; 3.386380e-05 ; 1.479493e-02 ];
93 //   at t =  4.0000e+00
94 resDoc(:,2) = [ 9.055333e-01 ; 2.240655e-05 ; 9.444430e-02 ];
95 //   at t =  4.0000e+01
96 resDoc(:,3) = [ 7.158403e-01 ; 9.186334e-06 ; 2.841505e-01 ];
97 //   at t =  4.0000e+02
98 resDoc(:,4) = [ 4.505250e-01 ; 3.222964e-06 ; 5.494717e-01 ];
99 //   at t =  4.0000e+03
100 resDoc(:,5) = [ 1.831975e-01 ; 8.941774e-07 ; 8.168016e-01 ];
101 //   at t =  4.0000e+04
102 resDoc(:,6) = [ 3.898730e-02 ; 1.621940e-07 ; 9.610125e-01 ];
103 //   at t =  4.0000e+05
104 resDoc(:,7) = [ 4.936363e-03 ; 1.984221e-08 ; 9.950636e-01 ];
105 //   at t =  4.0000e+06
106 resDoc(:,8) = [ 5.161831e-04 ; 2.065786e-09 ; 9.994838e-01 ];
107 //   at t =  4.0000e+07
108 resDoc(:,9) = [ 5.179817e-05 ; 2.072032e-10 ; 9.999482e-01 ];
109 //   at t =  4.0000e+08
110 resDoc(:,10) = [ 5.283401e-06 ; 2.113371e-11 ; 9.999947e-01 ];
111 //   at t =  4.0000e+09
112 resDoc(:,11) = [ 4.659031e-07 ; 1.863613e-12 ; 9.999995e-01 ];
113 //   at t =  4.0000e+10
114 resDoc(:,12) = [ 1.404280e-08 ; 5.617126e-14 ; 1.000000e+00 ];
115
116 // f as a string (dynamic link function)
117 res  = ode(y, t,tout, rtol, atol, "fex1");
118 // f as a list(string,...
119 if version(1) > 5 then
120     res2 = ode(y, t, tout, rtol, atol, list("fex2", 3.0d+7, -0.04, 1.0d+4));
121 end
122 // f as a macro
123 res3 = ode(y, t, tout, rtol, atol, f);
124 // f as a list(macro,...
125 res4 = ode(y, t, tout, rtol, atol, list(f1, 3.0d+7, -0.04, 1.0d+4));
126 args = [ 3.0d+7, -0.04, 1.0d+4 ];
127 res5 = ode(y, t, tout, rtol, atol, list(f2, args));
128 // f as a string (static link function)
129 res6 = ode(y, t,tout, rtol, atol, "fex");
130
131 // check results
132 assert_checkalmostequal(resDoc, res, 2d-7, [], "matrix"); // There are a little diff between resDoc and res
133 if version(1) > 5 then
134     assert_checkalmostequal(res, res2, 2d-7, [], "matrix"); // because results provides by lsoda
135 end
136 assert_checkalmostequal(res, res3, 2d-7, [], "matrix"); // documentation are in single precision.
137 assert_checkalmostequal(res, res4, 2d-7, [], "matrix");
138 assert_checkalmostequal(res, res5, 2d-7, [], "matrix");
139 assert_checkalmostequal(res, res6, 2d-7, [], "matrix");
140
141 //*************************** w iw ********************************/
142 tout2 = 0.4*exp(12*log(10));
143 tout3 = 0.4*exp((0:12)*log(10));
144 [yout w iw] = ode(y, t, tout, rtol, atol, f);
145 yout1 = ode(y, t, tout2, rtol, atol, f, w, iw);
146 yout2 = ode(y, t, tout3, rtol, atol, f);
147
148 assert_checkalmostequal(yout2(3*12+1:3*13), yout1, %eps, [], "matrix");
149
150 //*************************** Polynom ********************************/
151 //y(1) = 1;
152 //y(2) = 2;
153 //y(3) = 3;
154 //yy   = 1+2*%s+3*%s*%s;
155
156 //res  = ode(y, t,tout, rtol, atol, 'fex1');
157
158 //res6  = ode(yy, t, tout, rtol, atol, 'fex1');
159 //for i=1:12, assert_checkalmostequal(poly(res(:,i), "s", "coeff"),res6(i), %eps); end
160 //res7 = ode(yy, t, tout, rtol, atol, list('fex2', 3.0d+7, -0.04, 1.0d+4));
161 //for i=1:12, assert_checkequal(poly(res(:,i), "s", "coeff"), res7(i), %eps); end
162
163 //*************************** function Jac and lsode ********************************/
164 CC=["void jac(int* neq, double* t, double* y, int* mu, int* ml, double* j, int nj)"
165 "{"
166 "  j[0] = y[6]; "
167 "  j[1] = y[7]; "
168 "  j[2] = y[8]; "
169 "  j[3] = y[9]; "
170 "}"];
171
172 mputl(CC,TMPDIR+"/jac.c");
173 ilib_for_link("jac","jac.c",[],"c");
174 exec loader.sce;
175
176 CC=["void jac2(int* neq, double* t, double* y, int* mu, int* ml, double* j, int nj)"
177 "{"
178 "  j[0] = 10; "
179 "  j[1] = 0; "
180 "  j[2] = 0; "
181 "  j[3] = -1; "
182 "}"];
183 mputl(CC,TMPDIR+"/jac2.c");
184 ilib_for_link("jac2","jac2.c",[],"c");
185 exec loader.sce;
186
187 // ydot = A * y
188 C=[ "void fext(int* neq, double* t, double* y, double* ydot)"
189 "{"
190 "   ydot[0] = y[2]*y[0] + y[4]*y[1];"
191 "   ydot[1] = y[3]*y[0] + y[5]*y[1];"
192 "}"];
193
194 mputl(C,TMPDIR+"/fext.c");
195 ilib_for_link("fext","fext.c",[],"c");
196 exec loader.sce;
197
198 C=[ "void fext2(int* neq, double* t, double* y, double* ydot)"
199 "{"
200 "   ydot[0] = 10*y[0] + 0*y[1];"
201 "   ydot[1] = 0*y[0] + (-1)*y[1];"
202 "}"];
203
204 mputl(C,TMPDIR+"/fext2.c");
205 ilib_for_link("fext2","fext2.c",[],"c");
206 exec loader.sce;
207 clear f;
208
209 function ydot=f(t, y)
210     ydot=A*y
211 endfunction
212
213 function J=Jacobian(t, y)
214     J=A
215 endfunction
216
217 A=[10,0;0,-1];
218 y0=[0;1];
219 t0=0;
220 t=1;
221
222 res  = ode("stiff", y0, t0, t, f, Jacobian);
223 if version(1) > 5 then
224     res1 = ode("stiff", y0, t0, t, list("fext", 10, 0, 0,-1), list("jac", A));
225 end
226 res2 = ode("stiff", y0, t0, t, "fext2", "jac2");
227 res3 = ode("stiff", y0, t0, t, f, "jac2");
228 res4 = ode("stiff", y0, t0, t, "fext2", Jacobian);
229
230 assert_checkalmostequal(res, expm(A*t)*y0, 1.0D-7, [], "matrix");
231 if version(1) > 5 then
232     assert_checkalmostequal(res, res1, %eps, [], "matrix");
233 end
234 assert_checkalmostequal(res, res2, %eps, [], "matrix");
235 assert_checkalmostequal(res, res3, %eps, [], "matrix");
236 assert_checkalmostequal(res, res4, %eps, [], "matrix");
237
238 //*************************** discrete ********************************/
239 function yp=a_function(k,y)
240     yp=A*y+B*u(k);
241 endfunction
242
243 y1 = [1;2;3];
244 A  = diag([0.2,0.5,0.9]);
245 B  = [1;1;1];
246 u  = 1:10;
247 n  = 5;
248
249 y =ode("discrete", y1, 1, 1:n, a_function);
250 for i = 1:4, y1(:,i+1) = A * y1(:,i) + B * u(i); end
251 assert_checkalmostequal(y, y1, %eps, [], "matrix");
252
253 // Now y evaluates  at [y3,y5,y7,y9]
254 y1 = [1;2;3];
255 t  = 3:2:9;
256 y  = ode("discrete", y1, 1, t, a_function);
257 for i=1:9, y1(:,i+1) = A * y1(:,i) + B * u(i); end
258 y1 = y1(:,t);
259 assert_checkalmostequal(y, y1, %eps, [], "matrix");
260
261 //*************************** root ********************************/
262 y0=1;
263 ng=1;
264
265 C=[ "void fextern(int* neq, double* t, double* y, double* ydot)"
266 "{"
267 "int i = 0;"
268 "for( i = 0; i < *neq; i++)"
269 "   ydot[i] = y[i];"
270 "}"];
271
272 mputl(C,TMPDIR+"/fextern.c");
273 ilib_for_link("fextern","fextern.c",[],"c");
274 exec loader.sce;
275 clear f;
276 function ydot=f(t,y)
277     ydot=y;
278 endfunction
279
280 clear g;
281 // check rd result
282 function z=g(t,y)
283     z=y-2;
284 endfunction
285 [y,rd]=ode("root",y0,0,2,f,ng,g);
286 assert_checkequal( rd(2) <> 1 , %f);
287
288 clear g;
289 function z=g(t,y)
290     z=y-[2;2;33];
291 endfunction
292 [y,rd]=ode("root",y0,0,2,f,3,g);
293 assert_checkequal( rd(2) <> 1 , %f);
294 assert_checkequal( rd(3) <> 2 , %f);
295
296 clear g;
297 function z=g(t,y)
298     z=y-[2;2;2];
299 endfunction
300 [y,rd]=ode("root",y0,0,2,f,3,g);
301 assert_checkequal( rd(2) <> 1 , %f);
302 assert_checkequal( rd(3) <> 2 , %f);
303 assert_checkequal( rd(4) <> 3 , %f);
304
305 clear g;
306 function z=g(t,y)
307     z=y-[2;6;2;2];
308 endfunction
309 [y,rd]=ode("root",y0,0,2,f,4,g);
310 assert_checkequal( rd(2) <> 1 , %f);
311 assert_checkequal( rd(3) <> 3 , %f);
312 assert_checkequal( rd(4) <> 4 , %f);
313
314 // check y result
315
316 // result provide by lsodar documentation.
317 // on a cdc-7600 in single precision.
318 //   at t =  2.6400e-01
319 resDocRoot(:,1) = [ 9.899653e-01 ; 3.470563e-05 ; 1.000000e-02 ];
320 //        the above line is a root,  jroot =    0    1
321 //   at t =  4.0000e-01
322 resDoc(:,1) = [ 9.851712e-01 ; 3.386380e-05 ; 1.479493e-02 ];
323 //   at t =  4.0000e+00
324 resDoc(:,2) = [ 9.055333e-01 ; 2.240655e-05 ; 9.444430e-02 ];
325 //   at t =  4.0000e+01
326 resDoc(:,3) = [ 7.158403e-01 ; 9.186334e-06 ; 2.841505e-01 ];
327 //   at t =  4.0000e+02
328 resDoc(:,4) = [ 4.505250e-01 ; 3.222964e-06 ; 5.494717e-01 ];
329 //   at t =  4.0000e+03
330 resDoc(:,5) = [ 1.831975e-01 ; 8.941774e-07 ; 8.168016e-01 ];
331 //   at t =  4.0000e+04
332 resDoc(:,6) = [ 3.898730e-02 ; 1.621940e-07 ; 9.610125e-01 ];
333 //   at t =  4.0000e+05
334 resDoc(:,7) = [ 4.936363e-03 ; 1.984221e-08 ; 9.950636e-01 ];
335 //   at t =  4.0000e+06
336 resDoc(:,8) = [ 5.161831e-04 ; 2.065786e-09 ; 9.994838e-01 ];
337 //   at t =  2.0745e+07
338 resDocRoot(:,2) = [ 1.000000e-04 ; 4.000395e-10 ; 9.999000e-01 ];
339 //        the above line is a root,  jroot =    1    0
340 //   at t =  4.0000e+07
341 resDoc(:,9) = [ 5.179817e-05 ; 2.072032e-10 ; 9.999482e-01 ];
342 //   at t =  4.0000e+08
343 resDoc(:,10) = [ 5.283401e-06 ; 2.113371e-11 ; 9.999947e-01 ];
344 //   at t =  4.0000e+09
345 resDoc(:,11) = [ 4.659031e-07 ; 1.863613e-12 ; 9.999995e-01 ];
346 //   at t =  4.0000e+10
347 resDoc(:,12) = [ 1.404280e-08 ; 5.617126e-14 ; 1.000000e+00 ];
348
349 G=[ "void gex(int* neq, double* t, double* y, int* ng, double* gout)"
350 "{"
351 "gout[0] = y[0] - 1.0e-4;"
352 "gout[1] = y[2] - 1.0e-2;"
353 "}"];
354
355 mputl(G,TMPDIR+"/gex.c");
356 ilib_for_link("gex","gex.c",[],"c");
357 exec loader.sce;
358
359 y(1) = 1;
360 y(2) = 0;
361 y(3) = 0;
362 t0   = 0;
363
364 [yout1,rd1,w,iw] = ode("root", y, t0, tout, "fex1", 2, "gex");
365 assert_checkalmostequal(rd1(1), 2.64d-01, 1d-4);
366 [yout2,rd2,w,iw] = ode("root", y, t0, tout, "fex1", 2, "gex", w, iw);
367 assert_checkalmostequal(rd2(1), 2.0795776d+07, 4d-5);
368 err = execstr("[yout3,rd,w,iw] = ode(""root"", y, t0, tout, ""fex1"", 2, ""gex"", w, iw);","errcatch");
369 assert_checkequal( err == 0 , %f);
370
371 // check results
372 assert_checkalmostequal(resDocRoot(:,1), yout1, 2.0D-8, [], "matrix");
373 assert_checkalmostequal(resDocRoot(:,2), yout2(:,9), 2.0D-8, [], "matrix");
374 assert_checkalmostequal(resDoc(:,1:8), yout2(:,1:8), 2.0D-4, [], "matrix");
375
376 //*************************** rk/rkf/fix ********************************/
377 function ydot=functionF(t, y)
378     ydot=y^2-y*sin(t)+cos(t)
379 endfunction
380
381 y0 = 0;
382 t0 = 0;
383 t  = 0:0.1:%pi;
384
385 rk   = ode("rk",  y0, t0, t, functionF);
386 rkf  = ode("rkf", y0, t0, t, functionF);
387 fixx = ode("fix", y0, t0, t, functionF);
388
389 rkRes = [0.    0.09983341664683527    0.19866933079512300    0.29552020666153711 0.38941834230905709    0.47942553860493514    0.56464247339623352    0.64421768723947215 0.71735609090195429    0.78332690963060869    0.8414709848117728     0.89120736006615475 0.93203908597292051    0.96355818542403104    0.98544972999664104    0.99749498661376];
390 rkRes(17:32) = [0.99957360305287668    0.99166481046564392    0.97384763089330029    0.94630008770455387 0.90929742684492987    0.86320936667026738    0.80849640384312127    0.74570521220233155 0.67546318057873300    0.59847214413334937    0.51550137185246248    0.42737988026620155 0.33498815018939587    0.23924932924832210    0.14112000809477554    0.04158066246848785];
391
392 rkfRes = [0.    0.09983341667063099    0.19866933087782307    0.2955202068043328    0.38941834246046680     0.47942553864900261    0.56464247314940919    0.64421768645637856    0.71735608928892303      0.78332690686480611    0.84147098056308622    0.89120735401875306    0.93203907784361117      0.96355817497519225    0.98544971704249074    0.99749497101988072    0.99957358472991464];
393 rkfRes(18:32) = [    0.99166478935902302    0.97384760697150774    0.94630006094857066    0.90929739724116376     0.86320933420871493    0.80849636852157181    0.74570517403636893    0.67546313961625104      0.59847210047141619    0.51550132565379336    0.42737983177229999    0.33498809972769594      0.23924927723128114    0.14111995500988161    0.04158060885936282];
394
395 assert_checkalmostequal(rkRes, rk, %eps * 20, [], "matrix");
396 assert_checkalmostequal(rkfRes, rkf, %eps, [], "matrix");
397 assert_checkalmostequal(rkf, fixx, %eps, [], "matrix");
398 warning("on")