1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
3 // This file must be used under the terms of the CeCILL.
4 // This source file is licensed as described in the file COPYING, which
5 // you should have received as part of this distribution.  The terms
6 // are also available at
7 // http://www.cecill.info/licences/Licence_CeCILL_V2-en.txt
9 function paramfplot2d(f,x,theta,flag,rect)
10 //animated plot of x-->f(x,t) for t=theta(1),theta(2),etc
11 //x=N-vector of x-values
12 //f(x,t)=N-vector of y-values.
13 //f: mapping x,t -> f(x,t) = R^N valued function for x= vector of R^N and t=real number.
14 //f can be a either Scilab function or a dynamically linked routine since
15 // y=f(x,t) is evaluated as y=feval(x(:),t,f). See feval.
16 // Here y should be a column vector.
17 //theta = row vector of parameters theta=[theta(1), theta(2),... theta(M)]
18 // Optional parameters
19 //flag = 'yes' (screen is cleared between two consecutive plots).
20 //flag = 'no'  (screen is not cleared between two consecutive plots).
21 //
22 //rect = "rectangle" [xmin, xmax, ymin, ymax] (1 x 4 real vector),
23 // containing a-priori lower and upper bounds for x and f(t,x).
24 //function y=f(x,t),y=abs(cos(1.5*x+4*t)).*sin(x+10*t),endfunction
25 //x=linspace(0,20*%pi,500);theta=0:0.05:5;
26 [lhs,rhs]=argn(0)
27 if rhs<3 then
28   error(msprintf(gettext("%s: Wrong number of input argument(s): At least %d expected.\n"), "paramfplot2d", 3));
29 end
31 x=x(:);
32 if rhs<5 then //compute the data bounds
33    xmin=min(x);xmax=max(x);
34    ymin=%inf;ymax=-%inf;
35    for t=theta
36       y=f(x,t); ymin=min(ymin,min(y)); ymax=max(ymax,max(y));
37    end
38    rect=[xmin,xmax,ymin,ymax];
39 end
40 if rhs<4 then flag='no';end
41 realtimeinit(0.1);
43 clf();
44 fig=gcf();
45 a=gca();
46 a.data_bounds=matrix(rect,2,2);
47 a.axes_visible='on';
48 fig.pixmap='on'; //double buffer mode
49 y=feval(x,theta(1),f);
50 xpoly(x,y(:));p=gce(); //the polyline handle
51 realtime(0);
52 if flag=='no' then
53   for k=1:size(theta,'*')
54     realtime(k);
55     y=feval(x,theta(k),f);
56     p.data(:,2)=y(:);
57     show_pixmap()
58   end
59 else
60   for k=1:size(theta,'*')
61     realtime(k);
62     plot2d(x,feval(x,theta(k),f))
63     show_pixmap()
64   end
65 end
66 fig.pixmap='off';
68 endfunction