8f3ba125ec89ec555dcb9490472cda1a017c0ad3
[scilab.git] / scilab / modules / preferences / macros / getPreferencesValue.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) 2014 - Scilab Enterprises - Calixte DENIZET
3 //
4 // This file must be used under the terms of the CeCILL.
5 // This source file is licensed as described in the file COPYING, which
6 // you should have received as part of this distribution.  The terms
7 // are also available at
8 // http://www.cecill.info/licences/Licence_CeCILL_V2.1-en.txt
9
10 // Get preferences values
11 // - xpath is something like "//web/body/proxy", the target must be a single node
12 // - attributes is a matrix of strings containing the attributes names
13 // - doc (optional): the prefs xml document where to get the values
14 //
15 function values = getPreferencesValue(xpath, attributes, doc)
16     rhs = argn(2);
17
18     if (rhs ~= 2 & rhs ~= 3) then
19         error(msprintf(gettext("%s: Wrong number of input arguments: %d or %d expected.\n"), "getPreferencesValue", 2, 3));
20     end
21
22     if type(xpath) <> 10 then
23         error(msprintf(gettext("%s: Wrong type for input argument #%d: String expected.\n"), "getPreferencesValue", 1));
24     end
25
26     if type(attributes) <> 10 then
27         error(msprintf(gettext("%s: Wrong type for input argument #%d: Matrix of strings expected.\n"), "getPreferencesValue", 2));
28     end
29
30     if rhs == 2 then
31         doc = xmlRead(SCIHOME + "/XConfiguration.xml");
32     elseif typeof(doc) ~= "XMLDoc" then
33         error(msprintf(gettext("%s: Wrong type for input argument #%d: A XMLDoc expected.\n"), "getPreferencesValue", 3));
34     end
35
36     try
37         xp = xmlXPath(doc, xpath);
38     catch
39         if rhs == 2 then
40             xmlDelete(doc);
41         end
42         error(msprintf(gettext("%s: Invalid XPath request.\n"), "getPreferencesValue"));
43     end
44
45     if xp.size ~= 1 then
46         if rhs == 2 then
47             xmlDelete(doc);
48         end
49         error(msprintf(gettext("%s: Invalid XPath request."), "getPreferencesValue"));
50     end
51
52     node = xp(1);
53     if node.type ~= "XML_ELEMENT_NODE" then
54         if rhs == 2 then
55             xmlDelete(doc);
56         end
57         error(msprintf(gettext("%s: Target node is not a XML_ELEMENT_NODE."), "getPreferencesValue"));
58     end
59
60     attr = node.attributes;
61     values = [];
62     for a = attributes(:)'
63         v = attr(a);
64         if v ~= [] then
65             values = [values v];
66         else
67             if rhs == 2 then
68                 xmlDelete(doc);
69             end
70             error(msprintf(gettext("%s: Invalid attribute name: %s."), "getPreferencesValue", a));
71         end
72     end
73
74     if rhs == 2 then
75         xmlDelete(doc);
76     end
77     values = matrix(values, size(attributes));
78 endfunction