String: fix evstr base case
[scilab.git] / scilab / modules / string / macros / evstr.sci
1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
2 // Copyright (C) INRIA
3 // Copyright (C) DIGITEO - 2010 - Allan CORNET
4 //
5 // This file must be used under the terms of the CeCILL.
6 // This source file is licensed as described in the file COPYING, which
7 // you should have received as part of this distribution.  The terms
8 // are also available at
9 // http://www.cecill.info/licences/Licence_CeCILL_V2.1-en.txt
10
11
12 function [%val, %ierr] = evstr(%str)
13
14     [lhs, rhs] = argn(0);
15     %val = [];
16     select type(%str)
17
18     case 10 then
19         // matrix of character strings
20         if isempty(%str) then
21             %val = [];
22             %ierr =  0;
23             return;
24         end
25
26         // bug 7003
27         if ~isdef("Nan") then
28             Nan = %nan;
29         end
30         if ~isdef("NaN") then
31             NaN = %nan;
32         end
33
34         if ~isdef("Inf") then
35             Inf = %inf;
36         end
37
38         if ~isdef("INF") then
39             INF = %inf;
40         end
41
42         for %l = 1:size(%str, "r")
43             %t1(%l) = strcat(%str(%l, :), ",") + ";"
44         end
45         %t1(1) = "%val=[" + %t1(1);
46         %t1($) = part(%t1($), 1:length(%t1($)) - 1)+";";
47         %t1($+1)="]";
48         if lhs == 2 then
49             %ierr = execstr(%t1, "errcatch");
50         else
51             execstr(%t1)
52         end
53
54     case 15 then
55         // list
56         %sexp = %str(2),
57         %nstr = prod(size(%sexp));
58         % = list();
59         if lhs == 2 then
60             for %k_ = 1:%nstr,
61                 [%w, %ierr] = evstr(%sexp(%k_));
62                 %(%k_) = %w;
63                 if %ierr <>0  then
64                     %val = [];
65                     return;
66                 end
67             end
68             [%val, %ierr] = evstr(%str(1));
69         else
70             for %k_ = 1:%nstr,
71                 %(%k_) = evstr(%sexp(%k_));
72             end
73             %val = evstr(%str(1))
74         end
75
76     case 1 then
77         // real or complex constant matrix
78         %val = %str;
79         %ierr = 0;
80     else
81         error(msprintf(gettext("%s: Wrong type for input argument #%d: Real or Complex matrix, Matrix of character strings or list expected.\n"), "evstr", 1));
82     end
83     if exists("%val", "local") == 0 then
84         error(msprintf(gettext("%s: Given expression has no value.\n"), "evstr"));
85     end
86 endfunction