d827df3e38e1412f70ccaf26a89d3c45618cea21
[scilab.git] / scilab / modules / statistics / macros / variance.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) 2000 - INRIA - Carlos Klimann
3 // Copyright (C) 2013 - Samuel GOUGEON
4 //
5 // This file must be used under the terms of the CeCILL.
6 // This source file is licensed as described in the file COPYING, which
7 // you should have received as part of this distribution.  The terms
8 // are also available at
9 // http://www.cecill.info/licences/Licence_CeCILL_V2.1-en.txt
10 //
11
12 function [s] = variance(x, orien, w)
13     //
14     //This function computes  the  variance  of  the values of  a  vector or
15     //matrix x.
16     //
17     //For a vector or   a matrix x,  s=variance(x)  returns in  the scalar s  the
18     //variance of all the entries of x.
19     //
20     //s=variance(x,'r')    (or,  equivalently,    s=variance(x,1)) is     the  rowwise
21     //variance. It returns in each entry of the row vector s the variance of
22     //each column of x.
23     //
24     //s=variance(x,'c') (or, equivalently, s=variance(x,2)) is the columnwise standard
25     //deviation.   It  returns in  each  entry  of the   column vector y the
26     //variance of each row of x.
27     //
28     //
29
30     // Checking and normalizing input arguments:
31     // ----------------------------------------
32     [lhs,rhs] = argn(0)
33     if rhs==0 then
34         tmp = gettext("%s: Wrong number of input arguments: %d to %d expected.\n")
35         error(msprintf(tmp, "variance", 1, 2))
36     end
37
38     if x==[] then
39         s = %nan
40         return
41     end
42
43     if ~isdef("orien","local") then
44         orien = "*"
45     end
46
47     transposed = %f // to refer and process as in "r", we priorly transpose any "c" request
48     if orien=="r" | orien==1 | orien=="c" | orien==2 | orien=="*"
49         if orien=="c" | orien==2 then
50             x = x.'
51             transposed = %t
52             orien = "r"
53         end
54     else
55         tmp = gettext("%s: Wrong value for input argument: ''%s'', ''%s'', %d or %d expected.\n")
56         error(msprintf(tmp, "variance", "c", "r", 1, 2))
57     end
58
59     if rhs<3 then
60         w = 0
61     elseif typeof(w)~="constant" | and(w~=[0 1]) then
62         tmp = gettext("%s: Wrong value of w : %s; %d or %d expected.\n")
63         error(msprintf(tmp, "variance", string(w), 0, 1))
64     end
65
66     // Calculations
67     // ------------
68     d = size(x, orien) - 1 + w    // denominator
69     if orien=="*" then
70         m = mean(x)
71     else
72         m = mean(x, orien).*.ones(size(x,1),1)
73     end
74     s = sum(abs(x - m).^2, orien) / d
75
76     if transposed
77         s = s.'
78     end
79
80 endfunction
81