move windows part in macros/windows (prepares to add vs project generation)
[scilab.git] / scilab / modules / dynamic_link / macros / ilib_compile.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) INRIA
3 // Copyright (C) ENPC
4 // Copyright (C) DIGITEO - 2009
5 // Copyright (C) DIGITEO - 2010-2011 - Allan CORNET
6 //
7 // This file must be used under the terms of the CeCILL.
8 // This source file is licensed as described in the file COPYING, which
9 // you should have received as part of this distribution.  The terms
10 // are also available at
11 // http://www.cecill.info/licences/Licence_CeCILL_V2-en.txt
12
13 //=============================================================================
14 function libn = ilib_compile(lib_name, ..
15                              makename, ..
16                              files, ..
17                              ldflags, ..
18                              cflags, ..
19                              fflags, ..
20                              cc)
21
22   [lhs,rhs] = argn(0);
23   if rhs < 2 then
24     error(msprintf(gettext("%s: Wrong number of input argument(s).\n"),"ilib_compile"));
25     return
26   end
27
28   // The name of the library starts by "lib", strip it
29   lib_name_orig = strsubst(lib_name,"/^lib/","","r");
30
31   libn=""; //** init variable
32
33   if ~haveacompiler() then
34     error(_("A Fortran or C compiler is required."))
35     return;
36   end
37
38   [lhs,rhs]=argn(0);
39
40   if rhs < 3 then
41     files = [];
42   else
43     if ~isempty(files) & (or(fileext(files)==".o") | or(fileext(files)==".obj")) then
44       error(999, msprintf(_("%s: A managed file extension for input argument #%d expected."), "ilib_compile", 3));
45     end
46   end
47
48   if typeof(lib_name)<>"string" then
49     error(msprintf(gettext("%s: Wrong type for input argument #%d: A string expected.\n"),"ilib_compile",1));
50     return ;
51   end
52
53   oldpath = pwd();
54   files = files(:)';
55
56   [make_command, lib_name_make, lib_name, path, makename, files]= ...
57       ilib_compile_get_names(lib_name, makename, files);
58
59   if isdir(path) then
60     chdir(path);
61   end
62
63   if getos() == "Windows" then
64     //** ----------- Windows section  -----------------
65     
66     // Load dynamic_link Internal lib if it"s not already loaded
67     if ~ exists("dynamic_linkwindowslib") then
68       load("SCI/modules/dynamic_link/macros/windows/lib");
69     end
70     
71     dlwCompile(files, make_command, makename);
72     
73   else
74     //** ---------- Linux/MacOS/Unix section ---------------------
75
76     ScilabTreeFound=%f;
77
78     // Source tree version
79     // Headers are dispatched in the source tree
80     if isdir(SCI+"/modules/core/includes/") then
81       defaultModulesCHeader=[ "core", "mexlib","api_scilab","output_stream","localization" ];
82       defaultModulesFHeader=[ "core" ];
83       ScilabTreeFound=%t
84
85       for x = defaultModulesCHeader(:)';
86           cflags=" -I"+SCI+"/modules/"+x+"/includes/ "+cflags;
87       end
88       cflags=" -I"+SCI+"/libs/MALLOC/includes/ " + cflags;
89
90       for x = defaultModulesFHeader(:)';
91           fflags=" -I"+SCI+"/modules/"+x+"/includes/ " + fflags;
92           end
93     end
94
95     // Binary version
96     if isdir(SCI+"/../../include/scilab/") & ~ScilabTreeFound then
97       cflags="-I"+SCI+"/../../include/scilab/ " + cflags
98       fflags="-I"+SCI+"/../../include/scilab/ " + fflags
99       ScilabTreeFound=%t
100     end
101
102     // System version (ie: /usr/include/scilab/)
103     if isdir("/usr/include/scilab/") & ~ScilabTreeFound then
104        cflags="-I/usr/include/scilab/ "+cflags
105        fflags="-I/usr/include/scilab/ "+fflags
106        ScilabTreeFound=%t
107     end
108
109     if ( ilib_verbose() <> 0 & ScilabTreeFound <> %t) then
110        mprintf(gettext("%s: Warning: Scilab has not been able to find where the Scilab sources are. Please submit a bug report on http://bugzilla.scilab.org/\n"),"ilib_compile");
111     end
112
113     oldPath = pwd();
114
115     // Switch back to the TMPDIR where the mandatory files are
116
117     chdir(TMPDIR+"/"+lib_name_orig);
118
119    // Detect the actual path to the libstdc++ library. For the dynamic link
120    // build, we want to use the same lib as the compiler installed.
121    // CF bug #7887 for more information.
122    // Note that, for the configure, the setup is done by compilerDetection.sh
123     cmdGCC="if test -x ""$(which gcc 2>/dev/null)""; then echo $(LC_ALL=C gcc -print-search-dirs|awk ''$1==""install:""{print $2}''); fi";
124     [GCClibpath, ierr, stderr] = unix_g(cmdGCC);
125     if (GCClibpath <> "" & ierr == 0 & grep(getenv("LD_LIBRARY_PATH"),GCClibpath) == []) then
126         setenv("LD_LIBRARY_PATH",GCClibpath+"/../../../:"+getenv("LD_LIBRARY_PATH"));
127     end
128
129     cmd = "make "
130
131     cmd = cmd + gencompilationflags_unix(ldflags, cflags, fflags, cc, "build")
132
133     //** BEWARE : this function can cause errors if used with "old style" Makefile inside a Scilab 5
134     //**          environment where the Makefile are created from a "./configure"
135     [msg, ierr, stderr] = unix_g(cmd) ;
136
137     if ( ilib_verbose() == 2 ) then
138       mprintf(gettext("%s: Build command: %s\n"),"ilib_compile",cmd);
139       mprintf(gettext("Output: %s\n"),msg);
140       mprintf(gettext("stderr: %s\n"),stderr);
141     end
142
143     if ierr <> 0 then
144       mprintf(gettext("%s: An error occurred during the compilation:\n"),"ilib_compile");
145       lines(0);
146       disp(stderr);
147       mprintf("\n");
148       mprintf(gettext("%s: The command was:\n"),"ilib_compile");
149       mprintf(cmd);
150       mprintf("\n");
151       chdir(oldPath); // Go back to the working dir
152       return ;
153     end
154
155     if stderr <> "" then
156       if ( ilib_verbose() <> 0 ) then
157         mprintf(gettext("%s: Warning: No error code returned by the compilation but the error output is not empty:\n"),"ilib_compile");
158         mprintf(stderr);
159       end
160       return ;
161     end
162
163     generatedLibrary=".libs/" + lib_name;
164     // Copy the produce lib to the working path
165     if ~isfile(generatedLibrary) then
166       error(msprintf(gettext("%s: Could not find the built library ''%s''.\n"),"ilib_compile",generatedLibrary));
167     end
168     copyfile(generatedLibrary, oldPath);
169     
170   end
171   
172   libn = path + lib_name_make ;
173   chdir(oldpath);
174
175 endfunction
176 //=============================================================================
177 // function only defined in ilib_compile
178 //=============================================================================
179 function [make_command,lib_name_make,lib_name,path,makename,files] = ..
180              ilib_compile_get_names(lib_name, makename, files)
181
182   if getos() <> "Windows" then
183
184     k = strindex(makename,["/","\"]);
185
186     if k~=[] then
187       path = part(makename,1:k($));
188       makename = part(makename,k($)+1:length(makename));
189     else
190       path = "";
191     end
192
193     lib_name = lib_name + getdynlibext();
194     lib_name_make = lib_name;
195
196     make_command = "make ";
197     if files <> [] then
198       files = files + ".o";
199     end
200
201   else // Windows
202     // Load dynamic_link Internal lib if it"s not already loaded
203     if ~ exists("dynamic_linkwindowslib") then
204       load("SCI/modules/dynamic_link/macros/windows/lib");
205     end
206
207     [make_command, lib_name_make, lib_name, path, makename, files] = ..
208          dlwGetParamsIlibCompil(lib_name, makename, files);
209   end
210
211 endfunction
212 //=============================================================================
213