Set color of patches in graypolarplot as the mean of its four corners as specified...
[scilab.git] / scilab / modules / graphics / macros / graypolarplot.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) INRIA
3 // This file must be used under the terms of the CeCILL.
4 // This source file is licensed as described in the file COPYING, which
5 // you should have received as part of this distribution.  The terms
6 // are also available at    
7 // http://www.cecill.info/licences/Licence_CeCILL_V2-en.txt
8
9
10 function graypolarplot(theta,rho,z,varargin)
11 [lhs,rhs]=argn(0)
12 if rhs<=0 then
13   rho=1:0.2:4;theta=(0:0.02:1)*2*%pi;
14   z=30+round(theta'*(1+rho^2));
15   xbasc();
16   f=gcf();
17   f.color_map=hotcolormap(128);
18   f.background= 128;
19   f.foreground=1;
20   a=gca();
21   a.background= 128;
22   a.foreground=1;
23   graypolarplot(theta,rho,z)
24   return
25 end
26
27
28 R=max(rho)
29 nv=size(varargin)
30 if nv>=1 then strf=varargin(2),else  strf='030',end
31 if nv>=2 then rect=varargin(4),else  rect=[-R -R R R]*1.1,end
32
33 // drawlater
34 fig = gcf();
35 immediate_drawing = fig.immediate_drawing;
36 fig.immediate_drawing = "off";
37
38 //plot2d(0,0,1,strf,' ',rect)
39 axes = gca();
40 axes.data_bounds = [rect(1), rect(2); rect(3), rect(4)];
41 axes.clip_state = "clipgrf";
42 //[rho,k]=sort(rho);z=z(:,k);
43
44 //nt=size(theta,'*');theta=matrix(theta,1,-1)*180/%pi
45 drawGrayplot(theta,rho,z);
46
47 axes.isoview = "on";
48 axes.box = "off";
49 axes.axes_visible = ["off","off","off"];
50 axes.x_label.text = "";
51 axes.y_label.text = "";
52 axes.z_label.text = "";
53
54 // bug here, we need to draw the axes in order to get correct bounding box.
55 draw(axes);
56
57
58 step=R/5
59 r=step;dr=0.02*r;
60 for k=1:4
61   xarc(-r,r,2*r,2*r,0,360*64)
62   arc = gce();
63   arc.line_style = 3;
64   xstring((r+dr)*cos(5*%pi/12),(r+dr)*sin(5*%pi/12),string(round(10*r)/10))
65   r=r+step
66 end
67 xarc(-r,r,2*r,2*r,0,360*64)
68 xstring((r+dr)*cos(5*%pi/12),(r+dr)*sin(5*%pi/12),string(round(10*r)/10))
69
70 rect=xstringl(0,0,'360');w=rect(3);h=rect(4);d=sqrt(w^2+h^2)/1.8
71 r=R+d
72 for k=0:11
73   xsegs([0;R*cos(k*(%pi/6))],[0;R*sin(k*(%pi/6))])
74   arc = gce();
75   arc.line_style = 3;
76   xstring(r*cos(k*(%pi/6))-w/2,r*sin(k*(%pi/6))-h/2,string(k*30))
77 end
78
79 // drawnow
80 fig.immediate_drawing = immediate_drawing;
81
82 endfunction
83
84 function [x,y] = polar2Cart(rho, theta)
85   x = rho * cos(theta);
86   y = rho * sin(theta);
87 endfunction
88
89
90 function drawGrayplot(theta, rh, z)
91 // draw only the colored part of the grayplot
92
93 // the aim of the function is to draw a set of curved facets
94 // In previous versions, it used arcs to perform this.
95 // However, since arcs are drawn from the origin to the outside
96 // there were overlapping and cause Z fighting in 3D.
97 // Consequenlty we now decompose each curved facet into a set of rectangular
98 // facets.
99
100 nbRho = size(rho,'*');
101 nbTheta = size(theta,'*');
102
103 nbDecomposition = 32; // number of approximation facets
104
105 nbRefinedTheta = (nbTheta - 1) * nbDecomposition + 1;
106
107 // first step decompose theta in smaller intervals
108 // Actually compute cosTheta and sinTheta for speed
109 cosTheta = zeros(1, nbRefinedTheta);
110 sinTheta = zeros(1, nbRefinedTheta);
111
112 // first values
113 cosTheta(1) = cos(theta(1));
114 sinTheta(1) = sin(theta(1));
115
116 index = 2;
117 for i=1:(nbTheta - 1)
118   for j=1:nbDecomposition
119     t = j / nbDecomposition;
120     interpolatedTheta = t * theta(i + 1) + (1 - t) * theta(i);
121     cosTheta(index) = cos(interpolatedTheta);
122     sinTheta(index) = sin(interpolatedTheta);
123     index = index + 1;
124   end
125 end
126
127
128 nbQuadFacets = (nbRho - 1) * (nbRefinedTheta - 1);
129
130 // allocate matrices
131 xCoords = zeros(4, nbQuadFacets);
132 yCoords = zeros(4, nbQuadFacets);
133 colors = zeros(1, nbQuadFacets);
134
135 index = 1;
136
137 // compute the 4xnbFacets matrices for plot 3d
138 for i=1:(nbRho - 1)
139   for j=1:(nbRefinedTheta - 1);
140     // get the 4 corners of a facet
141     xCoords(:,index) = [rho(i) * cosTheta(j)
142                         rho(i) * cosTheta(j + 1)
143                         rho(i + 1) * cosTheta(j + 1)
144                         rho(i + 1) * cosTheta(j)];
145
146     yCoords(:,index) = [rho(i) * sinTheta(j)
147                         rho(i) * sinTheta(j + 1)
148                         rho(i + 1) * sinTheta(j + 1)
149                         rho(i + 1) * sinTheta(j)];
150
151     // color is the same for each nbDecomposition facets
152         // retrieve the not refined index
153         thetaIndex = (j - 1) / nbDecomposition + 1;
154         // colors is the mean of the 4 vertices of the patch
155     colors(index) = (z(thetaIndex, i) + z(thetaIndex + 1, i) + z(thetaIndex + 1, i + 1) + z(thetaIndex, i + 1)) / 4;
156
157     index = index + 1;
158   end
159 end
160
161
162 // flat plot
163 zCoords = zeros(4, nbQuadFacets);
164
165 // disable line draing and hidden color
166 plot3d(xCoords,yCoords,list(zCoords,colors));
167 gPlot = gce();
168 gPlot.color_mode = -1;
169 gPlot.hiddencolor = 0;
170
171 // restore 2d view
172 axes = gca();
173 axes.view = "2d";
174
175
176 endfunction