* Bug 15308 fixed: evstr(['1;2' '3;4']) was not accepted, unlike ['1 2';'3 4']
[scilab.git] / scilab / modules / string / macros / evstr.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) INRIA
3 // Copyright (C) DIGITEO - 2010 - Allan CORNET
4 // Copyright (C) 2016, 2017 - Samuel GOUGEON
5 //
6 // Copyright (C) 2012 - 2016 - Scilab Enterprises
7 //
8 // This file is hereby licensed under the terms of the GNU GPL v2.0,
9 // pursuant to article 5.3.4 of the CeCILL v.2.1.
10 // This file was originally licensed under the terms of the CeCILL v2.1,
11 // and continues to be available under such terms.
12 // For more information, see the COPYING file which you should have received
13 // along with this program.
14
15
16 function [%val, %ierr] = evstr(%str)
17
18     [lhs, rhs] = argn(0);
19     %val = [];
20     %ierr =  0;
21
22     select type(%str)
23
24     case 10 then
25         // matrix of character strings
26         if isempty(%str) then
27             %val = [];
28             return;
29         end
30
31         // bug 7003
32         vars = ["Nan"  "NaN"  "Inf"  "INF"]
33         vals = ["%nan" "%nan" "%inf" "%inf"]
34         tmp = ~isdef(vars)
35         if tmp~=[]
36             execstr(vars(tmp)+"="+vals(tmp))
37         end
38
39         // Removing comments:
40         regExp = "_(?<!\:)//[^\""\'']*$_";
41         %str = strsubst(%str, regExp , "", "r");
42         k = grep(%str, "_^[^""'']*?//.*?(\""|\'')_", "r");
43         if k~=[]
44             %str(k) = strsubst(%str(k), "_(?<!\:|"")?//.*$_" , "", "r");
45         end
46
47         // Bracketing expressions: http://bugzilla.scilab.org/15308
48         comm = grep(%str, "_(^|[^:])//_", "r");
49         tmp = 1:size(%str,"*");
50         if comm~=[]
51             tmp = setdiff(tmp, comm) // indices of expressions without remaining comments
52         end
53         if tmp~=[]
54             %str(tmp) = "[" + %str(tmp) + "]";
55         end
56         //
57         %t1 = strcat(%str, ",", "c")+";"
58         %t1(1) = "%val=[" + %t1(1);
59         %t1($) = part(%t1($), 1:length(%t1($)) - 1)+";";
60         %t1($+1)="]";
61         if lhs == 2 then
62             %ierr = execstr(%t1, "errcatch");
63         else
64             execstr(%t1)
65         end
66
67     case 15 then
68         // list
69         %sexp = %str(2),
70         %nstr = prod(size(%sexp));
71         % = list();
72         if lhs == 2 then
73             for %k_ = 1:%nstr,
74                 [%w, %ierr] = evstr(%sexp(%k_));
75                 %(%k_) = %w;
76                 if %ierr <>0  then
77                     %val = [];
78                     return;
79                 end
80             end
81             [%val, %ierr] = evstr(%str(1));
82         else
83             for %k_ = 1:%nstr,
84                 %(%k_) = evstr(%sexp(%k_));
85             end
86             %val = evstr(%str(1))
87         end
88
89     case 1 then
90         // real or complex constant matrix
91         %val = %str;
92     else
93         error(msprintf(gettext("%s: Wrong type for input argument #%d: Real or Complex matrix, Matrix of character strings or list expected.\n"), "evstr", 1));
94     end
95     if exists("%val", "local") == 0 then
96         error(msprintf(gettext("%s: Given expression has no value.\n"), "evstr"));
97     end
98 endfunction