bug 10179 fixed - Weird behaviour with evstr.
[scilab.git] / scilab / modules / string / macros / evstr.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) INRIA
3 // Copyright (C) DIGITEO - 2010 - Allan CORNET
4 //
5 // This file must be used under the terms of the CeCILL.
6 // This source file is licensed as described in the file COPYING, which
7 // you should have received as part of this distribution.  The terms
8 // are also available at
9 // http://www.cecill.info/licences/Licence_CeCILL_V2-en.txt
10
11
12 function [%val, %ierr] = evstr(%str)
13
14   [lhs, rhs] = argn(0);
15   %val = [];
16   select type(%str)
17
18   case 10 then
19     // matrix of character strings
20
21     // bug 7003
22     if ~isdef('Nan') then
23       Nan = %nan;
24     end
25     if ~isdef('NaN') then
26       NaN = %nan;
27     end
28
29     if ~isdef('Inf') then
30       Inf = %inf;
31     end
32
33     if ~isdef('INF') then
34       INF = %inf;
35     end
36
37     for %l = 1:size(%str, 'r')
38       %t1(%l) = strcat(%str(%l, :), ',') + ';'
39     end
40     %t1(1) = '%val=[' + %t1(1);
41     %t1($) = part(%t1($), 1:length(%t1($)) - 1)+";";
42     %t1($+1)=']';
43     if lhs == 2 then
44       %ierr = execstr(%t1, 'errcatch');
45     else
46       execstr(%t1)
47     end
48
49   case 15 then
50     // list
51     %sexp = %str(2),
52     %nstr = prod(size(%sexp));
53     % = list();
54     if lhs == 2 then
55       for %k_ = 1:%nstr,
56         [%w, %ierr] = evstr(%sexp(%k_));
57         %(%k_) = %w;
58         if %ierr <>0  then
59           %val = [];
60           return;
61         end
62       end
63       [%val, %ierr] = evstr(%str(1));
64     else
65       for %k_ = 1:%nstr,
66         %(%k_) = evstr(%sexp(%k_));
67       end
68       %val = evstr(%str(1))
69     end
70
71   case 1 then
72     // real or complex constant matrix
73     %val = %str;
74     %ierr = 0;
75   else
76     error(msprintf(gettext("%s: Wrong type for input argument #%d: Real or Complex matrix, Matrix of character strings or list expected.\n"), "evstr", 1));
77   end
78   if exists('%val', 'local') == 0 then
79     error(msprintf(gettext("%s: Given expression has no value.\n"), "evstr"));
80   end
81 endfunction