* Bug 15890 fixed: +[] warning from evstr()
[scilab.git] / scilab / modules / string / macros / evstr.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) INRIA
3 // Copyright (C) DIGITEO - 2010 - Allan CORNET
4 // Copyright (C) 2016, 2017, 2018 - Samuel GOUGEON
5 //
6 // Copyright (C) 2012 - 2016 - Scilab Enterprises
7 //
8 // This file is hereby licensed under the terms of the GNU GPL v2.0,
9 // pursuant to article 5.3.4 of the CeCILL v.2.1.
10 // This file was originally licensed under the terms of the CeCILL v2.1,
11 // and continues to be available under such terms.
12 // For more information, see the COPYING file which you should have received
13 // along with this program.
14
15
16 function [%val, %ierr] = evstr(%str)
17
18     [lhs, rhs] = argn(0);
19     %val = [];
20     %ierr =  0;
21
22     select type(%str)
23
24     case 10 then
25         // matrix of character strings
26         if isempty(%str) then
27             %val = [];
28             return;
29         end
30
31         // bug 7003
32         vars = ["Nan"  "NaN"  "Inf"  "INF"]
33         vals = ["%nan" "%nan" "%inf" "%inf"]
34         tmp = ~isdef(vars)
35         if or(tmp)
36             execstr(vars(tmp)+"="+vals(tmp))
37         end
38
39         // Removing comments:
40         regExp = "_(?<!\:)//[^\""\'']*$_";
41         %str = strsubst(%str, regExp , "", "r");
42         k = grep(%str, "_^[^""'']*?//.*?(\""|\'')_", "r");
43         if k~=[]
44             %str(k) = strsubst(%str(k), "_(?<!\:|"")?//.*$_" , "", "r");
45         end
46
47         // Bracketing expressions: http://bugzilla.scilab.org/15308
48         comm = grep(%str, "_(^|[^:])//_", "r");
49         tmp = 1:size(%str,"*");
50         if comm~=[]
51             tmp = setdiff(tmp, comm) // indices of expressions without remaining comments
52         end
53         if tmp~=[]
54             %str(tmp) = "[" + %str(tmp) + "]";
55         end
56         //
57         %t1 = strcat(%str, ",", "c")+";"
58         %t1(1) = "%val=[" + %t1(1);
59         %t1($) = part(%t1($), 1:length(%t1($)) - 1)+";";
60         %t1($+1) = "]";
61         %ierr = execstr(%t1, "errcatch");
62         if lhs == 1 & %ierr~=0 then
63             msg = _("%s: Argument #%d: Some expression can''t be evaluated (%s).\n")
64             error(msprintf(msg, "evstr", 1, strcat(lasterror())))
65         end
66
67     case 15 then
68         // list
69         if size(%str)~=2
70             msg = _("%s: Argument #%d: %d-element list expected.\n")
71             error(msprintf(msg, "evstr", 1, 2));
72         end
73         if type(%str(1))~=10 | type(%str(2))~=10
74             msg = _("%s: Argument #%d: Both list components must be of text type.\n")
75             error(msprintf(msg, "evstr", 1));
76         end
77         %sexp = %str(2),
78         %nstr = prod(size(%sexp));
79         % = list();
80         for %k_ = 1:%nstr,
81             [%w, %ierr] = evstr(%sexp(%k_));
82             %(%k_) = %w;
83             if %ierr <>0  then
84                 if lhs==2
85                     %val = [];
86                     return;
87                 else
88                     msg = _("%s: Argument #1(2): The expression #%d = ""%s"" can''t be evaluated (%s).\n")
89                     error(msprintf(msg, "evstr", %k_, %sexp(%k_), strcat(lasterror())))
90                 end
91             end
92         end
93         if lhs==2
94             [%val, %ierr] = evstr(%str(1));
95         else
96             %val = evstr(%str(1));
97         end
98
99     case 1 then
100         // real or complex constant matrix
101         %val = %str;
102     else
103         error(msprintf(gettext("%s: Wrong type for input argument #%d: Matrix of character strings or list expected.\n"), "evstr", 1));
104     end
105     if exists("%val", "local") == 0 then
106         error(msprintf(gettext("%s: Given expression has no value.\n"), "evstr"));
107     end
108 endfunction