plotframe: 'captions' is a function => overwriting removed
[scilab.git] / scilab / modules / graphics / macros / plotframe.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) INRIA
3 // Copyright (C) 2012 - 2016 - Scilab Enterprises
4 //
5 // This file is hereby licensed under the terms of the GNU GPL v2.0,
6 // pursuant to article 5.3.4 of the CeCILL v.2.1.
7 // This file was originally licensed under the terms of the CeCILL v2.1,
8 // and continues to be available under such terms.
9 // For more information, see the COPYING file which you should have received
10 // along with this program.
11
12 function plotframe(rect,axisdata,options,legs,subwindow)
13     // plotframe - fixes scales, tics and grid on a graphic,
14     //%Syntax
15     //  plotframe(rect,axisdata [,flags or leg or subwindow, ...)
16     //%Parameters
17     //  rect    : [xmin,ymin,xmax,ymax] data boudaries
18     //  axisdata: [nx,mx,ny,my]  mx and my x and y tics, nx,ny : x and y subtics
19     //  flags   : [quad,bounds] ou quad is a boolean if %t a grid is added
20     //        bounds a booleen also : if bounds is %t then rect can be modified
21     //        in order to have better scales on both axes which contains the
22     //        rect initial data.
23     //  subwindow : see xsetech (wrect)
24     //!
25     [lhs,rhs]=argn(0)
26
27     if rhs < 1 then
28         error(msprintf(gettext("%s: Wrong number of input argument(s): At least %d expected.\n"), "plotframe", 1));
29         return ;
30     end
31
32     f_subwin   = %f ;
33     f_flags    = %f ;
34     f_captions = %f ;
35     f_tics     = %f ;
36
37     // check if we found optional args
38     if exists("tics","local") == 1 then
39         f_tics = %t ;
40     end
41
42     if exists("flags","local") == 1 then
43         f_flags = %t ;
44     else
45         flags = [%f,%f] ;
46     end
47
48     if exists("Captions","local") == 1 then
49         f_captions = %t ;
50     end
51
52     if exists("subwin","local") == 1 then
53         f_subwin = %t ;
54     end
55
56     if rhs >= 2 & ~f_subwin & ~f_captions & ~f_flags & ~f_tics then
57         // no optional argument specified we use the old syntax
58         // with 2,3,4 or five parameters
59
60         f_tics = %t ;
61         tics = axisdata ;
62         if rhs == 5 then
63             select type(subwindow),
64             case 1 , subwin   = subwindow, f_subwin   = %t ;
65             case 4 , flags    = subwindow, f_flags    = %t ;
66             case 10, Captions = subwindow, f_captions = %t ;
67             end
68         end
69         if rhs >= 4 then
70             select type(legs),
71             case 1 , subwin   = legs, f_subwin   = %t ;
72             case 4 , flags    = legs, f_flags    = %t ;
73             case 10, Captions = legs, f_captions = %t ;
74             end
75         end
76         if rhs >= 3 then
77             select type(options),
78             case 1 , subwin   = options, f_subwin   = %t ;
79             case 4 , flags    = options, f_flags    = %t ;
80             case 10, Captions = options, f_captions = %t ;
81             end
82         end
83
84     end
85
86
87     if f_subwin then
88         xsetech(subwin,rect);
89     end
90     // -- trace du cadre et des echelles
91     if flags(2) then
92         if f_tics then
93             plot2d( [],[],0,"051"," ",rect,tics ) ;
94         else
95             plot2d( [],[],0,"051"," ",rect ) ;
96         end
97     else
98         if f_tics then
99             plot2d( [],[],0,"011"," ",rect, tics ) ;
100         else
101             plot2d( [],[],0,"011"," ",rect ) ;
102         end
103     end
104
105     // -- trace des legendes d'axes et du titre
106     if f_captions then
107         select size(Captions,"*"),
108         case 1, xtitle(Captions(1)) ;
109         case 2, xtitle(Captions(1),Captions(2)) ;
110         case 3, xtitle(Captions(1),Captions(2),Captions(3));
111         end
112     end
113
114     if flags(1) then  xgrid(); end
115
116 endfunction