7515b3533b753fa1eb96d2f85046d9c5df79c42e
[scilab.git] / scilab / modules / dynamic_link / macros / ilib_compile.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) INRIA
3 // Copyright (C) ENPC
4 // Copyright (C) DIGITEO - 2009
5 // Copyright (C) DIGITEO - 2010-2011 - Allan CORNET
6 //
7 // This file must be used under the terms of the CeCILL.
8 // This source file is licensed as described in the file COPYING, which
9 // you should have received as part of this distribution.  The terms
10 // are also available at
11 // http://www.cecill.info/licences/Licence_CeCILL_V2.1-en.txt
12
13 //=============================================================================
14 function libn = ilib_compile(lib_name, ..
15     makename, ..
16     files, ..
17     ldflags, ..
18     cflags, ..
19     fflags, ..
20     cc)
21
22     [lhs,rhs] = argn(0);
23     if rhs < 2 then
24         error(msprintf(gettext("%s: Wrong number of input argument(s).\n"),"ilib_compile"));
25         return
26     end
27
28     // The name of the library starts by "lib", strip it
29     lib_name_orig = strsubst(lib_name,"/^lib/","","r");
30
31     libn=""; //** init variable
32     if getos() == "Windows" & ~haveacompiler() then
33         error(_("A Fortran or C compiler is required."))
34         return;
35     end
36
37     [lhs,rhs]=argn(0);
38
39     if rhs < 3 then
40         files = [];
41     else
42         if ~isempty(files) & (or(fileext(files)==".o") | or(fileext(files)==".obj")) then
43             error(999, msprintf(_("%s: A managed file extension for input argument #%d expected."), "ilib_compile", 3));
44         end
45     end
46
47     if typeof(lib_name)<>"string" then
48         error(msprintf(gettext("%s: Wrong type for input argument #%d: A string expected.\n"),"ilib_compile",1));
49         return ;
50     end
51
52     oldpath = pwd();
53     files = files(:)';
54
55     [make_command, lib_name_make, lib_name, path, makename, files]= ...
56     ilib_compile_get_names(lib_name, files);
57
58     if isdir(path) then
59         chdir(path);
60     end
61
62     if getos() == "Windows" then
63         //** ----------- Windows section  -----------------
64
65         // Load dynamic_link Internal lib if it's not already loaded
66         if ~ exists("dynamic_linkwindowslib") then
67             load("SCI/modules/dynamic_link/macros/windows/lib");
68         end
69
70         dlwCompile(files, make_command, makename);
71
72     else
73         //** ---------- Linux/MacOS/Unix section ---------------------
74
75         ScilabTreeFound=%f;
76
77         // Source tree version
78         // Headers are dispatched in the source tree
79         if isdir(SCI+"/modules/core/includes/") then
80             defaultModulesCHeader=[ "core", "mexlib","api_scilab","output_stream","localization",  "dynamic_link",  "threads",  "string",  "console"];
81             defaultKernelCHeader=[ "ast" "exps" "operations" "parse" "symbol" "system_env" "types"];
82             defaultModulesFHeader=[ "core" ];
83             ScilabTreeFound=%t
84
85             for x = defaultModulesCHeader;
86                 cflags = cflags + " -I" + SCI + "/modules/" + x + "/includes/ ";
87             end
88
89             for x = defaultKernelCHeader;
90                 cflags = cflags + " -I" + SCI + "/modules/ast/includes/" + x;
91             end
92
93             for x = defaultModulesFHeader(:)';
94                 fflags=" -I"+SCI+"/modules/"+x+"/includes/ " + fflags;
95             end
96         end
97
98         // Binary version
99         if isdir(SCI+"/../../include/scilab/") & ~ScilabTreeFound then
100             cflags="-I"+SCI+"/../../include/scilab/ -I"+SCI+"/../../include/  -I"+SCI+"/../../lib/Eigen/includes/ " + cflags
101             fflags="-I"+SCI+"/../../include/scilab/ " + fflags
102             ScilabTreeFound=%t
103         end
104
105         // System version (ie: /usr/include/scilab/)
106         if isdir("/usr/include/scilab/") & ~ScilabTreeFound then
107             cflags="-I/usr/include/scilab/ "+cflags
108             fflags="-I/usr/include/scilab/ "+fflags
109             ScilabTreeFound=%t
110         end
111
112         if ( ilib_verbose() <> 0 & ScilabTreeFound <> %t) then
113             mprintf(gettext("%s: Warning: Scilab has not been able to find where the Scilab sources are. Please submit a bug report on http://bugzilla.scilab.org/\n"),"ilib_compile");
114         end
115
116         oldPath = pwd();
117
118         // Switch back to the TMPDIR where the mandatory files are
119
120         chdir(TMPDIR+"/"+lib_name_orig);
121
122         // Detect the actual path to the libstdc++ library. For the dynamic link
123         // build, we want to use the same lib as the compiler installed.
124         // CF bug #7887 for more information.
125         // Note that, for the configure, the setup is done by compilerDetection.sh
126         cmdGCC="if test -x ""$(which gcc 2>/dev/null)""; then echo $(LC_ALL=C gcc -print-search-dirs|awk ''$1==""install:""{print $2}''); fi";
127         [GCClibpath, ierr, stderr] = unix_g(cmdGCC);
128
129         if (GCClibpath <> "" & GCClibpath <> [] & ierr == 0 & grep(getenv("LD_LIBRARY_PATH"),GCClibpath) == []) then
130             setenv("LD_LIBRARY_PATH",GCClibpath+"/../../../:"+getenv("LD_LIBRARY_PATH"));
131         end
132
133         cmd = "make "
134
135         cmd = cmd + gencompilationflags_unix(ldflags, cflags, fflags, cc, "build")
136
137         //** BEWARE : this function can cause errors if used with "old style" Makefile inside a Scilab 5
138         //**          environment where the Makefile are created from a "./configure"
139         [msg, ierr, stderr] = unix_g(cmd) ;
140
141         if ( ilib_verbose() == 2 ) then
142             mprintf(gettext("%s: Build command: %s\n"),"ilib_compile",cmd);
143             mprintf(gettext("Output: %s\n"),msg);
144             mprintf(gettext("stderr: %s\n"),stderr);
145         end
146
147         if ierr <> 0 then
148             errMsg = sprintf(gettext("%s: An error occurred during the compilation:\n"), "ilib_compile");
149             errMsg = [errMsg ; stderr];
150             errMsg = [errMsg ; sprintf(gettext("%s: The command was:\n"), "ilib_compile")];
151             errMsg = [errMsg ; cmd];
152             chdir(oldPath); // Go back to the working dir
153             error(errMsg);
154             return ;
155         end
156
157         if stderr <> "" then
158             if ( ilib_verbose() <> 0 ) then
159                 mprintf(gettext("%s: Warning: No error code returned by the compilation but the error output is not empty:\n"),"ilib_compile");
160                 mprintf(stderr);
161             end
162             return ;
163         end
164
165         generatedLibrary=".libs/" + lib_name;
166         // Copy the produce lib to the working path
167         if ~isfile(generatedLibrary) then
168             error(msprintf(gettext("%s: Could not find the built library ''%s''.\n"),"ilib_compile",generatedLibrary));
169         end
170         copyfile(generatedLibrary, oldPath);
171
172     end
173
174     libn = path + lib_name_make ;
175     chdir(oldpath);
176
177 endfunction
178 //=============================================================================
179 // function only defined in ilib_compile
180 //=============================================================================
181 function [make_command, lib_name_make, lib_name,path, makename, files] = ..
182     ilib_compile_get_names(lib_name, files)
183
184     if getos() <> "Windows" then
185         path = "";
186
187         lib_name = lib_name + getdynlibext();
188         lib_name_make = lib_name;
189
190         make_command = "make ";
191         if files <> [] then
192             files = files + ".o";
193         end
194
195         makename = "Makefile";
196
197     else // Windows
198         // Load dynamic_link Internal lib if it"s not already loaded
199         if ~ exists("dynamic_linkwindowslib") then
200             load("SCI/modules/dynamic_link/macros/windows/lib");
201         end
202
203         [make_command, lib_name_make, lib_name, path, makename, files] = ..
204         dlwGetParamsIlibCompil(lib_name, files);
205     end
206
207 endfunction
208 //=============================================================================
209