Removed references to the xbasc function
[scilab.git] / scilab / modules / graphics / macros / contour.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) INRIA
3 // This file must be used under the terms of the CeCILL.
4 // This source file is licensed as described in the file COPYING, which
5 // you should have received as part of this distribution.  The terms
6 // are also available at    
7 // http://www.cecill.info/licences/Licence_CeCILL_V2-en.txt
8
9 function contour(x,y,z,nz,theta,alpha,leg,flag,ebox,zlev)
10         
11         rhs=argn(2);
12         
13         if rhs == 0 then   // demo
14                 
15                 deff('[z]=Surf1(x,y)','z=x^2+y^3');
16                 deff('[z]=Surf2(x,y)','z=x^2+y^2');
17                 
18                 x = -1:0.1:1;
19                 y = x;
20                 z = eval3d(Surf2,x,y)
21                 
22                 subplot(211);
23                 contour(x,y,Surf1,10);
24                 subplot(212);
25                 plot3d(x,y,z);
26                 contour(x,y,z+0.1,10,flag=[0 2 4]);
27                 return
28         end
29         
30   if rhs<4, error('contour requires at least 4 arguments'),end;
31   levels=[]
32
33   opts=[]
34   if exists('theta','local')==1 then opts=[opts,'theta=theta'],end
35   if exists('alpha','local')==1 then opts=[opts,'alpha=alpha'],end
36   if exists('leg'  ,'local')==1 then opts=[opts,'leg=leg']    ,end
37   if exists('ebox' ,'local')==1 then opts=[opts,'ebox=ebox']  ,end
38   if exists('flag' ,'local')==0 then flag=[2 2 3], end
39   if exists('zlev' ,'local')==0 then zlev=0  ,end
40   
41   if or(type(z)==[11 13]) then 
42     fun=z;clear z //to avoid redfinition warning
43     if type(fun)==11 then comp(fun),end
44     z=feval(x,y,fun)
45   end
46   
47   job=flag(1)
48   if rhs==4|job==2 then  
49     contour2d(x,y,z,nz);
50     return,
51   end
52     
53   if size(nz,'*')==1 then
54     style=1:nz,
55   else
56     style=1:size(nz,'*')
57   end
58   
59   opts=strcat([opts,'flag=flag(2:3)'],',');
60
61   [xc,yc]=contour2di(x,y,z,nz);
62
63
64   fig=gcf();
65   autoc=fig.auto_clear;
66   if autoc=="on" then, clf(),end
67   a=gca();
68   fg=a.foreground
69   v=fig.immediate_drawing;
70   fig.immediate_drawing="off"
71   fig.auto_clear="off"
72   cnt=0
73
74   fpf=xget("fpf");if fpf=='' then fpf='%.2g',end
75   k=1;n=yc(k); c=0; level = %inf;
76   while k < length(xc)
77     n = yc(k)
78     if xc(k) ~= level then 
79       c = c+1; level = xc(k),levels=[level levels];
80       a.foreground=c;
81       if cnt>0 then glue(a.children(1:cnt)),cnt=0,end
82     end
83     
84     if job==1 then zz=zlev,else zz=level,end
85     execstr('param3d(xc(k+(1:n)),yc(k+(1:n)),zz*ones(1,n),'+opts+')')
86     
87     cnt = cnt+1
88     if stripblanks(fpf)<>'' then
89           // don't clip as in contour2d since we are in 3D here
90           // and stringbox gives data in 2D
91       xstring(xc(k+1+n/2),yc(k+1+n/2)," "+msprintf(fpf,level))
92       e=gce();e.data(3)=zz;e.clip_state = "off"
93       cnt=cnt+1
94     end
95     k=k+n+1;
96   end
97   if cnt>0 then glue(a.children(1:cnt)),cnt=0,end
98   set('current_obj',a);
99   a.foreground=fg
100   if flag(3) == 0 then
101     a.axes_visible='off';
102     a.box='off';
103   elseif flag(3) == 1 then
104     a.axes_visible='off';
105     a.box='off';
106   elseif flag(3) == 2 then
107     a.axes_visible='off';
108     a.box='back_half';
109   elseif flag(3)==3 then
110     a.axes_visible='off';
111     a.box='on';
112    elseif flag(3)>=4 then
113     a.axes_visible='on';
114     a.box='on';
115   end
116   fig.immediate_drawing=v;
117   fig.auto_clear=autoc;
118 endfunction
119