License Header change: Removed the LICENSE_END before beta
[scilab.git] / scilab / modules / string / macros / evstr.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) INRIA
3 // Copyright (C) DIGITEO - 2010 - Allan CORNET
4 //
5 // Copyright (C) 2012 - 2016 - Scilab Enterprises
6 //
7 // This file is hereby licensed under the terms of the GNU GPL v2.0,
8 // pursuant to article 5.3.4 of the CeCILL v.2.1.
9 // This file was originally licensed under the terms of the CeCILL v2.1,
10 // and continues to be available under such terms.
11 // For more information, see the COPYING file which you should have received
12 // along with this program.
13
14
15 function [%val, %ierr] = evstr(%str)
16
17     [lhs, rhs] = argn(0);
18     %val = [];
19     select type(%str)
20
21     case 10 then
22         // matrix of character strings
23         if isempty(%str) then
24             %val = [];
25             %ierr =  0;
26             return;
27         end
28
29         // bug 7003
30         if ~isdef("Nan") then
31             Nan = %nan;
32         end
33         if ~isdef("NaN") then
34             NaN = %nan;
35         end
36
37         if ~isdef("Inf") then
38             Inf = %inf;
39         end
40
41         if ~isdef("INF") then
42             INF = %inf;
43         end
44
45         for %l = 1:size(%str, "r")
46             %t1(%l) = strcat(%str(%l, :), ",") + ";"
47         end
48         %t1(1) = "%val=[" + %t1(1);
49         %t1($) = part(%t1($), 1:length(%t1($)) - 1)+";";
50         %t1($+1)="]";
51         if lhs == 2 then
52             %ierr = execstr(%t1, "errcatch");
53         else
54             execstr(%t1)
55         end
56
57     case 15 then
58         // list
59         %sexp = %str(2),
60         %nstr = prod(size(%sexp));
61         % = list();
62         if lhs == 2 then
63             for %k_ = 1:%nstr,
64                 [%w, %ierr] = evstr(%sexp(%k_));
65                 %(%k_) = %w;
66                 if %ierr <>0  then
67                     %val = [];
68                     return;
69                 end
70             end
71             [%val, %ierr] = evstr(%str(1));
72         else
73             for %k_ = 1:%nstr,
74                 %(%k_) = evstr(%sexp(%k_));
75             end
76             %val = evstr(%str(1))
77         end
78
79     case 1 then
80         // real or complex constant matrix
81         %val = %str;
82         %ierr = 0;
83     else
84         error(msprintf(gettext("%s: Wrong type for input argument #%d: Real or Complex matrix, Matrix of character strings or list expected.\n"), "evstr", 1));
85     end
86     if exists("%val", "local") == 0 then
87         error(msprintf(gettext("%s: Given expression has no value.\n"), "evstr"));
88     end
89 endfunction