toolbox_skeleton: fix isdir() typo on loaders
[scilab.git] / scilab / modules / modules_manager / etc / loader_template.sce
1 // This file is released under the 3-clause BSD license. See COPYING-BSD.
2 // Generated by builder.sce: Please, do not edit this file
3
4 function startModule(TOOLBOX_NAME, TOOLBOX_TITLE, VERBOSELevel)
5     // VERBOSELevel: to be implemented
6
7     mprintf("Start " + TOOLBOX_TITLE + "\n")
8
9     if isdef(TOOLBOX_NAME + "lib") then
10         warning(TOOLBOX_NAME + " library is already loaded")
11         return
12     end
13
14     root_tlbx = get_absolute_file_path("loader.sce")
15     libNames = []
16
17     //Load  functions library
18     // ================================================================
19     if isdir(root_tlbx + "/macros")
20         mprintf("\tLoad macros\n")
21         pathmacros = pathconvert( root_tlbx ) + "macros" + filesep()
22         execstr(TOOLBOX_NAME + "lib = lib(pathmacros)")
23         libNames = TOOLBOX_NAME + "lib" // to be returned to the calling level
24     end
25
26     // load gateways and Java libraries
27     // ================================================================
28     if isdir(root_tlbx + "/sci_gateway")
29         oldVerbose = ilib_verbose()
30         ilib_verbose(0);
31         mprintf("\tLoad gateways\n")
32         exec(pathconvert(root_tlbx+"/sci_gateway/loader_gateway.sce", %f), -1)
33     end
34     if isfile(root_tlbx + "/src/java/loader.sce")
35         mprintf("\tLoad Java libraries\n")
36         exec(pathconvert(root_tlbx+"/src/java/loader.sce", %f), -1)
37         ilib_verbose(oldVerbose)
38     end
39
40     // load localization
41     if isdir(root_tlbx + "/locales")
42         addlocalizationdomain(TOOLBOX_NAME, root_tlbx + "/locales")
43     end
44
45     // Load and add help chapter
46     // ================================================================
47     if isdir(root_tlbx + "/jar") && or(getscilabmode() == ["NW";"STD"])
48         mprintf("\tLoad help\n");
49         path_addchapter = pathconvert(root_tlbx+"/jar")
50         if isdir(path_addchapter) then
51             add_help_chapter(TOOLBOX_NAME, path_addchapter, %F)
52         end
53     end
54
55     // Load demos
56     // ================================================================
57     // Currently, strictly loads demos if there is a .dem.gateway.sce file
58     // TODO: In case of no gateway, this could be done in a default way by
59     // listing the .sce files and adding the demos under TOOLBOX_TILE > name
60     // of the file without .sce
61     // SG: add_demo() should be upgraded to do this (build a temporary
62     //     demo gateway with a proper title) when its argin#2 is a path pointing
63     //     to an existing directory instead of a .sce.
64     if isfile(root_tlbx + "/demos/" + TOOLBOX_NAME + ".dem.gateway.sce")
65         if or(getscilabmode() == ["NW";"STD"]) then
66             mprintf("\tLoad demos\n");
67             pathdemos = pathconvert(root_tlbx+"/demos/" + TOOLBOX_NAME + ".dem.gateway.sce", %F, %T)
68             add_demo(TOOLBOX_TITLE, pathdemos);
69         end
70     end
71
72     // Load Preferences GUI
73     // ================================================================
74     // TODO: same as for the demos
75     if isfile(root_tlbx + "/etc/" + TOOLBOX_NAME + "_preferences.xml")
76         if getscilabmode() == "STD" then
77             addModulePreferences(TOOLBOX_TITLE, root_tlbx, root_tlbx + "/etc/" + TOOLBOX_NAME + "_preferences.xml");
78         end
79     end
80
81     //TODO: manage Xcos toolboxes
82     // ================================================================
83
84     // We return the name(s) of loaded libraries of macros (if any)
85     // ------------------------------------------------------------
86     if libNames~=[] then
87         tmp = strcat(libNames,",")
88         execstr("["+tmp+"] = return("+tmp+")")
89     end
90 endfunction
91 // VERBOSELevel: environment variable
92 // library(e)s handle(s) are returned by startModule with return()
93 if ~isdef("VERBOSELevel") then
94     VERBOSELevel = [];
95 end
96 startModule("#TBX_NAME#", "#TBX_TITLE#", VERBOSELevel);
97 clear startModule