077469b3e85f39470a7b74a4e5f2176e666214ba
[scilab.git] / scilab / modules / graphics / macros / colorbar.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) Bruno Pincon
3 // Copyright (C) Serge Steer (adaptation to new graphic system)
4 // Copyright (C) 2012 - 2016 - Scilab Enterprises
5 //
6 // This file is hereby licensed under the terms of the GNU GPL v2.0,
7 // pursuant to article 5.3.4 of the CeCILL v.2.1.
8 // This file was originally licensed under the terms of the CeCILL v2.1,
9 // and continues to be available under such terms.
10 // For more information, see the COPYING file which you should have received
11 // along with this program.
12
13 function colorbar(umin, umax, colminmax, fmt)
14
15     //  PURPOSE
16     //     Draw a colorbar for a plot3d, fec, Sgrayplot, etc...
17     //
18     //  PARAMETERS
19     //     umin : min value of the plot
20     //     umax : max value of the plot
21     //     colminmax : (optional) a vector with 2 integer components
22     //                 the first is the color number (of the current
23     //                 colormap) associated with umin
24     //                 the second the max color number ....
25     //                 default : [1 nb_colors] where nb_colors is
26     //                 the number of colors of the current colormap.
27     //                 May be useful to deal with a part of the colormap
28     //                 (for instance using fec or plot3d)
29     //     fmt : optional, a C format to display colorbar graduations
30     //
31     //  CAUTION
32     //     this function may be used BEFORE a plot3d, fec, Sgrayplot, ...
33     //     It is important because this function set and change the
34     //     frame for the plot. This way the colorbar is not part of
35     //     the "associated" plot and so is not modified by a zoom or
36     //     a rotation of the plot.
37     //
38     //
39     //  EXAMPLES
40     //     see the help page
41
42     // Check number of input argument
43     [lhs, rhs] = argn();
44     if rhs < 2 then
45         error(msprintf(gettext("%s: Wrong number of input arguments: %d to %d expected.\n"), "colorbar", 2, 4));
46     end
47     nb_grad = 5
48     if ~exists("fmt","local") then
49         fmt="%-5.2g";
50     else
51         if type(fmt)<>10|size(fmt,"*")<>1 then
52             error(msprintf(gettext("%s: Wrong type for input argument #%d: %s data structure expected.\n"), "colorbar", 4, "string (containing a C format)"));
53         end
54     end
55
56     f=gcf();
57     if ~exists("colminmax","local") then
58         nb_colors = size(f.color_map,1)
59         colminmax = [1 nb_colors]
60     else
61         nb_colors = colminmax(2) - colminmax(1) + 1
62     end
63
64     //defer the drawing to avoid binking
65     id=f.immediate_drawing=="on";
66     if id then f.immediate_drawing=="off",end
67     // get current axes and properties
68     a=gca();
69     fg_color=a.foreground
70     wr=a.axes_bounds; //get the rectangle of the current axes
71
72     // modify the orginal axes to let space for the colorbar
73     a_pl=a;
74     a_pl.axes_bounds=[wr(1) , wr(2) , 0.85*wr(3) , wr(4)]
75
76     // create a new axes for the colorbar et set its properties
77     a_cb=newaxes();
78     a_cb.axes_bounds=[wr(1)+0.83*wr(3) , wr(2)+wr(4)*0.2 , 0.2*wr(3) , wr(4)*0.6];
79     a_cb.data_bounds=[0 umin;1 umax];
80     a_cb.foreground=a.foreground;
81     a_cb.background=f.background;
82     a_cb.axes_visible="on";
83     a_cb.y_location = "right";
84     a_cb.tight_limits ="on";
85
86     //It is not possible to set no ticks for x (should be fixed)
87     a_cb.x_ticks=tlist(["ticks","locations","labels"],-1,"");
88     ytics = linspace(umin, umax, nb_grad);
89     a_cb.y_ticks=tlist(["ticks","locations","labels"],ytics', " "+msprintf(fmt+"\n",ytics'));
90     a_cb.auto_ticks = ["off","off","on"];
91     a_cb.box = "on";
92     a_cb.margins=[0 0.75 0 0];
93
94     //draw the colorbar
95     y = linspace(umin,umax,nb_colors)
96     col=[colminmax(1):colminmax(2)]
97     Sgrayplot([0 1],y,[col;col],colminmax=colminmax)
98
99     //reset the initial values
100     sca(a_pl) //current axes
101     if id then f.immediate_drawing="on",end //drawing mode
102
103 endfunction
104
105
106
107
108
109