Remove graphic test for new mode from macros.
[scilab.git] / scilab / modules / graphics / macros / contour.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) INRIA
3 // This file must be used under the terms of the CeCILL.
4 // This source file is licensed as described in the file COPYING, which
5 // you should have received as part of this distribution.  The terms
6 // are also available at    
7 // http://www.cecill.info/licences/Licence_CeCILL_V2-en.txt
8
9 function contour(x,y,z,nz,theta,alpha,leg,flag,ebox,zlev)
10   
11         rhs=argn(2);
12         if rhs == 0 then   // demo
13         
14                 title_demo = [
15                         '';
16                         'Demo of contour()';
17                         '========================================';
18                         ''];
19                 
20                 s_mat=[
21                         'deff(''[z]=Surf1(x,y)'',''z=x^2+y^3'');';
22                         'x=-1:0.1:1; y=x;'
23                         'subplot(211);contour(x,y,Surf1,10);'
24                         'deff(''[z]=Surf2(x,y)'',''z=x^2+y^2'');';
25                         'z=eval3d(Surf2,x,y)'
26                         'subplot(212);plot3d(x,y,z);contour(x,y,z+0.1,10,flag=[0 2 4]);'];
27                 
28                 write(%io(2),title_demo);
29                 write(%io(2),s_mat);
30                 write(%io(2),' ');
31                 execstr(s_mat);
32                 return
33         end
34
35   
36   if rhs<4, error('contour requires at least 4 arguments'),end;
37   levels=[]
38
39   opts=[]
40   if exists('theta','local')==1 then opts=[opts,'theta=theta'],end
41   if exists('alpha','local')==1 then opts=[opts,'alpha=alpha'],end
42   if exists('leg'  ,'local')==1 then opts=[opts,'leg=leg']    ,end
43   if exists('ebox' ,'local')==1 then opts=[opts,'ebox=ebox']  ,end
44   if exists('flag' ,'local')==0 then flag=[2 2 3], end
45   if exists('zlev' ,'local')==0 then zlev=0  ,end
46   
47   if or(type(z)==[11 13]) then 
48     fun=z;clear z //to avoid redfinition warning
49     if type(fun)==11 then comp(fun),end
50     z=feval(x,y,fun)
51   end
52   
53   job=flag(1)
54   if rhs==4|job==2 then  
55     contour2d(x,y,z,nz);
56     return,
57   end
58     
59   if size(nz,'*')==1 then
60     style=1:nz,
61   else
62     style=1:size(nz,'*')
63   end
64   
65   opts=strcat([opts,'flag=flag(2:3)'],',');
66
67   [xc,yc]=contour2di(x,y,z,nz);
68
69
70   fig=gcf();
71   autoc=fig.auto_clear;
72   if autoc=="on" then, xbasc(),end
73   a=gca();
74   fg=a.foreground
75   v=fig.immediate_drawing;
76   fig.immediate_drawing="off"
77   fig.auto_clear="off"
78   cnt=0
79
80   fpf=xget("fpf");if fpf=='' then fpf='%.2g',end
81   k=1;n=yc(k); c=0; level = %inf;
82   while k < length(xc)
83     n = yc(k)
84     if xc(k) ~= level then 
85       c = c+1; level = xc(k),levels=[level levels];
86       a.foreground=c;
87       if cnt>0 then glue(a.children(1:cnt)),cnt=0,end
88     end
89     
90     if job==1 then zz=zlev,else zz=level,end
91     execstr('param3d(xc(k+(1:n)),yc(k+(1:n)),zz*ones(1,n),'+opts+')')
92     
93     cnt = cnt+1
94     if stripblanks(fpf)<>'' then
95       xstring(xc(k+1+n/2),yc(k+1+n/2)," "+msprintf(fpf,level))
96       e=gce();e.data(3)=zz
97       cnt=cnt+1
98     end
99     k=k+n+1;
100   end
101   if cnt>0 then glue(a.children(1:cnt)),cnt=0,end
102   set('current_obj',a);
103   a.foreground=fg
104   if flag(3) == 0 then
105     a.axes_visible='off';
106     a.box='off';
107   elseif flag(3) == 1 then
108     a.axes_visible='off';
109     a.box='off';
110   elseif flag(3) == 2 then
111     a.axes_visible='off';
112     a.box='back_half';
113   elseif flag(3)==3 then
114     a.axes_visible='off';
115     a.box='on';
116    elseif flag(3)>=4 then
117     a.axes_visible='on';
118     a.box='on';
119   end
120   fig.immediate_drawing=v;
121   fig.auto_clear=autoc;
122 endfunction
123