* Bug 15728 fixed: evstr(s) was wrong for s='k' 'tmp' 'vals'..
[scilab.git] / scilab / modules / string / macros / evstr.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) INRIA
3 // Copyright (C) DIGITEO - 2010 - Allan CORNET
4 // Copyright (C) 2016, 2017, 2018 - Samuel GOUGEON
5 //
6 // Copyright (C) 2012 - 2016 - Scilab Enterprises
7 //
8 // This file is hereby licensed under the terms of the GNU GPL v2.0,
9 // pursuant to article 5.3.4 of the CeCILL v.2.1.
10 // This file was originally licensed under the terms of the CeCILL v2.1,
11 // and continues to be available under such terms.
12 // For more information, see the COPYING file which you should have received
13 // along with this program.
14
15
16 function [%val, %ierr] = evstr(%str)
17
18     %lhs = argn(1);
19     %val = [];
20     %ierr =  0;
21
22     select type(%str)
23
24     case 10 then
25         // matrix of character strings
26         if isempty(%str) then
27             %val = [];
28             return;
29         end
30
31         // bug 7003
32         vars = ["Nan"  "NaN"  "Inf"  "INF"]
33         vals = ["%nan" "%nan" "%inf" "%inf"]
34         tmp = ~isdef(vars)
35         if or(tmp)
36             execstr(vars(tmp)+"="+vals(tmp))
37         end
38
39         // Removing comments:
40         regExp = "_(?<!\:)//[^\""\'']*$_";
41         %str = strsubst(%str, regExp , "", "r");
42         k = grep(%str, "_^[^""'']*?//.*?(\""|\'')_", "r");
43         if k~=[]
44             %str(k) = strsubst(%str(k), "_(?<!\:|"")?//.*$_" , "", "r");
45         end
46
47         // Bracketing expressions: http://bugzilla.scilab.org/15308
48         comm = grep(%str, "_(^|[^:])//_", "r");
49         tmp = 1:size(%str,"*");
50         if comm~=[]
51             tmp = setdiff(tmp, comm) // indices of expressions without remaining comments
52         end
53         if tmp~=[]
54             %str(tmp) = "[" + %str(tmp) + "]";
55         end
56         //
57         %t1 = strcat(%str, ",", "c")+";"
58         %t1(1) = "%val=[" + %t1(1);
59         %t1($) = part(%t1($), 1:length(%t1($)) - 1)+";";
60         %t1($+1) = "]";
61         clear k tmp vars vals regExp comm %str
62
63         %ierr = execstr(%t1, "errcatch");
64         if %lhs == 1 & %ierr~=0 then
65             msg = _("%s: Argument #%d: Some expression can''t be evaluated (%s).\n")
66             error(msprintf(msg, "evstr", 1, strcat(lasterror())))
67         end
68
69     case 15 then
70         // list
71         if size(%str)~=2
72             msg = _("%s: Argument #%d: %d-element list expected.\n")
73             error(msprintf(msg, "evstr", 1, 2));
74         end
75         if type(%str(1))~=10 | type(%str(2))~=10
76             msg = _("%s: Argument #%d: Both list components must be of text type.\n")
77             error(msprintf(msg, "evstr", 1));
78         end
79         %sexp = %str(2),
80         % = list();
81         for %k_ = 1:prod(size(%sexp))
82             [%w, %ierr] = evstr(%sexp(%k_));
83             %(%k_) = %w;
84             if %ierr <>0  then
85                 if %lhs == 2
86                     %val = [];
87                     return;
88                 else
89                     msg = _("%s: Argument #1(2): The expression #%d = ""%s"" can''t be evaluated (%s).\n")
90                     error(msprintf(msg, "evstr", %k_, %sexp(%k_), strcat(lasterror())))
91                 end
92             end
93         end
94         if %lhs == 2
95             [%val, %ierr] = evstr(%str(1));
96         else
97             %val = evstr(%str(1));
98         end
99
100     case 1 then
101         // real or complex constant matrix
102         %val = %str;
103     else
104         error(msprintf(gettext("%s: Wrong type for input argument #%d: Matrix of character strings or list expected.\n"), "evstr", 1));
105     end
106     if exists("%val", "local") == 0 then
107         error(msprintf(gettext("%s: Given expression has no value.\n"), "evstr"));
108     end
109 endfunction