Licence added
[scilab.git] / scilab / modules / signal_processing / macros / group.sci
1 function [tg,fr]=group(npts,a1i,a2i,b1i,b2i)
2 //Calculate the group delay of a digital filter
3 //with transfer function h(z).
4 //The filter specification can be in coefficient form,
5 //polynomial form, rational polynomial form, cascade
6 //polynomial form, or in coefficient polynomial form.
7 //  npts :Number of points desired in calculation of group delay
8 //  a1i  :In coefficient, polynomial, rational polynomial, or
9 //       :cascade polynomial form this variable is the transfer
10 //       :function of the filter.  In coefficient polynomial
11 //       :form this is a vector of coefficients (see below).
12 //  a2i  :In coeff poly form this is a vector of coeffs
13 //  b1i  :In coeff poly form this is a vector of coeffs
14 //  b2i  :In coeff poly form this is a vector of coeffs
15 //  tg   :Values of group delay evaluated on the grid fr
16 //  fr   :Grid of frequency values where group delay is evaluated
17 //
18 //In the coefficient polynomial form the tranfer funtion is
19 //formulated by the following expression:
20 //
21 //       h(z)=prod(a1i+a2i*z+z**2)/prod(b1i+b2i*z+z^2)
22 //
23 //!
24 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
25 // Copyright (C) INRIA - 1988 - C. Bunks
26 // 
27 // This file must be used under the terms of the CeCILL.
28 // This source file is licensed as described in the file COPYING, which
29 // you should have received as part of this distribution.  The terms
30 // are also available at    
31 // http://www.cecill.info/licences/Licence_CeCILL_V2-en.txt
32
33 //get frequency grid values in [0,.5)
34  
35    fr=(0:.5/npts:.5*(npts-1)/npts);
36  
37 //get the of arguments used to called group
38  
39    [ns,ne]=argn(0);
40  
41 //if the number of arguments is 2 then
42 //the case may be non-cascade
43  
44    hcs=1;
45    if ne==2 then
46  
47 //get the type of h and the variable name
48  
49       h=a1i;
50       ht=type(h);
51  
52 //if ht==1 then h is a vector containing filter coefficients
53  
54       if ht==1 then
55  
56 //make h a rational polynomial
57  
58          hs=maxi(size(h));
59          z=poly(0,'z');
60          h=poly(h,'z','c');
61          h=gtild(h,'d')*(1/z^(hs-1));
62          ht=16;
63       end,
64  
65 //if ht==16 then h is a rational polynomial
66 //(perhaps in cascade form)
67  
68       //-compat ht==15 retained for list/tlist compatibility
69       if ht==15|ht==16 then
70          z=varn(h(3));
71          hcs=maxi(size(h(2)));
72       end,
73  
74 //if the rational polynomial is not in cascade form then
75  
76       if hcs==1 then
77  
78 //if ht==2 then h is a regular polynomial
79  
80          if ht==2 then
81             z=varn(h);
82          end,
83  
84 //get the derivative of h(z)
85  
86          hzd=derivat(h);
87  
88 //get the group delay of h(z)
89  
90          z=poly(0,z);
91          tgz=-z*hzd/h;
92  
93 //evaluate tg
94  
95          rfr=exp(2*%pi*%i*fr);
96          tg=real(freq(tgz(2),tgz(3),rfr));
97  
98 //done with non-cascade calculation of group delay
99  
100       end,
101    end,
102  
103 //re-organize if h is in cascade form
104  
105    if hcs>1 then
106       xc=[coeff(h(2)),coeff(h(3))];
107       a2i=xc(1:hcs);
108       a1i=xc(hcs+1:2*hcs);
109       b2i=xc(3*hcs+1:4*hcs);
110       b1i=xc(4*hcs+1:5*hcs);
111       ne=5;
112    end,
113  
114 //if implementation is in cascade form
115  
116    if ne==5 then
117  
118 //a1i,a2i,b1i,b2i are the coefficients of a
119 //second order decomposition of the filter
120 //(i.e. in cascade form, see Deczky)
121  
122       phi=2*%pi*fr;
123       z=poly(0,'z');
124       ejw=freq(z,1,exp(%i*phi));
125       emjw=freq(z,1,exp(-%i*phi));
126  
127       a1=a1i'*ones(phi);
128       b1=b1i'*ones(phi);
129       a2=a2i'*ones(phi);
130       b2=b2i'*ones(phi);
131       ejw=ones(a1i)'*ejw;
132       emjw=ones(a1i)'*emjw;
133  
134       aterm=(a1+2*ejw)./(a1+ejw+a2.*emjw);
135       bterm=(b1+2*ejw)./(b1+ejw+b2.*emjw);
136  
137       tgi=real(bterm-aterm);
138       tg=ones(a1i)*tgi;
139  
140 //done with cascade calculation of group delay
141 end
142 endfunction