xget(): removal from tests
[scilab.git] / scilab / modules / fileio / tests / nonreg_tests / bug_4339.tst
1 // =============================================================================
2 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
3 // Copyright (C) 2012 - DIGITEO - Antoine ELIAS
4 //
5 //  This file is distributed under the same license as the Scilab package.
6 // =============================================================================
7 //
8 // <-- Non-regression test for bug 4339 -->
9 //
10 // <-- Bugzilla URL -->
11 // http://bugzilla.scilab.org/show_bug.cgi?id=4339
12 //
13 // <-- Short Description -->
14 // listvarinfile does not manage graphic handles
15
16 clear;
17 warning("off")
18 //figure
19 hF = figure();
20
21 //axes + plot3d
22 plot3d();
23 hPlot3d = gca();
24
25 //axes + compound + polyline + legend
26 scf();
27 plot2d();
28 hPlot2d = gca();
29
30 //Fac3d
31 scf();
32 t = [0 : 0.3 : 2*%pi]';
33 z = sin(t) * cos(t');
34 [xx, yy, zz] = genfac3d(t, t, z);
35 plot3d([xx xx],[yy yy],list([zz zz+4],[4*ones(1,400) 5*ones(1,400)]))
36 hFac3d = gce();
37 clear t z xx yy zz;
38 //Rectangle
39 scf();
40 plot2d(0,0,-1,"010"," ",[-2,-2,2,2]);
41 xrect(-1,1,2,2);
42 hRectangle = gce();
43
44 //Arc
45 xarc(-1.5,1.5,3,3,0,360*64)
46 hArc = gce();
47
48 //Champ
49 champ(-5:5,-5:5,rand(11,11),rand(11,11))
50 hChamp = gce();
51
52 //Segs
53 x=2*%pi*(0:7)/8;
54 xv=[2*sin(x);9*sin(x)];
55 yv=[2*cos(x);9*cos(x)];
56 xsegs(xv,yv,1:8)
57 hSeg = gce();
58 clear x xv yv;
59
60 //Grayplot
61 scf();
62 m=5;n=5;
63 M=round(32*rand(m,n));
64 grayplot(1:m,1:n,M)
65 hGrayplot = gce();
66 clear m n M;
67
68 //Matplot
69 Matplot(1:size(gcf().color_map, 1))
70 hMatplot = gce();
71
72 //Fec
73 scf();
74 x = [0 1 0 -1];
75 y = [0 0 1  1];
76 T = [1 1 2 3 1;
77 2 3 4 1 1];
78 z = [0 1 0 -1];
79 fec(x, y, T, z, strf="040", mesh=%t)
80 hFec = gce();
81 clear x y z T
82
83 //Text
84 xstring(0.5,0.5,"Text demo",0,0)
85 hText = gce();
86
87 //Axis
88 scf();
89 plot2d(1:10,1:10,1,"020")
90 // horizontal axis
91 drawaxis(x=2:7,y=4,dir="u",tics="v");
92 hAxis = gce();
93
94 //uimenu
95 hMenu = uimenu(hF,"label", "windows");
96
97 //uicontrol
98 hUiControl = uicontrol(hF,"style","listbox", "position", [10 10 150 160]);
99
100 save(TMPDIR + "/bug_4339.bin", "hUiControl", "hMenu", "hAxis", "hText", "hFec", "hMatplot", "hGrayplot", "hSeg", "hChamp", "hArc", "hRectangle", "hFac3d", "hPlot2d", "hPlot3d", "hF");
101
102 [varList, varSize] = listvarinfile(TMPDIR + "/bug_4339.bin");
103 varListRef = ["hUiControl"; "hMenu"; "hAxis"; "hText"; "hFec"; "hMatplot"; "hGrayplot"; "hSeg"; "hChamp"; "hArc"; "hRectangle"; "hFac3d"; "hPlot2d"; "hPlot3d"; "hF"];
104 assert_checkequal(gsort(varList), gsort(varListRef));
105