error(number): converting occurrences remaining in all .sce .sci files
[scilab.git] / scilab / modules / fileio / macros / mdelete.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) INRIA - Vincent COUVERT
3 // Copyright (C) INRIA - Pierre MARECHAL
4 //
5 // Copyright (C) 2012 - 2016 - Scilab Enterprises
6 //
7 // This file is hereby licensed under the terms of the GNU GPL v2.0,
8 // pursuant to article 5.3.4 of the CeCILL v.2.1.
9 // This file was originally licensed under the terms of the CeCILL v2.1,
10 // and continues to be available under such terms.
11 // For more information, see the COPYING file which you should have received
12 // along with this program.
13
14 function mdelete(filename)
15
16     // Scilab Project - V. Couvert
17     // Delete a file given by filename (or a set of files if meta-characters used in filename)
18
19     // Modified by Pierre MARECHAL
20     // Scilab Team
21     // Date : 2006-06-29
22     // Fix the bug2041
23
24     // Date : 2007-01-16
25     // Fix the bug2288 (Thanks to M. Dubois, http://dubois.ensae.net )
26
27     rhs = argn(2);
28     if rhs <> 1 then
29         msg = gettext("%s: Wrong number of input arguments: %d expected.\n")
30         error(msprintf(msg, "mdelete", 1));
31     end
32
33     if type(filename) <> 10 | size(filename,"*") <> 1 then
34         msg = gettext("%s: Wrong type for input argument: String expected.\n")
35         error(msprintf(msg, "mdelete"));
36     end
37
38     // Handle file path
39     if getos() == "Windows" then
40         filename = strsubst(filename,filesep(),"/");
41     end
42
43     // File path
44     k = strindex(filename,"/");
45
46     if k == [] then
47         file_path = "./";
48     else
49         file_path = part(filename,1:k($));
50         filename  = part(filename,k($)+1:length(filename));
51     end
52
53     if getos() == "Windows" then
54         fullfilename = strsubst(file_path+filename,"/","\");
55         lst_files    = listfiles(fullfilename);
56     else
57         lst_files = listfiles(file_path+filename);
58     end
59
60     if lst_files<>[] then
61         for i=1:size(lst_files,"*")
62             deletefile(lst_files(i));
63         end
64     end
65
66 endfunction