3b87f522159e4d40086302743295f663ce8c1fce
[scilab.git] / scilab / modules / dynamic_link / macros / ilib_compile.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) INRIA
3 // Copyright (C) ENPC
4 // Copyright (C) DIGITEO - 2009
5 // Copyright (C) DIGITEO - 2010-2011 - Allan CORNET
6 //
7 // This file must be used under the terms of the CeCILL.
8 // This source file is licensed as described in the file COPYING, which
9 // you should have received as part of this distribution.  The terms
10 // are also available at
11 // http://www.cecill.info/licences/Licence_CeCILL_V2.1-en.txt
12
13 //=============================================================================
14 function libn = ilib_compile(lib_name, ..
15     makename, ..
16     files, ..
17     ldflags, ..
18     cflags, ..
19     fflags, ..
20     cc)
21
22     [lhs,rhs] = argn(0);
23     if rhs < 2 then
24         error(msprintf(gettext("%s: Wrong number of input argument(s).\n"),"ilib_compile"));
25         return
26     end
27
28     // The name of the library starts by "lib", strip it
29     lib_name_orig = strsubst(lib_name,"/^lib/","","r");
30
31     libn=""; //** init variable
32     if getos() == "Windows" & ~haveacompiler() then
33         error(_("A Fortran or C compiler is required."))
34         return;
35     end
36
37     [lhs,rhs]=argn(0);
38
39     if rhs < 3 then
40         files = [];
41     else
42         if ~isempty(files) & (or(fileext(files)==".o") | or(fileext(files)==".obj")) then
43             error(999, msprintf(_("%s: A managed file extension for input argument #%d expected."), "ilib_compile", 3));
44         end
45     end
46
47     if typeof(lib_name)<>"string" then
48         error(msprintf(gettext("%s: Wrong type for input argument #%d: A string expected.\n"),"ilib_compile",1));
49         return ;
50     end
51
52     oldpath = pwd();
53     files = files(:)';
54
55     [make_command, lib_name_make, lib_name, path, makename, files]= ...
56     ilib_compile_get_names(lib_name, files);
57
58     if isdir(path) then
59         chdir(path);
60     end
61
62     if getos() == "Windows" then
63         //** ----------- Windows section  -----------------
64
65         // Load dynamic_link Internal lib if it's not already loaded
66         if ~ exists("dynamic_linkwindowslib") then
67             load("SCI/modules/dynamic_link/macros/windows/lib");
68         end
69
70         dlwCompile(files, make_command, makename);
71
72     else
73         //** ---------- Linux/MacOS/Unix section ---------------------
74
75         ScilabTreeFound=%f;
76
77         // Source tree version
78         // Headers are dispatched in the source tree
79         if isdir(SCI+"/modules/core/includes/") then
80             defaultModulesCHeader=[ "core", "mexlib","api_scilab","output_stream","localization", "operations", "symbol", "types", "ast",  "dynamic_link",  "system_env",  "threads",  "string",  "console"];
81             defaultModulesFHeader=[ "core" ];
82             ScilabTreeFound=%t
83
84             for x = defaultModulesCHeader(:)';
85                 cflags=" -I"+SCI+"/modules/"+x+"/includes/ "+cflags;
86             end
87
88             cflags=" -I"+SCI+"/modules/ast/includes/exps "+cflags;
89             for x = defaultModulesFHeader(:)';
90                 fflags=" -I"+SCI+"/modules/"+x+"/includes/ " + fflags;
91             end
92         end
93
94         // Binary version
95         if isdir(SCI+"/../../include/scilab/") & ~ScilabTreeFound then
96             cflags="-I"+SCI+"/../../include/scilab/ -I"+SCI+"/../../include/  -I"+SCI+"/../../lib/Eigen/includes/ " + cflags
97             fflags="-I"+SCI+"/../../include/scilab/ " + fflags
98             ScilabTreeFound=%t
99         end
100
101         // System version (ie: /usr/include/scilab/)
102         if isdir("/usr/include/scilab/") & ~ScilabTreeFound then
103             cflags="-I/usr/include/scilab/ "+cflags
104             fflags="-I/usr/include/scilab/ "+fflags
105             ScilabTreeFound=%t
106         end
107
108         if ( ilib_verbose() <> 0 & ScilabTreeFound <> %t) then
109             mprintf(gettext("%s: Warning: Scilab has not been able to find where the Scilab sources are. Please submit a bug report on http://bugzilla.scilab.org/\n"),"ilib_compile");
110         end
111
112         oldPath = pwd();
113
114         // Switch back to the TMPDIR where the mandatory files are
115
116         chdir(TMPDIR+"/"+lib_name_orig);
117
118         // Detect the actual path to the libstdc++ library. For the dynamic link
119         // build, we want to use the same lib as the compiler installed.
120         // CF bug #7887 for more information.
121         // Note that, for the configure, the setup is done by compilerDetection.sh
122         cmdGCC="if test -x ""$(which gcc 2>/dev/null)""; then echo $(LC_ALL=C gcc -print-search-dirs|awk ''$1==""install:""{print $2}''); fi";
123         [GCClibpath, ierr, stderr] = unix_g(cmdGCC);
124
125         if (GCClibpath <> "" & GCClibpath <> [] & ierr == 0 & grep(getenv("LD_LIBRARY_PATH"),GCClibpath) == []) then
126             setenv("LD_LIBRARY_PATH",GCClibpath+"/../../../:"+getenv("LD_LIBRARY_PATH"));
127         end
128
129         cmd = "make "
130
131         cmd = cmd + gencompilationflags_unix(ldflags, cflags, fflags, cc, "build")
132
133         //** BEWARE : this function can cause errors if used with "old style" Makefile inside a Scilab 5
134         //**          environment where the Makefile are created from a "./configure"
135         [msg, ierr, stderr] = unix_g(cmd) ;
136
137         if ( ilib_verbose() == 2 ) then
138             mprintf(gettext("%s: Build command: %s\n"),"ilib_compile",cmd);
139             mprintf(gettext("Output: %s\n"),msg);
140             mprintf(gettext("stderr: %s\n"),stderr);
141         end
142
143         if ierr <> 0 then
144             errMsg = sprintf(gettext("%s: An error occurred during the compilation:\n"), "ilib_compile");
145             errMsg = [errMsg ; stderr];
146             errMsg = [errMsg ; sprintf(gettext("%s: The command was:\n"), "ilib_compile")];
147             errMsg = [errMsg ; cmd];
148             chdir(oldPath); // Go back to the working dir
149             error(errMsg);
150             return ;
151         end
152
153         if stderr <> "" then
154             if ( ilib_verbose() <> 0 ) then
155                 mprintf(gettext("%s: Warning: No error code returned by the compilation but the error output is not empty:\n"),"ilib_compile");
156                 mprintf(stderr);
157             end
158             return ;
159         end
160
161         generatedLibrary=".libs/" + lib_name;
162         // Copy the produce lib to the working path
163         if ~isfile(generatedLibrary) then
164             error(msprintf(gettext("%s: Could not find the built library ''%s''.\n"),"ilib_compile",generatedLibrary));
165         end
166         copyfile(generatedLibrary, oldPath);
167
168     end
169
170     libn = path + lib_name_make ;
171     chdir(oldpath);
172
173 endfunction
174 //=============================================================================
175 // function only defined in ilib_compile
176 //=============================================================================
177 function [make_command, lib_name_make, lib_name,path, makename, files] = ..
178     ilib_compile_get_names(lib_name, files)
179
180     if getos() <> "Windows" then
181         path = "";
182
183         lib_name = lib_name + getdynlibext();
184         lib_name_make = lib_name;
185
186         make_command = "make ";
187         if files <> [] then
188             files = files + ".o";
189         end
190
191         makename = "Makefile";
192
193     else // Windows
194         // Load dynamic_link Internal lib if it"s not already loaded
195         if ~ exists("dynamic_linkwindowslib") then
196             load("SCI/modules/dynamic_link/macros/windows/lib");
197         end
198
199         [make_command, lib_name_make, lib_name, path, makename, files] = ..
200         dlwGetParamsIlibCompil(lib_name, files);
201     end
202
203 endfunction
204 //=============================================================================
205