Merge remote-tracking branch 'origin/6.1'
[scilab.git] / scilab / modules / dynamic_link / macros / dllinfo.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) DIGITEO - Allan CORNET
3 //
4 // Copyright (C) 2012 - 2016 - Scilab Enterprises
5 //
6 // This file is hereby licensed under the terms of the GNU GPL v2.0,
7 // pursuant to article 5.3.4 of the CeCILL v.2.1.
8 // This file was originally licensed under the terms of the CeCILL v2.1,
9 // and continues to be available under such terms.
10 // For more information, see the COPYING file which you should have received
11 // along with this program.
12
13 //=============================================================================
14 function dllinfolist = dllinfo(dllname, options)
15
16     dllinfolist = list();
17     if getos() <> "Windows" then
18         warning(msprintf(gettext("%s: This feature has been implemented for Windows.\n"),"dllinfo"));
19     else
20         // Load dynamic_link Internal lib if it's not already loaded
21         if ~ exists("dynamic_linkwindowslib") then
22             load("SCI/modules/dynamic_link/macros/windows/lib");
23         end
24
25         [lhs,rhs] = argn(0);
26
27         if rhs == 1 then
28             options = "exports";
29         end
30
31         if type(dllname) <> 10 | size(dllname, "*") <> 1  then
32             error(msprintf(gettext("%s: Wrong type for input argument #%d: string expected.\n"),"dllinfo",1));
33         end
34
35         if fileinfo(dllname) == [] then
36             error(msprintf(gettext("%s: The file %s does not exist.\n"),"dllinfo",dllname));
37         end
38
39         fext = fileext(dllname);
40         if ~(strcmp(fext,".exe", "i") == 0 | strcmp(fext,".dll", "i")== 0) then
41             error(msprintf(gettext("%s: Cannot open file %s.\n"),"dllinfo",dllname));
42         end
43
44         if type(options) <> 10 | size(options) <> 1 then
45             error(msprintf(gettext("%s: Wrong type for input argument #%d: string expected.\n"),"dllinfo",2));
46         end
47
48         if ~(strcmp(options,"imports","i")== 0 | strcmp(options,"exports", "i")== 0 | strcmp(options, "machine", "i")== 0) then
49             error(msprintf(gettext("%s: Wrong value for input argument #%d: Must be in the set {%s}.\n"),"dllinfo",2,"''imports'',''exports'',''machine''"));
50         end
51
52         dllinfolist = dlwDllInfo(dllname, options);
53     end
54 endfunction
55 //=============================================================================