Merge remote-tracking branch 'origin/6.1'
[scilab.git] / scilab / modules / elementary_functions / macros / %sp_diag.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) INRIA
3 //
4 // Copyright (C) 2012 - 2016 - Scilab Enterprises
5 //
6 // This file is hereby licensed under the terms of the GNU GPL v2.0,
7 // pursuant to article 5.3.4 of the CeCILL v.2.1.
8 // This file was originally licensed under the terms of the CeCILL v2.1,
9 // and continues to be available under such terms.
10 // For more information, see the COPYING file which you should have received
11 // along with this program.
12
13 function d = %sp_diag(a,k)
14     // %sp_diag - implement diag function for sparse matrix, rational matrix ,..
15
16     [lhs,rhs]=argn(0)
17     if rhs==1 then k=0,end
18
19     [ij,v,sz]=spget(a)
20     m=sz(1);n=sz(2)
21     if m>1&n>1 then
22         if ij<>[]
23             l = find(ij(:,1)==(ij(:,2)-k))
24         else
25             l = []
26         end
27         if k<=0 then
28             mn=min(m+k,n)
29             i0=-k
30         else
31             mn=min(m,n-k)
32             i0=0
33         end
34         kk=abs(k)
35         if l==[] then d=sparse([],[],[mn,1]);return;end
36         d=sparse([ij(l,1)-i0,ones(ij(l,1))],v(l),[mn,1])
37     else
38         if m>1 then ij=ij(:,1);else ij=ij(:,2);end
39         nn = max(m,n)+abs(k)
40         if ij==[] then
41             d=sparse([],[],[nn,nn])
42         else
43             if k>0 then
44                 d=sparse([ij,ij+k],v,[nn,nn])
45             else
46                 d=sparse([ij-k,ij],v,[nn,nn])
47             end
48         end
49     end
50 endfunction