Prefs: create XConfiguration.xml file only when SCIHOME exists and is writable (https...
[scilab.git] / scilab / modules / preferences / macros / getPreferencesValue.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) 2014 - Scilab Enterprises - Calixte DENIZET
3 //
4 // This file must be used under the terms of the CeCILL.
5 // This source file is licensed as described in the file COPYING, which
6 // you should have received as part of this distribution.  The terms
7 // are also available at
8 // http://www.cecill.info/licences/Licence_CeCILL_V2.1-en.txt
9
10 // Get preferences values
11 // - xpath is something like "//web/body/proxy", the target must be a single node
12 // - attributes is a matrix of strings containing the attributes names
13 // - doc (optional): the prefs xml document where to get the values
14 //
15 function values = getPreferencesValue(xpath, attributes, doc)
16     rhs = argn(2);
17
18     if (rhs ~= 2 & rhs ~= 3) then
19         error(msprintf(gettext("%s: Wrong number of input arguments: %d or %d expected.\n"), "getPreferencesValue", 2, 3));
20     end
21
22     if type(xpath) <> 10 then
23         error(msprintf(gettext("%s: Wrong type for input argument #%d: String expected.\n"), "getPreferencesValue", 1));
24     end
25
26     if type(attributes) <> 10 then
27         error(msprintf(gettext("%s: Wrong type for input argument #%d: Matrix of strings expected.\n"), "getPreferencesValue", 2));
28     end
29
30     if rhs == 2 then
31         try
32             doc = xmlRead(SCIHOME + "/XConfiguration.xml");
33         catch
34             error(msprintf(gettext("%s: Invalid XConfiguration.xml file.\n"), "getPreferencesValue"));
35         end
36     elseif typeof(doc) ~= "XMLDoc" then
37         error(msprintf(gettext("%s: Wrong type for input argument #%d: A XMLDoc expected.\n"), "getPreferencesValue", 3));
38     end
39
40     try
41         xp = xmlXPath(doc, xpath);
42     catch
43         if rhs == 2 then
44             xmlDelete(doc);
45         end
46         error(msprintf(gettext("%s: Invalid XPath request.\n"), "getPreferencesValue"));
47     end
48
49     if xp.size ~= 1 then
50         if rhs == 2 then
51             xmlDelete(doc);
52         end
53         error(msprintf(gettext("%s: Invalid XPath request."), "getPreferencesValue"));
54     end
55
56     node = xp(1);
57     if node.type ~= "XML_ELEMENT_NODE" then
58         if rhs == 2 then
59             xmlDelete(doc);
60         end
61         error(msprintf(gettext("%s: Target node is not a XML_ELEMENT_NODE."), "getPreferencesValue"));
62     end
63
64     attr = node.attributes;
65     values = [];
66     for a = attributes(:)'
67         v = attr(a);
68         if v ~= [] then
69             values = [values v];
70         else
71             if rhs == 2 then
72                 xmlDelete(doc);
73             end
74             error(msprintf(gettext("%s: Invalid attribute name: %s."), "getPreferencesValue", a));
75         end
76     end
77
78     if rhs == 2 then
79         xmlDelete(doc);
80     end
81     values = matrix(values, size(attributes));
82 endfunction