[graphics] Demos: add a 'Technical plots' section
[scilab.git] / scilab / modules / graphics / demos / technical / black.dem.sce
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) 2019 - Samuel GOUGEON
3 //
4 // This file is released under the 3-clause BSD license. See COPYING-BSD.
5
6 function demo_black()
7     my_handle = scf(100001);
8     clf(my_handle,"reset");
9     demo_viewCode("black.dem.sce");
10     my_plot_desc = "black";
11     my_handle.figure_name = my_plot_desc;
12
13     // DEMO START
14     //Black diagram
15     s = poly(0,'s');
16     sl = syslin('c',5*(1+s)/(.1*s.^4+s.^3+15*s.^2+3*s+1))
17
18     subplot(1,2,1)
19     black(sl, 0.01, 10);
20
21     subplot(1,2,2)
22     //Black diagram with Nichols chart as a grid
23     Plant = syslin('c',16000/((s+1)*(s+10)*(s+100)));
24     //two degree of freedom PID
25     tau = 0.2;xsi=1.2;
26     PID = syslin('c',(1/(2*xsi*tau*s))*(1+2*xsi*tau*s+tau.^2*s.^2));
27     black([Plant;Plant*PID ],0.01,100,["Plant";"Plant and PID corrector"]);
28
29     //move the caption in the lower right corner
30     gca().children(1).legend_location = "in_lower_right";
31     nicholschart(colors=color('light gray')*[1 1])
32     // DEMO END
33 endfunction
34
35 demo_black();
36 clear demo_black;