* Bug #9577 fixed - Optimization: setting neldermead_configure(-numberofvariables...
[scilab.git] / scilab / modules / optimization / macros / optimbase / optimbase_configure.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) 2008-2009 - INRIA - Michael Baudin
3 // Copyright (C) 2009-2011 - DIGITEO - Michael Baudin
4 //
5 // This file must be used under the terms of the CeCILL.
6 // This source file is licensed as described in the file COPYING, which
7 // you should have received as part of this distribution.  The terms
8 // are also available at
9 // http://www.cecill.info/licences/Licence_CeCILL_V2.1-en.txt
10
11 //
12 // optimbase_configure --
13 //   Configure the current object with the given value for the given key.
14 //
15 function this = optimbase_configure (this,key,value)
16     UN=number_properties("tiny")
17     [lhs,rhs]=argn();
18     if ( rhs <> 3 ) then
19         errmsg = msprintf(gettext("%s: Wrong number of input argument: %d expected.\n"), "optimbase_configure", 3);
20         error(errmsg)
21     end
22     select key
23     case "-verbose" then
24         optimbase_typereal ( value , "value" , 3 );
25         optimbase_checkscalar ( "optimbase_configure" , value , "value" , 3 )
26         optimbase_checkgreq ( "optimbase_configure" , value , "value" , 3 , 0 )
27         this.verbose = value;
28     case "-verbosetermination" then
29         optimbase_typereal ( value , "value" , 3 );
30         optimbase_checkscalar ( "optimbase_configure" , value , "value" , 3 )
31         optimbase_checkgreq ( "optimbase_configure" , value , "value" , 3 , 0 )
32         this.verbosetermination = value;
33     case "-logfile" then
34         optimbase_typestring ( value , "value" , 3 );
35         optimbase_checkscalar ( "optimbase_configure" , value , "value" , 3 )
36         if ( this.logstartup ) then
37             this = optimbase_logshutdown ( this )
38         end
39         this.logfile = value;
40         this = optimbase_logstartup ( this );
41     case "-x0" then
42         optimbase_typereal ( value , "value" , 3 );
43         [n,m] = size(value);
44         if m<>1 then
45             errmsg = msprintf(gettext("%s: The x0 vector is expected to be a column matrix, but current shape is %d x %d"),"optimbase_configure",n,m);
46             error(errmsg);
47         end
48         this.x0 = value;
49         this.numberofvariables = n; // Setting x0 also sets the size of the system
50     case "-maxfunevals" then
51         optimbase_typereal ( value , "value" , 3 );
52         optimbase_checkscalar ( "optimbase_configure" , value , "value" , 3 )
53         optimbase_checkgreq ( "optimbase_configure" , value , "value" , 3 , 1 )
54         this.maxfunevals = value;
55     case "-maxiter" then
56         optimbase_typereal ( value , "value" , 3 );
57         optimbase_checkscalar ( "optimbase_configure" , value , "value" , 3 )
58         optimbase_checkgreq ( "optimbase_configure" , value , "value" , 3 , 1 )
59         this.maxiter = value;
60     case "-tolfunabsolute" then
61         optimbase_typereal ( value , "value" , 3 );
62         optimbase_checkscalar ( "optimbase_configure" , value , "value" , 3 )
63         optimbase_checkgreq ( "optimbase_configure" , value , "value" , 3 , 0 )
64         this.tolfunabsolute = value;
65     case "-tolfunrelative" then
66         optimbase_typereal ( value , "value" , 3 );
67         optimbase_checkscalar ( "optimbase_configure" , value , "value" , 3 )
68         optimbase_checkgreq ( "optimbase_configure" , value , "value" , 3 , 0 )
69         this.tolfunrelative = value;
70     case "-tolxabsolute" then
71         optimbase_typereal ( value , "value" , 3 );
72         optimbase_checkscalar ( "optimbase_configure" , value , "value" , 3 )
73         optimbase_checkgreq ( "optimbase_configure" , value , "value" , 3 , 0 )
74         this.tolxabsolute = value;
75     case "-tolxrelative" then
76         optimbase_typereal ( value , "value" , 3 );
77         optimbase_checkscalar ( "optimbase_configure" , value , "value" , 3 )
78         optimbase_checkgreq ( "optimbase_configure" , value , "value" , 3 , 0 )
79         this.tolxrelative = value;
80     case "-tolxmethod" then
81         optimbase_typeboolean ( value , "value" , 3 );
82         optimbase_checkscalar ( "optimbase_configure" , value , "value" , 3 )
83         this.tolxmethod = value;
84     case "-tolfunmethod" then
85         optimbase_typeboolean ( value , "value" , 3 );
86         optimbase_checkscalar ( "optimbase_configure" , value , "value" , 3 )
87         this.tolfunmethod = value;
88     case "-function" then
89         optimbase_typecallable ( value , "value" , 3)
90         this.fun = value;
91     case "-outputcommand" then
92         optimbase_typecallable ( value , "value" , 3)
93         this.outputcommand = value;
94     case "-numberofvariables" then
95         optimbase_typereal ( value , "value" , 3 );
96         optimbase_checkscalar ( "optimbase_configure" , value , "value" , 3 )
97         optimbase_checkgreq ( "optimbase_configure" , value , "value" , 3 , 1 )
98         this.numberofvariables = value;
99     case "-storehistory" then
100         optimbase_typeboolean ( value , "value" , 3 );
101         optimbase_checkscalar ( "optimbase_configure" , value , "value" , 3 )
102         this.storehistory = value;
103     case "-boundsmin" then
104         optimbase_typereal ( value , "value" , 3 );
105         this.boundsmin = value;
106     case "-boundsmax" then
107         optimbase_typereal ( value , "value" , 3 );
108         this.boundsmax = value;
109     case "-nbineqconst" then
110         optimbase_typereal ( value , "value" , 3 );
111         optimbase_checkscalar ( "optimbase_configure" , value , "value" , 3 )
112         optimbase_checkgreq ( "optimbase_configure" , value , "value" , 3 , 0 )
113         this.nbineqconst = value;
114     case "-withderivatives" then
115         optimbase_typeboolean ( value , "value" , 3 );
116         optimbase_checkscalar ( "optimbase_configure" , value , "value" , 3 )
117         this.withderivatives = value;
118         //
119         // Obsolete options.
120         //
121     else
122         errmsg = msprintf(gettext("%s: Unknown key %s"),"optimbase_configure",key)
123         error(errmsg)
124     end
125 endfunction
126 // Generates an error if the given variable is not of type real
127 function optimbase_typereal ( var , varname , ivar )
128     if ( type ( var ) <> 1 ) then
129         errmsg = msprintf(gettext("%s: Expected real variable for variable %s at input #%d, but got %s instead."),"optimbase_typereal", varname , ivar , typeof(var) );
130         error(errmsg);
131     end
132 endfunction
133 // Generates an error if the given variable is not of type string
134 function optimbase_typestring ( var , varname , ivar )
135     if ( type ( var ) <> 10 ) then
136         errmsg = msprintf(gettext("%s: Expected string variable for variable %s at input #%d, but got %s instead."),"optimbase_typestring", varname , ivar , typeof(var) );
137         error(errmsg);
138     end
139 endfunction
140 // Generates an error if the given variable is not of type function (macro)
141 function optimbase_typefunction ( var , varname , ivar )
142     if ( type ( var ) <> 13 ) then
143         errmsg = msprintf(gettext("%s: Expected function but for variable %s at input #%d, got %s instead."),"optimbase_typefunction", varname , ivar , typeof(var) );
144         error(errmsg);
145     end
146 endfunction
147 // Generates an error if the given variable is not of type boolean
148 function optimbase_typeboolean ( var , varname , ivar )
149     if ( type ( var ) <> 4 ) then
150         errmsg = msprintf(gettext("%s: Expected boolean but for variable %s at input #%d, got %s instead."),"optimbase_typeboolean", varname , ivar , typeof(var) );
151         error(errmsg);
152     end
153 endfunction
154
155 // Generates an error if the value corresponding to an option is unknown.
156 function unknownValueForOption ( value , optionname )
157     errmsg = msprintf(gettext("%s: Unknown value %s for %s option"),"unknownValueForOption",value , optionname );
158     error(errmsg);
159 endfunction
160
161 function optimbase_typecallable ( var , varname , ivar )
162     // Check that var is a function or a list
163     if ( and ( type ( var ) <> [11 13 15] ) ) then
164         errmsg = msprintf(gettext("%s: Expected function or list for variable %s at input #%d, but got %s instead."),"optimbase_typecallable", varname , ivar , typeof(var) );
165         error(errmsg);
166     end
167     if ( type ( var ) == 15 ) then
168         // Check that var(1) is a function
169         if ( and ( type ( var(1) ) <> [11 13] ) ) then
170             errmsg = msprintf(gettext("%s: Expected function for variable %s(1) at input #%d, but got %s instead."),"optimbase_typecallable", varname , ivar , typeof(var) );
171             error(errmsg);
172         end
173     end
174 endfunction
175
176 function optimbase_checkrange ( funname , var , varname , ivar , vmin , vmax )
177     if ( ~and ( vmin <= var & var <= vmax ) ) then
178         k = find ( vmin > var | var > vmax )
179         k = k(1)
180         errmsg = msprintf(gettext("%s: Expected that all entries of input argument %s at input #%d are in the range [%s,%s], but entry #%d is equal to %s."),funname,varname,ivar,string(vmin),string(vmax),k,string(var(k)));
181         error(errmsg);
182     end
183 endfunction
184
185 function optimbase_checkgreq ( funname , var , varname , ivar , thr )
186     if ( or ( var < thr ) ) then
187         k = find ( var < thr )
188         k = k(1)
189         errmsg = msprintf(gettext("%s: Expected that all entries of input argument %s at input #%d are greater or equal than %s, but entry #%d is equal to %s."),funname,varname,ivar,string(thr),k,string(var(k)));
190         error(errmsg);
191     end
192 endfunction
193
194 function optimbase_checkflint ( funname , var , varname , ivar )
195     if ( or ( round(var)<>var ) ) then
196         k = find ( round(var)<>var )
197         k = k(1)
198         errmsg = msprintf(gettext("%s: Expected floating point integer for input argument %s at input #%d, but entry #%d is equal to %s."),funname,varname,ivar,k,string(var(k)));
199         error(errmsg);
200     end
201 endfunction
202
203 function optimbase_checkscalar ( funname , var , varname , ivar )
204     if ( or(size(var) <> [1 1]) ) then
205         strcomp = strcat(string(size(var))," ")
206         errmsg = msprintf(gettext("%s: Wrong size for input argument #%d: %d-by-%d matrix expected.\n"), funname, ivar , 1, 1 );
207         error(errmsg)
208     end
209 endfunction
210
211 function optimbase_checkoption ( funname , var , varname , ivar , expectedopt )
212     if ( and ( var <> expectedopt ) ) then
213         stradd = """ or """
214         strexp = """" + strcat(string(expectedopt),stradd) + """"
215         errmsg = msprintf(gettext("%s: Expected value [%s] for input argument %s at input #%d, but got ""%s"" instead."),funname,strexp,varname,ivar,string(var));
216         error(errmsg);
217     end
218 endfunction